批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]如何用批处理去除txt文本里每一行中相同的字符串 [打印本页]

作者: qzwifi 时间: 2012-12-17 15:42 标题: [已解决]如何用批处理去除txt文本里每一行中相同的字符串

本帖最后由 pcl_test 于 2016-7-6 11:09 编辑

例：

文本a.txt内容为：
01 08 12 16

b.txt为：
01 02 03 04 05 06 07 08 09 10
11 12 13 14 15 16 17 18 19 20

处理后为：
02 03 04 05 06 07 09 10
11 13 14 15 17 18 19 20

就是把文本b.txt内有包含到文本a.txt里的数字去除

保存为3.txt

作者: apang 时间: 2012-12-17 18:48

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
  for %%b in (%%a) do set .%%b=1
)
(for /f "delims=" %%a in (b.txt) do (
  for %%b in (%%a) do (
    if not defined .%%b set "str=!str! %%b"
  )
  if defined str echo,!str:~1!&set "str="
))>3.txt
复制代码

作者: qzwifi 时间: 2012-12-17 19:08

回复 2# apang

OK，谢谢 apang 大哥！

作者: 悬崖之树 时间: 2012-12-18 21:11 标题: apang兄，为什么我的代码不灵了？

本帖最后由悬崖之树于 2012-12-18 21:13 编辑

兄弟，帮我看看我的代码错在哪里了？谢谢！

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in (b.txt) do (
   for %%b in (%%a) do (
      for /f "delims=" %%c in (a.txt) do (
         for %%d in (%%c) do (
            if "%%b" equ "%%d" (set /a n+=1)       
         )
         
      )
      if "!n!" equ "0" set "str=!str! %%b"
      set n=0
   )
   echo !str:~1!&echo.
)
pause
复制代码

我自己是无能为力了。

作者: apang 时间: 2012-12-18 23:36

本帖最后由 apang 于 2012-12-18 23:41 编辑

回复 4# 悬崖之树

11行：if "!n!" equ "" (set "str=!str! %%b") else set "n="
12行：删掉
14行：建议 if "!str!" neq "" echo,!str:~1!&set "str=" 否则当str为空值时，echo,!str:~1!显示的是很奇怪的字符

PS：思路对的，for嵌套级数多了点。。。

作者: 悬崖之树 时间: 2012-12-20 17:47

本帖最后由悬崖之树于 2012-12-20 18:05 编辑

真是谢谢apang大哥了，我是茅塞顿开啊。
关键在于没有想到 set /a n=n+1 在没有运行前，n不是0 而是空。

欢迎光临批处理之家 (http://www.bathome.net/)