@echo off

for /f "tokens=15 delims= " %%i in ('ipconfig ^| find /i "IP Address"') do (
    set fsip=%%i
)
echo %fsip%
pause


for /f "tokens=1,2,3 delims=." %%i in ("%fsip%") do (
    set a=%%i.%%j.%%k
)

set Gateway=%a%.1
echo %a%
pause

del /f /q 在线ip.txt
del /f /q 离线ip.txt

for /l %%m in (1,1,254) do (

        ping.exe %a%.%%m -n 1 -w 300 >nul&&echo %a%.%%m>>在线ip.txt||echo %a%.%%m>>离线ip.txt

)
exit
复制代码

@echo off &setlocal enabledelayedexpansion
Title 局域网空闲IP查询
Rem '/*========获取本机的IP地址(局域网)=========*/
echo 正在获取本机的IP地址，请稍等...
for /f "tokens=3 skip=2 delims=: " %%i in ('nbtstat -n') do (
set "IP_addr=%%i"
set IP_addr=!IP_addr:~1,-1!
echo 本机IP为：!IP_addr!
goto :next
)
:next
for /f "delims=. tokens=1,2,3,4" %%i in ("%IP_addr%") do set IP_fd=%%i.%%j.%%k
Rem '/*========获取计算机名============*/
echo.&echo 正在获取局域网内计算机名，请稍等...
echo 处于网段 %IP_fd%.* 的计算机有：&echo.
for /f "delims=" %%i in ('net view') do (

set "var=%%i"

rem ----------获取计算机名称------------
if "!var:~0,2!"=="\\" (
set "var=!var:~2!"
echo !var!
Rem ----------ping计算机名--------------
ping -n 1 !var!>nul
)
)
echo.&echo -----------------------------
Rem '/*========提取arp缓存=========*/
echo.&echo 正在获取局域网内计算机IP，请稍等...& echo.

for /f "skip=3 tokens=1,* delims= " %%i in ('arp -a') do echo IP： %%i 已经使用
echo.&echo -----------------------------
echo 程序完成,谢谢使用!@Wenguolin.Com
pause>nul
复制代码

@echo off&title 局域网检测
set ff=list.txt
Rem    =======获取本机的IP地址========
echo;
for /f "tokens=1-6 delims=.: " %%a in ('ipconfig^|find ". . ."')do (
   set %%a_%%b=%%c.%%d.%%e.%%f
   if /i "%%a"=="ip" set ipd=%%c.%%d.%%e)
echo 本机 IP  %ip_address%
echo 子网掩码 %Subnet_Mask%
echo 网   关  %default_gateway%
set ip%default_gateway%=y
set/a n1=0,n2=0
echo.&echo 正在搜索 %ipd%.* 网段在线计算机 ... 
setlocal enabledelayedexpansion
(echo;%date:~,10% %time% 在线计算机：&echo;
echo  计算机名                 IP
echo ==================================
for /f "delims=\" %%i in ('net view^|find "\\"')do (
  set "var=%%i                    "
  set ip%%i=y
  for /f "tokens=3 delims=: " %%j in ('ping -n 1 %%i^|find/i "Reply from"'
    )do (echo !var:~,20!%%j&echo !var:~,20!%%j>con&set/a n1+=1))
echo ==================================
echo   共有 !n1! 个在线&echo; 
echo 以下 IP 离线：&(echo;&echo 离线 IP：&echo;)>con
echo ==============

for /L %%i in (1,1,254)do if not defined ip%ipd%.%%i (
  set/a n2+=1
  echo;%ipd%.%%i&echo;%ipd%.%%i>con)
echo ==============
echo !n2! 个离线)>"%ff%" 
echo;&echo %n2% 个离线
endlocal
echo;&set/p= 检测完成,按任意键退出... <nul&pause>nul
复制代码