批处理之家 - Powered by Discuz! Board

标题: [技术讨论] vbs中的"Scripting.FileSystemObject"[属性与方法] [打印本页]

作者: czjt1234 时间: 2012-10-5 17:02 标题: vbs中的"Scripting.FileSystemObject"[属性与方法]

本帖最后由 czjt1234 于 2012-10-23 08:55 编辑

Scripting.FileSystemObject 创建 FileSystemObject 对象，提供对磁盘、文件、文件夹的访问

属性
Drives                所有可用的磁盘对象的集合，返回 Drives 集合

方法
BuildPath             在已存在路径后追加路径名称
CopyFile             复制文件
CopyFolder             复制文件夹
CreateFolder          创建文件夹，返回 Folder 对象
CreateTextFile       创建文件，返回 TextStream 对象
DeleteFile             删除文件
DeleteFolder          删除文件夹
DriveExists          指定的驱动器是否存在，返回True|False
FileExists             指定的文件是否存在，返回True|False
FolderExists          指定的文件夹是否存在，返回True|False
GetAbsolutePathName    返回指定路径的绝对路径
GetBaseName          获取文件名
GetDrive             获取磁盘对象，返回 Driver 对象
GetDriveName          获取盘符
GetExtensionName       获取扩展名
GetFile                获取文件对象，返回 File 对象
GetFileName          获取文件名+扩展名
GetFileVersion       获取文件版本信息
GetFolder             获取文件夹对象，返回 Folder 对象
GetParentFolderName    获取父文件夹
GetSpecialFolder       返回指定的特殊文件夹的完整路径
GetTempName          返回一个随机的文件名
MoveFile             移动文件
MoveFolder             移动文件夹
OpenTextFile          打开文本文件，返回 TextStream 对象

FileSystemObject 对象及其属性、方法，都可以在 Script5.6.chm 里找到参考

-----------------------------------------------------------------------------

该对象的属性和方法，创建了

File    对象
Folder    对象
Driver    对象
TextStream 对象
Drives    集合
Files    集合
Folders 集合

作者: czjt1234 时间: 2012-10-5 17:03

本帖最后由 czjt1234 于 2012-10-23 08:57 编辑

下面是 FileSystemObject 对象的属性和方法的参数，及用法举例

代码测试环境：winxpsp3 IE8 Wscript版本5.7.0.18066

'-------------------------------------------------------------

Dim objFSO, blnYN, strRead
Dim objFile, objFolder, objDriver, objTextStream
Dim objDrivers, objFiles, objFolders, objAddFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")
'FileSystemObject 对象的属性和方法，可以直接对文件和文件夹操作，不需要先获取文件、文件夹对象

'-------------------------------------------------------------

blnYN = objFSO.FolderExists("D:\test")
'判断文件夹是否存在，返回True|False

blnYN = objFSO.FileExists("D:\test.txt")
'判断文件是否存在，返回True|False

blnYN = objFSO.DriveExists("C:")
'判断磁盘名是否存在，返回True|False

'-------------------------------------------------------------

objFSO.CreateFolder "D:\test"
'创建文件夹，不返回对象

objFSO.CreateTextFile "D:\test.txt", True|False, True|False
'创建文件，不返回对象
'第2个参数，True表示覆盖已有文件(缺省值)，False为不覆盖
'第3个参数，True表示文件编码为Unicode，False表示ASCII(缺省值)

Set objFolder = objFSO.GetFolder("D:\test")
'获取文件夹对象，返回 Folder 对象

Set objFile = objFSO.GetFile("D:\test.txt")
'获取文件对象，返回 File 对象

'也可以在创建文件和文件夹时直接返回对象

Set objFolder = objFSO.CreateFolder("D:\test")
'创建文件夹，返回 Folder 对象

Set objTextStream = objFSO.CreateTextFile("D:\test.txt", True|False, True|False)
'创建文件，返回 TextStream 对象，并以可写方式打开文件

'-------------------------------------------------------------

objFSO.CopyFolder "d:\test", "e:\test", True|False
'复制文件夹
'True表示覆盖已有文件夹和文件(缺省值)，False为不覆盖
'不能覆盖只读文件。路径支持通配符?*

objFSO.CopyFile "d:\test.txt", "e:\test.txt", True|False
'复制文件
'True表示覆盖已有文件(缺省值)，False为不覆盖
'不能覆盖只读文件

