批处理之家 - Powered by Discuz! Board

标题: [已解决]批处理命令for分隔符delims＝后面的%%和!!有什么区别？ [打印本页]

作者: JooKin 时间: 2012-6-28 00:09 标题: [已解决]批处理命令for分隔符delims＝后面的%%和!!有什么区别？

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET "bb=+"
FOR /f “tokens=1* delims=%bb%”  %%i IN ("123+456") DO echo %%i
PAUSE
复制代码

显示结果是：123
把%bb%改成!bb!为什么显示结果没有变还是123+456？？

作者: CrLf 时间: 2012-6-28 00:26

闲逛贴吧，正好看到这个解释：
http://tieba.baidu.com/p/1687836406

作者: JooKin 时间: 2012-6-28 00:58

回复 2# CrLf

那如果真的需要用到!!呢？有什么方法替代解决吗？比如

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
SET str=1/2\3:4?5*6
SET x=/\:?*
FOR /l %%a IN (0 1 4) DO (
	FOR /f "tokens=1* delims=!x:~%%a,1!"  %%i IN ("%str%") DO ECHO %%j
)
PAUSE
复制代码

作者: apang 时间: 2012-6-28 08:46

@ECHO OFF&SETLOCAL ENABLEDELAYEDEXPANSION 
SET str=1/2\3:4?5*6
SET x=/\:?*
FOR /l %%a IN (0 1 4) DO call :11 !x:~%%a,1!
PAUSE&goto :eof
:11
FOR /f "tokens=1* delims=%1"  %%i IN ("%str%") DO ECHO %%j
复制代码

作者: JooKin 时间: 2012-6-28 20:58

回复 4# apang

谢谢！还有更好的办法吗？

作者: weichenxiehou 时间: 2012-6-29 11:21

本帖最后由 weichenxiehou 于 2012-6-29 11:23 编辑

回复 5# JooKin
如果真要用!bb!也不是不行…

@echo off
setlocal enabledelayedexpansion
set "bb= "
cmd/c "for /f "tokens=1* delims=!bb!" %%i in ("124+456") do echo,%%i"
复制代码

不过效率与call比起来可能不会有多少优势，且在新开的进程里创建的变量退出后不会保留。

作者: lllsoslll 时间: 2012-6-29 14:10

我在试验一种新方法，结果搞出个这东西：
猜猜输出什么？

@echo off

set s=
for /f "delims=" %%a in ("%s:/=##%")do echo %

:: 开始

FOR /f  %%i IN ("2345678") DO ECHO %%a

:: 结束
pause
复制代码

作者: CrLf 时间: 2012-6-29 14:23

回复 7# lllsoslll

奇异的现象，茫然

作者: lllsoslll 时间: 2012-6-29 14:35

貌似“)”丢失导致的，但又不仅仅是这个原因，

欢迎光临批处理之家 (http://www.bathome.net/)