批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理for命令中怎样查找以双引号开头的行？ [打印本页]

作者: forfiles 时间: 2012-6-20 19:54 标题: [已解决]批处理for命令中怎样查找以双引号开头的行？

本帖最后由 forfiles 于 2012-6-20 22:10 编辑

a.txt内容如下：
"1-2-3"
000
"4-5-6"

命令行里面可以这样查找以双引号开头的行：

findstr "^"" a.txt
复制代码

但是bat脚本里面这样写会出错：

@echo off
for /f "tokens=3 delims=-" %%a in ('findstr "^"" a.txt') do (
    echo %%a
)
复制代码

The syntax of the command is incorrect.

求讲姐

作者: weichenxiehou 时间: 2012-6-20 20:15

@echo off
for /f "tokens=3 delims=-" %%a in ('findstr ^"^^^"^" a.txt') do (
    echo %%a
)
复制代码

for括号命令中因为^的出现会增加一次预处理，对各个符号转义一次后和命令行下输入的相同。

作者: forfiles 时间: 2012-6-20 22:10

回复 2# weichenxiehou

学习了。Niubility

作者: apang 时间: 2012-6-20 22:12

@echo off
for /f "tokens=3 delims=-" %%a in ('findstr /b ^"^"^" a.txt') do (
    echo %%a
)
复制代码

总觉得怪怪的，不如下面的直接：

@echo off
for /f "tokens=1,3 delims=-" %%a in (a.txt) do (
  if not "%%~a"=="%%a" echo %%b
)
复制代码

作者: forfiles 时间: 2012-6-20 22:19

回复 4# apang

学习了。多谢。

作者: CrLf 时间: 2012-6-20 22:20

win7 下，如果 test.txt 内容不含文件路径的话或许也可以试试：

@echo off
(for /f "eol=' delims=" %%a in (test.txt) do (
  for /f "delims=" %%b in (%%a^") do echo ^"%%b
)) 2>nul
复制代码

因为 for /f 仅在输入参数以 " 开头时才触发字符串解析：
http://bbs.bathome.net/thread-15748-1-2.html

作者: waitfortea 时间: 2022-9-21 19:14

%%a^"这个什么意思啊

作者: qixiaobin0715 时间: 2022-9-22 09:37

本帖最后由 qixiaobin0715 于 2022-9-22 14:55 编辑

回复 7# waitfortea
不要再纠结（%%a^"）了，^" 转义双引号为普通字符。
CrLf的代码总是匪夷所思，“因为 for /f 仅在输入参数以 " 开头时才触发字符串解析”，这句话已经说的很清楚了。
即若某一行开头不是双引号，就不会与第2个for中添加的行结尾的双引号形成闭合双引号而运行错误，第2个for循环就不会执行。

欢迎光临批处理之家 (http://www.bathome.net/)