'-------------------------------------------------------------

objFSO.MoveFolder "d:\test", "d:\test1\"
'移动文件夹，目标文件夹必须已存在
'不支持跨盘移动。路径支持通配符?*

objFSO.MoveFolder "d:\test", "d:\test1"
'相当于文件夹重命名

objFSO.MoveFile "D:\test.txt", "e:\"
'移动文件

objFSO.MoveFile "D:\test.txt", "D:\test1.txt"
'相当于文件重命名

'-------------------------------------------------------------

objFSO.DeleteFolder "e:\test", True|False
'删除文件夹
'True表示删除只读文件夹，False为不删除(缺省值)

objFSO.DeleteFile "e:\test.txt", True|False
'删除文件
'True表示删除只读文件，False为不删除(缺省值)

'-------------------------------------------------------------

strRead = "c:\windows\notepad.exe"

MsgBox "文件名："    & objFSO.GetBaseName(strRead)       & vbCrLf & vbCrLf & _
   "扩展名："    & objFSO.GetExtensionName(strRead) & vbCrLf & vbCrLf & _
   "文件全名："    & objFSO.GetFileName(strRead)       & vbCrLf & vbCrLf & _
   "盘符："       & objFSO.GetDriveName(strRead)       & vbCrLf & vbCrLf & _
   "父文件夹："    & objFSO.GetParentFolderName(strRead) & vbCrLf & vbCrLf & _
   "文件版本信息：" & objFSO.GetFileVersion(strRead)

'返回指定字符串的文件信息
'字符串可以是文件或文件夹，也可以是不存在的文件或文件夹

'-------------------------------------------------------------

strRead = objFSO.GetTempName
'返回一个随机的文件名，用于创建临时文件或文件夹

strRead = objFSO.BuildPath("d:\test", "Sub Folder")
'在第一个路径后添加名称，返回 d:\test\Sub Folder
'与直接连接字符串相比，这里不用区分是 d:\test 还是 d:\test\

strRead = objFSO.GetSpecialFolder(0|1|2)
'返回指定的特殊文件夹的完整路径
  Const WindowsFolder = 0  '返回 windows 文件夹完整路径
  Const SystemFolder = 1  '返回 system32 文件夹完整路径
  Const TemporaryFolder = 2  '返回 temp 文件夹完整路径

strRead = objFSO.GetAbsolutePathName("C:")
'返回指定路径的绝对路径
'只指定盘符，则返回该盘符的当前目录
'只指定路径，则默认为当前盘符当前目录

'-------------------------------------------------------------

Set objDriver = objFSO.GetDrive("C:")
'获取磁盘对象，返回 Driver 对象

Set objDrivers = objFSO.Drives
'所有 Drive 对象组成的集合，返回 Drivers 集合

Set objTextStream = objFSO.OpenTextFile("D:\test.txt", 1|2|8, True|False, -2|-1|0)
'打开文件，返回 TextStream 对象
'可以读写文件内容，不能使用文件属性，不可以复制、移动、删除文件
'True表示文件不存在时自动新建文件，False为不新建(缺省值)
  Const ForReading       = 1 '只读(缺省值)
  Const ForWriting       = 2 '清空文件，覆盖写入
  Const ForAppending    = 8 '在文件末尾追加写入
  Const TristateUseDefault = -2  '以系统默认格式打开文件
  Const TristateTrue    = -1  '以 Unicode 格式打开文件
  Const TristateFalse    = 0 '以 ASCII 格式打开文件(缺省值)

'-------------------------------------------------------------

作者: czjt1234 时间: 2012-10-5 17:04

本帖最后由 czjt1234 于 2012-10-23 09:36 编辑

FileSystemObject 对象的 GetFile 方法可创建 File 对象

File 对象可以使用文件属性，可以复制、移动、删除文件，不能读写文件内容

属性
Attributes             文件的属性
DateCreated          文件的创建时间
DatelastAccessed       文件的最后访问时间
DateLastModified       文件的最后修改时间
Drive                文件所在的盘符
Name                   文件名
ParentFolder          文件的父文件夹
Path                   文件的完整路径
ShortName             文件的8.3格式短文件名
ShortPath             文件的短路径名
Size                   文件的大小
Type                   文件的类型

方法
Copy                   复制文件
Delete                删除文件
Move                   移动文件
OpenAsTextStream       打开文件，返回 TextStream 对象

