批处理之家 - Powered by Discuz! Board

@echo off
color 0a&mode con cols=70 lines=18&title 欢迎使用“IE缓存提取器”！！
set LJ=%cd%
set CS=%UserProfile%\Local Settings\Temporary Internet Files\Content.IE5
:IE
cls&echo.&echo.
echo. ——欢迎使用“IE缓存提取器”！！
echo.
echo. ╭───────────────╮
echo. ╭────┤ 请选择，您要执行的操作—— ├─────╮
echo. │ ╰───────────────╯ │
echo. │ 0: 清空IE缓存 3: 提取常见图片 │
echo. │ │
echo. │ 1: 提取常见视频 4: 提取常见文档 │
echo. │ │
echo. │ 2: 提取常见音频 5: 提取指定文件 │
echo. ╰──────────────────────────╯
echo. 作者：溪水听冬 QQ：471 996 462
echo.&set /p IE= 输入您选择的“数字”后，请敲回车:
attrib -s -h -r "%CS%\*.*" /s /d >nul 2>nul
set SP=FLV mp4 RM RMVB WMV AVI ASF 3GP DivX
set YP=MP3 WMA WAV CDA APE FLAC OGG AAC
set TP=BMP GIF JPG PNG TGA SVG
set WD=TXT PDF RTF CHM HLP DOC XLS PPT
if /i "%IE%"=="0" goto QK
if /i "%IE%"=="1" call :copy %SP%
if /i "%IE%"=="2" call :copy %YP%
if /i "%IE%"=="3" call :copy %TP%
if /i "%IE%"=="4" call :copy %WD%
if /i "%IE%"=="5" goto ZD
cls
echo.&echo.&echo. 你输入的“ %IE% ”无效！！
echo.&echo.&echo. 别调皮了，返回重新输入吧！！！
echo.&echo.&pause
goto IE
:QK
cls
echo.&echo.&echo. ——为了保证“IE缓存”删除干净，
echo.&echo.&echo. 即将关闭 "IE 进程" 和 "视窗进程"...
ping 127.0.0.1 -n 3 >nul 2>nul
CD "%CS%\"
taskkill /f /im explorer.exe >nul 2>nul
taskkill /f /im iexplore.exe >nul 2>nul
rd /s /q "%CS%\" >nul 2>nul
del /f /s /q "%CS%\*.*" >nul 2>nul
start explorer.exe >nul 2>nul
CD %LJ%
goto IE
:copy
cls
set DQ=%1 %2 %3 %4 %5 %6 %7 %8 %9
for %%a in (%DQ%) do (
echo.&echo. 正在提取 %%a 文件...
echo.&xcopy "%CS%\*.%%a" "%LJ%\IE缓存\%%a文件\" /S /Q /H /Y /C
ping 127.0.0.1 -n 3 >nul 2>nul
)
goto END
:ZD
cls&echo.&echo.
echo. ——即将提取您指定的文件！！
echo.
echo. ╭───────────────╮
echo. ╭────┤ 请指定：您要提取的文件格式 ├─────╮
echo. │ ╰───────────────╯ │
echo. │ 例如: 提取“图标文件”，就输入 —— ICO │
echo. │ │
echo. │ 又如: 提取“广告动画”，就输入 —— SWF │
echo. ╰──────────────────────────╯
echo.&echo.&set /p ZD= 输入您选择的“文件后缀名”后，请敲回车:
cls&echo.&echo. 正在提取 %ZD% 文件...
echo.&xcopy "%CS%\*.%ZD%" "%LJ%\IE缓存\%ZD%文件\" /S /Q /H /Y /C
ping 127.0.0.1 -n 3 >nul 2>nul
goto END
:END
cls
if exist "%LJ%\IE缓存\" (goto CG)
echo.&echo.&echo. “IE缓存目录” 中，没有您要提取的文件！！
echo.&echo.&echo. 请浏览一次相应网页后，再来提取！！
echo.&echo.&pause
goto IE
:CG
attrib -s -h -r "%LJ%\IE缓存\*.*" /s /d
echo.&echo. 资源已提取到“%LJ%\IE缓存”目录中！
echo.&echo. 如要提取其它格式的缓存文件，请返回主菜单，
echo.&echo. 运行“提取指定文件”选项！
echo.&pause
goto IE

