批处理之家 - Powered by Discuz! Board

@echo off&setlocal enabledelayedexpansion
rem 清除001下所有文件
del .\filelist1\001\*.* /Q
rem 通过文件列表filelist1.txt，在001下新建模拟文件待重命名
for /f "tokens=1 delims= " %%i in (filelist1.txt) do echo.>.\filelist1\001\%%i
pause
cls
set name=
set num=0
rem 将文件名#后面部分数值小于等于0的全部加1000后重命名，方便总体更名排序
rem 上一行所提方案有误：1000会排在1的后面，2的前面，汗~
rem 新方案：修改将文件名#后面部分数值小于等于0的全部前加字母a后重命名
for /f "delims=j# tokens=1,2" %%i in ('dir .\filelist1\001\ /B^|find "#0."') do (
rem for /f "delims=j# tokens=1,2" %%i in ('dir .\filelist1\001\ /B^|find "#1000."') do ( 方案有误，前加1000排序乱了，此行修改
set name1=%%i
set name2=%%j
rem ren .\filelist1\001\!name1!#!name2!jpg !name1!#a!name2:~3!jpg 方案有误，前加1000排序乱了，此行修改
ren .\filelist1\001\!name1!#!name2!jpg !name1!#a!name2!jpg
)
pause
rem 开始整体更名，由于更名3.1.jpg为3.jpg时遇到重名导致3.1和3.2失败，但是3.jpg被成功更名为5.jpg顺序无误，遂整体执行两次后完成修改
call :beginren
call :beginren
goto :eof
:beginren
for /f "delims=j# tokens=1,2" %%i in ('dir .\filelist1\001\ /B') do (
set name1=%%i
set name2=%%j
set shortname=!name2:~,-1!
set /a num+=1
echo !name1! !name2:~,-1! !shortname!
if not !name1!==!name! (echo 前面不等于&set num=1&ren .\filelist1\001\!name1!#!name2!jpg !name1!#!num!.jpg&set name=!name1!) else (echo 前面等于&if not !shortname!==!num! echo 后面不等于&ren .\filelist1\001\!name1!#!name2!jpg !name1!#!num!.jpg&set name=!name1!)
echo !num! !!name!!
)
goto :eof

复制代码

@echo off
rem 批处理放一级目录下、二级目录并排位置运行
echo 正在处理...
for /d %%i in (*)do (
cd "%%i" &echo %%i\ :
rem =====将文件名赋以固定10位的变量名===========
setlocal enabledelayedexpansion
for /f "tokens=1-3* delims=#." %%a in ('dir/b/a-d ????#*.jpg')do (
set h1=0%%b
set h1=!h1:~-2!
if "!h1!"=="00" set "h1=a0"
if "%%d"=="" (
set "fn=%%a#%%b.%%c"
set "h2= 0"
)else (
set "fn=%%a#%%b.%%c.%%d"
set h2=00%%c
set h2=!h2:~-2!
)
set "#%%a#!h1!!h2!=!fn!"
)
rem =====排序并重命名==========
for /f "tokens=1,2* delims=#=" %%a in ('set #')do (
if not defined ##%%a set ##%%a=y&set/a n=0
set/a n+=1
ren %%c %%a#!n!.jpg 2>nul||ren %%c %%a#!n!.jpg.yky
)
ren *.yky *. 2>nul
endlocal
cd..
)
pause

复制代码