作者: czjt1234 时间: 2012-10-5 17:04

本帖最后由 czjt1234 于 2012-10-6 22:55 编辑

下面是 File 对象的属性和方法的参数，及用法举例

代码测试环境：winxpsp3 IE8 Wscript版本5.7.0.18066

'-------------------------------------------------------------

Dim objFSO, blnYN, strRead
Dim objFile, objFolder, objDriver, objTextStream
Dim objDrivers, objFiles, objFolders, objAddFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")

'-------------------------------------------------------------

Set objFile = objFSO.GetFile("C:\Program Files\Internet Explorer\JSProfilerCore.dll")

MsgBox "属性："       & objFile.Attributes    & vbCrLf & vbCrLf & _
   "创建时间："    & objFile.DateCreated    & vbCrLf & vbCrLf & _
   "最后访问时间：" & objFile.DatelastAccessed & vbCrLf & vbCrLf & _
   "最后修改时间：" & objFile.DateLastModified & vbCrLf & vbCrLf & _
   "盘符："       & objFile.Drive          & vbCrLf & vbCrLf & _
   "文件名："    & objFile.Name          & vbCrLf & vbCrLf & _
   "父文件夹："    & objFile.ParentFolder    & vbCrLf & vbCrLf & _
   "完整路径："    & objFile.Path          & vbCrLf & vbCrLf & _
   "短文件名："    & objFile.ShortName       & vbCrLf & vbCrLf & _
   "完整短路径：" & objFile.ShortPath       & vbCrLf & vbCrLf & _
   "大小："       & objFile.Size          & vbCrLf & vbCrLf & _
   "类型："       & objFile.Type

'-------------------------------------------------------------

Set objFile = objFSO.GetFile("d:\test.txt")

objFile.Attributes = 1|2|4
'设置文件的属性。必须先获取文件对象
  Const Normal    = 0 '普通文件。没有设置任何属性
  Const ReadOnly = 1 '只读
  Const Hidden    = 2 '隐藏
  Const System    = 4 '系统
  Const Volume    = 8 '磁盘驱动器卷标(只读)
  Const Directory = 16  '文件夹(只读)
  Const Archive    = 32  '存档
  Const Alias    = 64  '链接或者快捷方式(只读)
  Const Compressed  = 128 '压缩文件(只读)

'-------------------------------------------------------------

Set objFile = objFSO.GetFile("d:\test.txt")

objFile.Copy "e:\test.txt", True|False
'复制文件到指定路径。必须先获取文件对象
'True表示覆盖已有文件(缺省值)，False为不覆盖
'不能覆盖只读文件

objFile.Move "e:\test.txt"
'移动文件到指定路径。必须先获取文件对象

objFile.Move "d:\test1.txt"
'相当于文件重命名

objFile.Delete True|False
'删除文件。必须先获取文件对象
'True表示删除只读文件。False为不删除(缺省值)

'-------------------------------------------------------------

Set objTextStream = objFile.OpenAsTextStream(1|2|8, -2|-1|0)
'打开文件，返回 TextStream 对象。必须先获取文件对象
'可以读写文件内容，不能使用文件属性，不可以复制、移动、删除文件
  Const ForReading       = 1 '只读(缺省值)
  Const ForWriting       = 2 '清空文件，覆盖写入
  Const ForAppending    = 8 '在文件末尾追加写入
  Const TristateUseDefault = -2  '以系统默认格式打开文件
  Const TristateTrue    = -1  '以 Unicode 格式打开文件
  Const TristateFalse    = 0 '以 ASCII 格式打开文件(缺省值)

'-------------------------------------------------------------

作者: czjt1234 时间: 2012-10-5 17:06

本帖最后由 czjt1234 于 2012-10-23 09:37 编辑

FileSystemObject 对象的 CreateFolder 和 GetFolder 方法可创建 Folder 对象

Folder 对象可使用文件夹的属性，可以复制、移动、删除文件夹

属性
Attributes             文件夹的属性
DateCreated          文件夹的创建时间
DatelastAccessed       文件夹夹的最后访问时间
DateLastModified       文件的最后修改时间
Drive                文件夹所在的盘符
Files                当前对象里所有文件的集合，返回 Files 集合
IsRootFolder          判断是否为根目录，返回True|False
Name                   文件夹名
ParentFolder          文件夹的父文件夹
Path                   文件夹的完整路径
ShortName             文件夹的8.3格式短文件名
ShortPath             文件的短路径名
Size                   文件夹的大小
SubFolders             当前对象里所有文件夹的集合，返回 Folders 集合
Type                   文件夹的类型