复制代码

@echo off
color 0a&mode con cols=70 lines=18&title 欢迎使用“IE缓存提取器”！！
:IE
cls&echo.&echo.
echo. ——欢迎使用“IE缓存提取器”！！
echo.
echo. ╭───────────────╮
echo. ╭────┤ 请选择，您要执行的操作—— ├─────╮
echo. │ ╰───────────────╯ │
echo. │ 0: 清空IE缓存 3: 提取常见图片 │
echo. │ │
echo. │ 1: 提取常见视频 4: 提取常见文档 │
echo. │ │
echo. │ 2: 提取常见音频 5: 提取指定文件 │
echo. ╰──────────────────────────╯
echo. 作者：溪水听冬 QQ：471 996 462
echo.&set /p IE= 输入您选择的“数字”后，请敲回车:
attrib -s -h -r "%UserProfile%\Local Settings\*.*" /s /d >nul 2>nul
REM /*************初始化文件后缀名
set audio=MP3 WMA WAV CDA APE FLAC OGG AAC
set vedio=FLV mp4 RM RMVB WMV AVI 3GP DivX
set picture=BMP GIF JPG PNG BMP
set document=TXT PDF RTF CHM HLP DOC XLS PPT
REM ***********************************/
if /i "%IE%"=="0" goto QK
REM /************CALL调用：copy过程*******
if /i "%IE%"=="1" call :copy %vedio%
if /i "%IE%"=="2" call :copy %audio%
if /i "%IE%"=="3" call :copy %picture%
if /i "%IE%"=="4" call :copy %document%
REM ***********************************/
if /i "%IE%"=="5" goto ZD
cls
echo.&echo.&echo. 你输入的“ %IE% ”无效！！
echo.&echo.&echo. 别调皮了，返回重新输入吧！！！
echo.&echo.&pause
goto IE
REM /**cd 命令不该用的地方。已经被删除，如果有错误再添加回去
:QK
cls
echo.&echo.&echo. ——为了保证“IE缓存”删除干净，
echo.&echo.&echo. 即将关闭 "IE 进程" 和 "视窗进程"...
ping 127.0.0.1 -n 3 >nul 2>nul
taskkill /f /im explorer.exe >nul 2>nul
taskkill /f /im iexplore.exe >nul 2>nul
rd /s /q "%userprofile%\Local Settings\History\"
rd /s /q "%userprofile%\Local Settings\Temporary Internet Files\"
del /f /s /q "%userprofile%\Local Settings\History\*.*"
del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
REM ***********************************//////
goto IE
REM /*多个提取过程因为有相同属性，集合到了一块代码，采用CALL传值
:copy
cls
for %%a in (%*) do (
echo.&echo. 正在提取 %%a 文件...
echo.&xcopy "%UserProfile%\Local Settings\Temporary Internet Files\*.%%a" "D:\IE缓存\%%a文件\" /S /Q /H /Y /C
ping 127.0.0.1 -n 3 >nul 2>nul
)
goto DK
REM ****************************************************//
:ZD
cls&echo.&echo.
echo. ——即将提取您指定格式的文件！！
echo.
echo. ╭───────────────╮
echo. ╭────┤ 请指定：您要提取的文件格式 ├─────╮
echo. │ ╰───────────────╯ │
echo. │ 例如: 提取“图标文件”，就输入 —— ICO │
echo. │ │
echo. │ 又如: 提取“广告动画”，就输入 —— SWF │
echo. ╰──────────────────────────╯
echo.&echo.&set /p ZD= 输入您选择的“文件后缀名”后，请敲回车:
cls&echo.&echo. 正在提取 %ZD% 文件...
echo.&xcopy "%UserProfile%\Local Settings\Temporary Internet Files\*.%ZD%" "D:\IE缓存\%ZD%文件\" /S /Q /H /Y /C
ping 127.0.0.1 -n 3 >nul 2>nul
goto DK
:DK
cls
echo.&echo. —— 您要提取的文件，已经全部提取到
echo.&echo. “D:\IE缓存\”文件夹中的相应目录！！
echo.&echo. 如要提取IE浏览器的、其它格式的缓存文件，
echo.&echo. 请返回主菜单，运行“提取指定文件”选项！
echo.&pause
if exist "D:\IE缓存\" (attrib -s -h -r "D:\IE缓存\*.*" /s /d &start "" "D:\IE缓存\")
goto IE

