@echo off
setlocal enableDelayedExpansion
(
for /f "delims=" %%a in ('dir /a-d /s /b') do (
  set /a #%%~nxa+=1
  set $%%~nxa/!#%%~nxa!=%%a
  if !#%%~nxa! gtr 1 (
    if !#%%~nxa!==2 (echo !$%%~nxa/1!)
    echo %%a
  )
)
)>result.txt
pause
复制代码

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%a in ('dir /a-d /b /s "A\*.deb"') do (
  if not defined .%%~nxa (set .%%~nxa=1) else echo %%~nxa
))>$
endlocal
for /f "delims=" %%a in ($) do (
  if not defined .%%a dir /a-d /b /s "A\%%a"&set .%%a=1
)
del $
pause
复制代码

@echo off
(for /f "delims=" %%a in ('dir /a-d /b /s "A\*.*"') do (
  if not defined .%%~nxa (set .%%~nxa=1) else echo %%~nxa
))>$
(for /f "delims=" %%a in ($) do (
  if not defined _%%a dir /a-d /b /s "A\%%a"&set _%%a=1
))>result.txt
del $
findstr /n ".*" result.txt&&set/p num=选择序号(空格隔开):
for %%a in (%num%) do (
  for /f "tokens=1* delims=:" %%b in ('findstr /n ".*" result.txt') do (
    if "%%a"=="%%b" echo del /q "%%c"
  )
)
pause
复制代码

@echo off
setlocal enableDelayedExpansion
(
for /f "delims=" %%a in ('dir /a-d /s /b') do (
  set #%%~nxa=!#%%~nxa!/
  set $%%~nxa!#%%~nxa!=%%a
  if !#%%~nxa! neq / (
    if !#%%~nxa!==// (echo !$%%~nxa/!)
    echo %%a
  )
)
)>result.txt
pause
复制代码