方法
Copy                   复制文件夹
Delete                删除文件夹
Move                   移动文件夹

作者: czjt1234 时间: 2012-10-5 17:06

本帖最后由 czjt1234 于 2012-10-6 22:58 编辑

下面是 Folder 对象的属性和方法的参数，及用法举例

代码测试环境：winxpsp3 IE8 Wscript版本5.7.0.18066

'-------------------------------------------------------------

Dim objFSO, blnYN, strRead
Dim objFile, objFolder, objDriver, objTextStream
Dim objDrivers, objFiles, objFolders, objAddFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")

'-------------------------------------------------------------

Set objFolder = objFSO.GetFolder("C:\Program Files\Internet Explorer")

MsgBox "属性："       & objFolder.Attributes    & vbCrLf & vbCrLf & _
   "创建时间："    & objFolder.DateCreated    & vbCrLf & vbCrLf & _
   "最后访问时间：" & objFolder.DatelastAccessed & vbCrLf & vbCrLf & _
   "最后修改时间：" & objFolder.DateLastModified & vbCrLf & vbCrLf & _
   "盘符："       & objFolder.Drive          & vbCrLf & vbCrLf & _
   "文件名："    & objFolder.Name          & vbCrLf & vbCrLf & _
   "父文件夹："    & objFolder.ParentFolder    & vbCrLf & vbCrLf & _
   "完整路径："    & objFolder.Path          & vbCrLf & vbCrLf & _
   "短文件名："    & objFolder.ShortName       & vbCrLf & vbCrLf & _
   "完整短路径：" & objFolder.ShortPath       & vbCrLf & vbCrLf & _
   "大小："       & objFolder.Size          & vbCrLf & vbCrLf & _
   "类型："       & objFolder.Type          & vbCrLf & vbCrLf & _
   "是否为根目录：" & objFolder.IsRootFolder

'-------------------------------------------------------------

Set objFolder = objFSO.GetFolder("d:\test")

objFolder.Attributes = 1|2|4
'设置文件夹的属性。必须先获取文件夹对象
  Const Normal    = 0 '普通文件。没有设置任何属性
  Const ReadOnly = 1 '只读
  Const Hidden    = 2 '隐藏
  Const System    = 4 '系统
  Const Volume    = 8 '磁盘驱动器卷标(只读)
  Const Directory = 16  '文件夹(只读)
  Const Archive    = 32  '存档
  Const Alias    = 64  '链接或者快捷方式(只读)
  Const Compressed  = 128 '压缩文件(只读)

'-------------------------------------------------------------

Set objFolder = objFSO.GetFolder("d:\test")

objFolder.Copy "e:\test", True|False
'复制文件夹到指定路径。必须先获取文件夹对象
'True表示覆盖已有文件夹及文件(缺省值)，False为不覆盖
'不能覆盖只读文件

objFolder.Move "d:\test1\"
'移动文件夹到指定路径。必须先获取文件夹对象。不支持跨盘移动

objFolder.Move "d:\test1"
'相当于文件夹重命名

objFolder.Delete True|False
'删除文件夹。必须先获取文件夹对象
'True表示删除只读文件，False为不删除(缺省值)

'-------------------------------------------------------------

Set objFolder = objFSO.GetFolder("d:\test")

set objFiles = objFolder.Files
'当前对象里所有文件的集合，不包括子文件夹里的文件。返回 Files 集合

set objFolders = objFolder.SubFolders
'当前对象里所有文件夹的集合，不包括子文件夹。返回 Folders 集合

'-------------------------------------------------------------

作者: czjt1234 时间: 2012-10-5 17:07

本帖最后由 czjt1234 于 2012-10-23 09:38 编辑

FileSystemObject 对象的 GetDrive 方法可创建 Driver 对象

Driver 对象提供对磁盘属性的访问

属性
AvailableSpace       可用空间
DriveLetter          驱动器号
DriveType             磁盘类型返回值：0未知 1可移动 2固定 3网络 4CDROM 5RAM盘
FileSystem             文件系统返回 FAT|NTFS|CDFS
FreeSpace             可用空间
IsReady                驱动器是否就绪返回True|False
Path                   驱动器路径
RootFolder             返回根目录
SerialNumber          返回十进制序列号，在cmd.exe的dir命令里是16进制
ShareName             返回网络磁盘的共享名
TotalSize             总字节数
VolumeName             卷标