复制代码

@echo off
::查看临时文件（通用）
start "" "C:\Documents and Settings\Administrator\Local Settings\Temporary Internet Files\Content.IE5"
for /f "tokens=* delims=" %%a in ('dir /a /b /s "%userprofile%\Local Settings\Temporary Internet Files\*.*"') do echo %%a
pause

复制代码

@echo off&setlocal enabledelayedexpansion&::by cjiabing&from http://hi.baidu.com/cjiabing
title 查找和提取缓存文件
::提取临时文件指定文件名
:GetTempFileName
cls
echo.
echo,
echo; 可以加入后缀名，如：mynetwork.html
echo; 可以加入通配符，如：*qq* *.jpg
echo;
set input=
set /p input= 输入文件名：
echo.&set num=0
set "padd=%~dp0"
cd /d "C:\Documents and Settings\Administrator\Local Settings\Temporary Internet Files\Content.IE5"
echo:-------------------------------------------------------------------------
for /f "tokens=*" %%a in ('dir %input% /b /s') do (set /a num+=1&echo;【!num!】%%~nxa&echo;%%~sdpa&echo;%%~tzaa&echo;)
set inport=
set /p inport= 是否提取文件【Y/Enter】输入数字提取指定行：
if "%inport%"=="" goto GetTempFileName
set js=0
for /f "tokens=*" %%a in ('dir %input% /b /s') do (
set /a js+=1
if /i "%inport%"=="Y" copy "%%~a" "%padd%"
if /i "%inport%"=="!js!" copy "%%~a" "%padd%"
)
echo;
echo 提取结束，请查看当前目录！
echo;
pause
goto GetTempFileName

复制代码

if "%IE%"=="0" (
goto :QK
) else if "%IE%"=="1" (
call :copy %vedio%
) else if "%IE%"=="2" (
call :copy %audio%
) else if "%IE%"=="3" (
call :copy %picture%
) else if "%IE%"=="4" (
call :copy %document%
) else if "%IE%"=="5" (
goto :ZD
)

复制代码

:_TREE
if not exist "%~dp0GetTmp" md "%~dp0GetTmp"
for /d %%a in ("%userprofile%\Local Settings\Temporary Internet Files\Content.IE5\*") do (
echo:%%a&cd /d %%a
for /r %%i in (%TYPE%) do (
if exist "%~dp0GetTmp\%%~na" (Xcopy /s /y "%%~i" "%~dp0GetTmp\%%~na") else (md "%~dp0GetTmp\%%~na"&Xcopy /s /y "%%~i" "%~dp0GetTmp\%%~na")
)
)
cd /d %~dp0
cls&dir /b "%~dp0GetTmp"
pause&goto start

复制代码

@echo off
cls&echo.&echo. 正在提取 MP3 文件...
echo.&xcopy "%UserProfile%\Local Settings\Temporary Internet Files\Content.IE5\*.MP3" "%CD%\IE缓存\MP3文件\" /S /Q /H /Y /C
ping 127.0.0.1 -n 3 >nul 2>nul
exit

复制代码

@echo off
echo.&echo. 当前盘符：%~d0
echo.&echo. 当前盘符和路径：%~dp0
echo.&echo. 当前批处理全路径：%~f0
echo.&echo. 当前盘符和路径的短文件名格式：%~sdp0
echo.&echo. 当前CMD默认目录：%cd%
echo.&pause
exit

复制代码

:copy
cls
set suffix=%1 %2 %3 %4 %5 %6 %7 %8
for %%a in (%suffix%) do (
echo.&echo. 正在提取 %%a 文件...
echo.&xcopy "%UserProfile%\Local Settings\Temporary Internet Files\*.%%a" "D:\IE缓存\%%a文件\" /S /Q /H /Y /C
ping 127.0.0.1 -n 3 >nul 2>nul
)
goto DKK

复制代码