批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]bat能否实现自动模拟键盘输入密码，模拟鼠标点击确定? [打印本页]

作者: ygqiang 时间: 2011-12-10 09:16 标题: [已解决]bat能否实现自动模拟键盘输入密码，模拟鼠标点击确定?

本帖最后由 ygqiang 于 2011-12-11 14:39 编辑

我有个软件，运行后，需要输入密码：111111，然后点确定，才能运行。

用bat能否实现自动模拟键盘输入密码，模拟鼠标点击确定，让这个软件自动运行呢？

如果bat不能实现，用什么方法可以实现？

作者: cjiabing 时间: 2011-12-10 10:59

vbs，搜索网内

作者: 冷玉公子 时间: 2011-12-10 17:26

去批处理第三方命令看看，主页搜一下。
不过干这个活最专业是应该是 AutoIt

作者: ygqiang 时间: 2011-12-11 05:39

set wshell=createobject("wscript.shell")
wshell.run "C:\Progra~1\Tencent\TM2009\Bin\TM.exe",1
wscript.sleep 2000 '2秒
wshell.sendkeys "11111"&chr(10)
复制代码

好像，这个vbs代码可以实现我需要的功能。

但想用bat方法，在c盘根目录下建立test.vbs

del /f /q c:\test.vbs
(echo set wshell=createobject("wscript.shell")
echo wshell.run "C:\Progra~1\Tencent\TM2009\Bin\TM.exe",1
echo wscript.sleep 2000 '2秒
echo wshell.sendkeys "11111"&chr(10)
)>"c:\test.vbs"
pause
复制代码

但因为里面有()，这个bat方法不管用啊。

如何用别的bat命令，在c盘根目录下建立test.vbs啊？多谢

作者: lcg823 时间: 2011-12-11 10:50

试试这样吧！！

@echo off
del /f /q c:\test.vbs
(echo set wshell=createobject^("wscript.shell"^)
echo wshell.run "C:\Progra~1\Tencent\TM2009\Bin\TM.exe",1
echo wscript.sleep 2000 '2秒
echo wshell.sendkeys "11111"^&chr^(10^)
)>"c:\test.vbs"
pause
复制代码

作者: ygqiang 时间: 2011-12-11 14:38

多谢楼上，问题解决。

作者: ygqiang 时间: 2011-12-11 14:40

本帖最后由 ygqiang 于 2012-3-22 08:16 编辑

最终解决方法：

@echo off
if "%1" == "h" goto begin
mshta vbscript:createobject("wscript.shell").run("%~fs0 h",0)(window.close)&&exit
:begin
rem 下边开始写批处代码了(适合全自动场合)

taskkill /f /im  thirdIO20.exe
taskkill /f /im  CCS.exe
taskkill /f /im  ccsSvcLg.exe
taskkill /f /im  CCS_Door.exe

del /f /q c:\test.vbs
(echo set wshell=createobject^("wscript.shell"^)
echo wshell.run """F:\上机管理\CCS20\CCS.exe""",1
echo wscript.sleep 15000 '15秒
echo wshell.sendkeys "111111"
echo wscript.sleep 2000 '2秒
echo wshell.sendkeys "{enter}"
)>"c:\test.vbs"

ping 127.0.0.1 -n 5 >nul 2>nul

start F:\上机管理\CCS20\thirdIO20.exe
ping 127.0.0.1 -n 5 >nul 2>nul

start c:\test.vbs
ping 127.0.0.1 -n 20 >nul 2>nul

start F:\上机管理\CCSSvcLg\ccsSvcLg.exe
ping 127.0.0.1 -n 10 >nul 2>nul

del /f /q c:\test.vbs

f:
cd\
cd F:\上机管理\CCSDoor20\
start CCS_Door.exe

ping 127.0.0.1 -n 5 >nul 2>nul

exit
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)