方法
(无)

作者: czjt1234 时间: 2012-10-5 17:07

本帖最后由 czjt1234 于 2012-10-23 09:40 编辑

下面是 Driver 对象的属性和方法的参数，及用法举例

代码测试环境：winxpsp3 IE8 Wscript版本5.7.0.18066

'-------------------------------------------------------------

Dim objFSO, blnYN, strRead
Dim objFile, objFolder, objDriver, objTextStream
Dim objDrivers, objFiles, objFolders, objAddFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")

'-------------------------------------------------------------

Set objDriver = objFSO.GetDrive("C:")
'获取磁盘对象，返回 Driver 对象

MsgBox "可用空间："       & objDriver.AvailableSpace & vbCrLf & vbCrLf & _
   "驱动器号："       & objDriver.DriveLetter & vbCrLf & vbCrLf & _
   "磁盘类型："       & objDriver.DriveType    & vbCrLf & vbCrLf & _
   "文件系统："       & objDriver.FileSystem    & vbCrLf & vbCrLf & _
   "可用空间："       & objDriver.FreeSpace    & vbCrLf & vbCrLf & _
   "驱动器是否就绪：" & objDriver.IsReady       & vbCrLf & vbCrLf & _
   "驱动器路径："    & objDriver.Path          & vbCrLf & vbCrLf & _
   "根目录："          & objDriver.RootFolder    & vbCrLf & vbCrLf & _
   "序列号："          & objDriver.SerialNumber & vbCrLf & vbCrLf & _
   "网络磁盘的共享名：" & objDriver.ShareName    & vbCrLf & vbCrLf & _
   "总字节数："       & objDriver.TotalSize    & vbCrLf & vbCrLf & _
   "卷标："          & objDriver.VolumeName

'-------------------------------------------------------------

objDriver.VolumeName = "sys"    设置卷标

'-------------------------------------------------------------

其中 objDriver.ShareName 网络磁盘的共享名

比如网上邻居可以访问 \\a002\本地磁盘 (D)
映射网络驱动器 Z: 到 \\a002\本地磁盘 (D)
那么可以看到

Set objDriver = objFSO.GetDrive("Z:")
MsgBox "网络磁盘的共享名：" & objDriver.ShareName

但是用dos外部命令
subst.exe Z: "\\a002\本地磁盘 (D)"
映射的 Z: ，就不支持 .ShareName 属性。但其它属性都支持

作者: czjt1234 时间: 2012-10-5 17:08

本帖最后由 czjt1234 于 2012-10-23 09:40 编辑

FileSystemObject 对象的 CreateTextFile 和 OpenTextFile 方法
File 对象的 OpenAsTextStream 方法
这3个方法可创建 TextStream 对象

TextStream 对象用于对文本内容进行操作
可以读写文件内容，不能使用文件属性，不可以复制、移动、删除文件

属性
AtEndOfLine          判断光标是否在行末，返回True|False
AtEndOfStream          判断光标是否在文末，返回True|False
Column                返回当前光标所在列号
Line                   返回当前光标所在行号

方法
Close                关闭文件对象
Read                   从光标位置读取数据
ReadAll                从光标位置读取全部数据
ReadLine             从光标位置读取本行数据
Skip                   跳过指定字符数
SkipLine             跳过一行
Write                写入数据
WriteBlankLines       插入空行
WriteLine             写入数据并回车换行

作者: czjt1234 时间: 2012-10-5 17:09

本帖最后由 czjt1234 于 2012-12-16 11:34 编辑

下面是 TextStream 对象的属性和方法的参数，及用法举例

代码测试环境：winxpsp3 IE8 Wscript版本5.7.0.18066

'-------------------------------------------------------------
Dim objFSO, blnYN, strRead
Dim objFile, objFolder, objDriver, objTextStream
Dim objDrivers, objFiles, objFolders, objAddFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")

'-------------------------------------------------------------

