批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理如何替换文本中的数字为指定符号并删除空格和空行 [打印本页]

作者: wh1234567 时间: 2012-11-18 17:08 标题: [已解决]批处理如何替换文本中的数字为指定符号并删除空格和空行

本帖最后由 pcl_test 于 2016-5-5 23:18 编辑

批处理如何替换数字为,，并删除空格和空行。
例如：
1 王 2 李 3 张 4 刘 5 陈 6 杨 7 黄 8 孙 9 周 10 吴
11 徐 12 赵 13 朱 14 马 15 胡 16 郭 17 林 18 何 19 高 20 梁

101 汤 102 陶 103 黎 104 温 105 莫 106 易 107 樊 108 乔 109 文 110 安

291 衣 292 蔺 293 和 294 冀 295 占 296 公 297 门 298 帅 299 利 300 满

处理后输出到文本，例如：
王,李,张,刘,...,汤,...,满

作者: tmplinshi 时间: 2012-11-18 17:18

本帖最后由 tmplinshi 于 2012-11-18 17:24 编辑

sed -n -r "s/^[ 0-9]+//; s/[0-9]+/,/g; s/ //gp" a.txt
复制代码

作者: tmplinshi 时间: 2012-11-18 17:31

@echo off
for /f "tokens=* delims=0123456789 " %%a in (a.txt) do (
    set str=%%a
    setlocal enabledelayedexpansion
    for /l %%a in (0 1 9) do set str=!str:%%a=,!
    
    set str_=
    for %%a in (!str!) do set str_=!str_!,%%a
    echo !str_:~1!
    
    endlocal
)
pause
复制代码

作者: wh1234567 时间: 2012-11-18 17:49

本帖最后由 wh1234567 于 2012-11-18 17:52 编辑

回复 3# tmplinshi

得处理并输出到另外一个文本里呢，另外我发现处理后可能不正确，个数好像少了很多个

作者: tmplinshi 时间: 2012-11-18 17:51

回复 tmplinshi

得处理并输出到另外一个文本里呢
wh1234567 发表于 2012-11-18 17:49

@echo off
(for /f "tokens=* delims=0123456789 " %%a in (a.txt) do (
set str=%%a
setlocal enabledelayedexpansion
for /l %%a in (0 1 9) do set str=!str:%%a=,!

set str_=
for %%a in (!str!) do set str_=!str_!,%%a
echo !str_:~1!

endlocal
)) >new.txt
pause

作者: wh1234567 时间: 2012-11-18 17:54

回复 5# tmplinshi

这次能处理了，但是不是全部排到一起的，就是不别按10个为一行，而是全部连到一起的那种，谢谢您了

作者: tmplinshi 时间: 2012-11-18 18:10

回复 tmplinshi

这次能处理了，但是不是全部排到一起的，就是不别按10个为一行，而是全部连到一 ...
wh1234567 发表于 2012-11-18 17:54

@echo off
(for /f "tokens=* delims=0123456789 " %%a in (a.txt) do (
     set str=%%a
     setlocal enabledelayedexpansion
     for /l %%a in (0 1 9) do set str=!str:%%a=,!
     
     set str_=
     for %%a in (!str!) do set str_=!str_!,%%a
     set /p =!str_:~1!
     
     endlocal
 )) <nul >new.txt
 pause
复制代码

作者: apang 时间: 2012-11-18 18:25

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
  for %%b in (%%a) do (
    set /a 1%%b 2>nul&&set "str=!str!,"||set "str=!str!%%b"
  )
)
echo,!str:~1!>b.txt
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)