Set objTextStream = objFSO.OpenTextFile("D:\test.txt", 1|2|8, True|False, -2|-1|0)
'打开文件，返回 TextStream 对象
'可以读写文件内容，不能使用文件属性，不可以复制、移动、删除文件
'True表示文件不存在时自动新建文件，False为不新建(缺省值)
  Const ForReading       = 1 '只读(缺省值)
  Const ForWriting       = 2 '清空文件，覆盖写入
  Const ForAppending    = 8 '在文件末尾追加写入
  Const TristateUseDefault = -2  '以系统默认格式打开文件
  Const TristateTrue    = -1  '以 Unicode 格式打开文件
  Const TristateFalse    = 0 '以 ASCII 格式打开文件(缺省值)

objTextStream.Skip(3)
'在读取数据时，跳过3个字符，光标位置移到3个字符之后
'每行末尾的回车换行算2个字符
'要求打开方式为只读

objTextStream.SkipLine
'在读取数据时，跳过一行，光标位置移到下一行行首
'要求打开方式为只读

strRead = objTextStream.Read(3)
'从光标位置读取3个字符，光标移到3个字符之后
'要求打开方式为只读

strRead = objTextStream.ReadLine
'从光标位置读取一行，光标移到下一行行首
'要求打开方式为只读

strRead = objTextStream.ReadAll
'从光标位置读取文件所有内容，光标移到文末
'要求打开方式为只读

blnYN = objTextStream.AtEndOfLine
'判断光标位置是否在某一行末尾，返回True|False
'要求打开方式为只读

blnYN = objTextStream.AtEndOfStream
'判断光标位置是否在文末，返回True|False
'要求打开方式为只读

objTextStream.Write "test"
'从光标位置插入字符串

objTextStream.WriteLine "test"
'从光标位置插入字符串，并回车换行

objTextStream.WriteBlankLines 5
'从光标位置插入5个空行

strRead = objTextStream.Line
'返回当前光标所在行号

strRead = objTextStream.Column
'返回当前光标所在列号

objTextStream.Close
'关闭文件对象，立刻保存到磁盘

'-------------------------------------------------------------

作者: czjt1234 时间: 2012-10-5 17:09

本帖最后由 czjt1234 于 2012-12-16 11:31 编辑

objFSO.Drives 属性创建 Drives 集合

objFolder.Files 属性创建 Files 集合

objFolder.SubFolders 属性创建 Folders 集合

这3个集合都支持属性 Count，返回集合内对象的个数

Folders 集合还有个方法 Add，用于在 Folders 集合里添加文件夹对象，可返回一个 Foler 对象

作者: czjt1234 时间: 2012-10-5 17:14

本帖最后由 czjt1234 于 2012-12-16 11:29 编辑

下面是 Drives Files Folders 集合的用法举例

代码测试环境：winxpsp3 IE8 Wscript版本5.7.0.18066

'-------------------------------------------------------------
Dim objFSO, blnYN, strRead
Dim objFile, objFolder, objDriver, objTextStream
Dim objDrivers, objFiles, objFolders, objAddFolder

Set objFSO = CreateObject("Scripting.FileSystemObject")

'-------------------------------------------------------------

Set objDrivers = objFSO.Drives
'返回 Drives 集合

Msgbox objDrivers.Count
'该集合内对象的个数

'枚举 Drives 集合的成员
For Each objDriver In objDrivers
Msgbox objDriver.Path
Next

'新建文件夹 d:\test，并在 d:\test 里新建几个文件和文件夹

Set objFolder = objFSO.GetFolder("d:\test")
'返回 Folder 对象

Set objFolders = objFolder.SubFolders
'返回 Folders 集合

Msgbox objFolders.Count
'该集合内对象的个数

objFolders.Add "test01"
'在当前目录 d:\test 里增加一个子文件夹 test01
'同时 Folders 集合里也增加该文件夹对象

set objAddFolder = objFolders.Add("test02")
'在当前目录 d:\test 里增加一个子文件夹 test02
'同时 Folders 集合里也增加该文件夹对象
'返回一个 Folder 对象
MsgBox objAddFolder.Path

'枚举 Folders 集合的成员
For Each objFolder In objFolders
Msgbox objFolder.Path
Next

Set objFolder = objFSO.GetFolder("d:\test")
set objFiles = objFolder.Files
'返回 Files 集合

Msgbox objFiles.Count
'该集合内对象的个数

'枚举 Files 集合的成员
for Each objFile In objFiles
Msgbox objFile.Path
Next

'-------------------------------------------------------------

欢迎光临批处理之家 (http://www.bathome.net/)