批处理之家 - Powered by Discuz! Board

标题: 【练习-010】批处理实现文本最末列数值乘一个数 [打印本页]

作者: pusofalse 时间: 2008-8-7 02:48 标题: 【练习-010】批处理实现文本最末列数值乘一个数

a.txt

 
1##4072.0###52.19### #72## #
2#38705.8# # # 51.73## #70# #
372###389.0##51.80##19.77# # 72#####
4##59.71#3715.45##71######
复制代码

以#和空格作为分隔符，最后一列的数值乘以7，其他不变。
已知的条件，数字是随机的，最末列的数值是整数，即使乘以7，仍在CMD所能计算范围内。
#与空格与“.”的位置和数量与每行的列数都是随机的。
输出如下：

 
1##4072.0###52.19### #504## #
2#38705.8# # # 51.73## #490# #
372###389.0##51.80##19.77# # 504#####
4##59.71#3715.45##497######
复制代码

只是对最末列的数值进行运算操作，其他不变。
要求通用，高效。
-----------------------------------------------------------------------------------------
感谢大家的积极参与，至此，比较完美的答案请参照6楼ietuk版主，7楼terse，10楼youxi01，15楼huahua0901，21楼batman 等人的代码。
此基础上，简洁而且通用，个人觉得当属21楼BATMAN版主的代码。

[ 本帖最后由 pusofalse 于 2008-8-9 12:19 编辑 ]

作者: ieutk 时间: 2008-8-7 13:55

是这样理解的吗？

list.txt

1##4072.0###52.19### #504## #
2#38705.8# # # 51.73## #490# #
372###389.0##51.80##19.77# # 504#####
4##59.71#3715.45##497######
5##4072.0###52.19### #72## #
6#38705.8# # # 51.73## #70# #
772###389.0##51.80##19.77# # 72#####
8##59.71#3715.45##71######
复制代码

代码如下
--------------------------------------------------------------------------------------------------------------

@echo off
for /f "delims=" %%a in (list.txt) do call :is "%%a"
pause
goto :eof

:is
set /a num+=1
for /f "tokens=%num% delims=# " %%a in ("%~1") do (
	call set "var=%%var%% %%a"
	goto is
)
for %%a in (%var%) do set "num=%%a"
set /a _num=7*%num%
set "str=%~1"
call set "str=%%str:%num%=%_num%%%"
echo %str%
set "num=0"
goto :eof
复制代码

作者: huahua0919 时间: 2008-8-7 15:24

楼上代码错了，不可以用替换的
不然所有71的数字都被你替换了

作者: ieutk 时间: 2008-8-7 15:26

那到是，还要修代码

作者: pusofalse 时间: 2008-8-7 18:32

这题就是不让用变量替换才故意给出有重复数字的文本。
我之后生成的文本中有重复数字字串的概率是1%
变量截取可以，但好麻烦。

作者: ieutk 时间: 2008-8-7 18:54

@echo off&setlocal enabledelayedexpansion
for /f "usebackq skip=35 delims=" %%a in ("%~dpnx0") do (
 set "var=%%a"
 set "e="
 set "m=0"
 set /a num+=1
 call :is "%%a"
    )
for /l %%a in (1 1 %num%) do echo.!_str1%%a!!_num%%a!!_str2%%a!
pause
goto :eof
:is
set "str=%~1"
if "%var:~-1%" lss "0" (
 set "e=%var:~-1%!e!"
 set "var=%var:~0,-1%"&set /a m+=1
 goto is
    )
set "_str2%num%=%e%
set "_strn%num%=!str:~0,-%m%!"
call :su "!_strn%num%!"
goto :eof
:su
set "a="
set "u=%~1"
set "y=0"
:st
for /l %%a in (0 1 9) do if "%u:~-1%"=="%%a" set "a=%u:~-1%!a!"&set /a y+=1
set "u=%u:~0,-1%"
for /l %%a in (0 1 9) do if "%u:~-1%"=="%%a" goto :st
set /a x+=1
set "_num%x%=%a%"
set /a _num%num%*=7
set "_str1%x%=!_strn%x%:~0,-%y%!"
goto :eof
1##4072.0###52.19### #504## #
2#38705.8# # # 51.73## #490# #
372###389.0##51.80##19.77# # 504#####
4##59.71#3715.45##497######
5##4072.0###52.19### #72## #
6#38705.8# # # 51.73## #70# #
772###389.0##51.80##19.77# # 72#####
8##59.71#3715.45##71######
复制代码

[ 本帖最后由 ieutk 于 2008-8-7 19:05 编辑 ]

作者: terse 时间: 2008-8-7 21:05

这样行不？

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0 1 9) do set %%i=%%i
    for /f "delims=" %%i in (1.txt) do set "str=%%i"&call:lp
    pause&goto :eof
:lp
set/a n+=1
set var=!str:~-%n%,1!
if defined !var! (set str2=!var!!str2!&set lp=lp) else (
    if not defined lp (set str1=!var!!str1!) else (
    set/a str2*=7&set str=!str:~,-%n%!!var!!str2!!str1!
    >>b.txt echo !str!
    for %%i in (str1 str2 n lp) do set %%i=
    goto :eof
    ))
    goto lp
复制代码

作者: pusofalse 时间: 2008-8-7 21:20

7楼代码简洁，但感觉效率不如6楼。

作者: terse 时间: 2008-8-7 21:58

原帖由 pusofalse 于 2008-8-7 21:20 发表
7楼代码简洁，但感觉效率不如6楼。

何以见得呢？
你把上面的内容COPY 100次后测试看看

作者: youxi01 时间: 2008-8-8 01:56

测试代码：

@echo off 2>nul 3>nul
setlocal enabledelayedexpansion 
for /f "delims=" %%a in (list.txt) do (
	set /a n=0
	set var=%%a
	set var=!var:#= !
	for %%i in (!var!) do set res=%%i
	Rem '/*处理浮点///
	set /a ok=!res! && (set /a res=!res!*7) || (set var=!res:*.=!
			   for /l %%i in (0 1 9) do set var=!var:%%i= %%i!
	                   for %%i in (!var!) do set/a n+=1
			   set res=!res:.=!
			   set /a res=!res!*7
			   call set res=%%res:~0,-!n!%%.%%res:~-!n!%%)
	echo !res!
)
pause>nul
复制代码

测试数据：

1##4072.0###52.19### #504## #
2#38705.8# # # 51.73## #490# #
372###389.0##51.80##19.77# # 504#####
4##59.71#3715.45##497######
5##4072.0###52.19### #72.8026## #
6#38705.8# # # 51.73## #70.2# #
772###389.0##51.80##19.77# # 72.0#####
8##59.71#3715.45##71######

测试结果：

3528
3430
3528
3479
509.6182
491.4
504.0
497

作者: pusofalse 时间: 2008-8-8 05:55

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
     set "str="%%a""&set n=0
     for /l %%i in (0 1 9) do (
         set "str=!str:#%%i=#" "%%i!"
         set "str=!str:# %%i=# " "%%i!"
      )
     for %%c in (!str!) do set/a n+=1&set "..!n!=%%c"
     call,set _#=%%..!n!%%
     for /l %%j in (0 1 9) do set _#=!_#:%%j=!
     call,set ..!n!=%%..!n!:#=%%&call,set ..!n!=%%..!n!:"=%%
     set/a ..!n!*=7,m=n-1
     for /l %%d in (1 1 !m!) do set "res=!res!!..%%d!"
     call,echo !res:"=!%%..!n!%%!_#:"=!
     set "res="&set "_#="
)
pause>nul&exit/b
复制代码

初步测试通过。

作者: terse 时间: 2008-8-8 11:57

原帖由 pusofalse 于 2008-8-8 05:55 发表
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
   set "str="%%a""&set n=0
   for /l %%i in (0 1 9) do (
      set "str=!str:#%%i=#" "%%i!"
      set "str ...

还是替换效率高
如最后一列数字前有两个空格就处理不了看代码没处理两个空格
譬如：
#1# # 4072.0###52.19### # 504## #

作者: pusofalse 时间: 2008-8-8 12:20 标题: 回复 12楼的帖子

多谢指出。
又调试了一下，处理两个空格，但如果有二个以上又错误了。想一个通用的方法。

作者: pusofalse 时间: 2008-8-8 12:53

用我这种方法，确实处理不了多个空格，即便能够处理，效率也是非常低下而且不通用。
刚才测试了一下，效率一下降到谷底了。
得想一个全新的代码。

作者: huahua0919 时间: 2008-8-8 13:41

我把我的代码也贴到这，如果通用性有问题请告知
方法一：（用时0.25~0.30秒）

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (LastNumberChange.txt) do set/a n+=1&set LastLine=$%%i$
for /f "delims=" %%i in (LastNumberChange.txt) do (
set/a m+=1
if %n% neq !m! call set "all=!all!%%i&echo."
)

:start
set FirstNumber=%LastLine:~,1%
set "all1=!all1!%FirstNumber%"
set LastLine=%LastLine:~1%
echo %LastLine%|findstr "[0-9]" >nul&&goto :start
:all1
set /a t+=1
call set LastOne=%%all1:~-!t!%%
set/a x=LastOne*1
if "%LastOne%"=="%x%" goto :all1
set/a LastOne=%LastOne:~1%*7
set /a t-=1
set xlm=!all1:~,-%t%!
Set "Sum=%all%%xlm%%LastOne%%LastLine%"
echo %Sum:$=%
pause
复制代码

方法二：（用时0.02~0.05秒）

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (LastNumberChange.txt) do set/a n+=1&set LastLine=$%%i$
for /f "delims=" %%i in (LastNumberChange.txt) do (
set/a m+=1
if %n% neq !m! call set "all=!all!%%i&echo."
)
:LastOne
set/a x+=1
call set LastOne=%%LastLine:~-!x!,1%%
set /a Mult=%LastOne%*1
if not "%Mult%"=="%LastOne%" goto :LastOne
set/a x-=1
call set Front=%%LastLine:~,-%x%%%
call set Last=%%LastLine:~-%x%%%
:Middle
set/a x1+=1
call set LastOne1=%%Front:~-!x1!%%
set /a Mult1=%LastOne1%*1
if "%Mult1%"=="%LastOne1%" goto :Middle
set/a Middle=%LastOne1:~1%*7
set/a x1-=1
call set Front=%%Front:~,-%x1%%%
set "Sum=%all%%Front%%Middle%%Last%"
echo %Sum:$=%
pause
复制代码

作者: pusofalse 时间: 2008-8-8 14:03 标题: 回复 15楼的帖子

看错题意了啊。并不是最后一行末列数值乘7 每行都要乘以7。

第二个同是。

[ 本帖最后由 pusofalse 于 2008-8-8 14:05 编辑 ]

作者: pusofalse 时间: 2008-8-8 14:08 标题: 新方案

好绕啊。

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
 set "str=%%a"&set "a="&set "faith="&set "trust="&set "false="
 set n=0
 if "!str:~,1!" equ "#" set a=a
 if "!str:~,1!" equ " " set a=a
 call :lp
)
pause>nul&exit/b
:lp
set/a n+=1
if defined a call :lp1

for /f "tokens=%n%* delims=# " %%a in ("%str%") do (
 set trust=trust
 if "%%b" neq "" (
 set var=!var!%%a
 if defined a goto lp
 ) else (
 set c=%%a
))
if defined a goto result
:lp1
for /f "tokens=%n%* delims=0123456789." %%a in ("%str%") do (
 set false=false
 if "%%b" neq "" (
 set var=!var!%%a
 if not defined a goto lp
 ) else (
 set d=%%a
))
if defined faith goto :eof
if defined a goto :eof
:result
set/a c*=7
if defined a set faith=faith&set/a n+=1&call :lp1
if not defined trust echo %d%
if not defined false echo %c%
if defined trust if defined false echo %var%%c%%d%
set "var="
复制代码

[ 本帖最后由 pusofalse 于 2008-8-8 14:42 编辑 ]

作者: huahua0919 时间: 2008-8-8 14:24

楼上代码还是有问题啊
如果最后一行的数值是下面的三种形式就不行了

4##59.71#3715.45##71
复制代码

71##
复制代码

71
复制代码

[ 本帖最后由 huahua0919 于 2008-8-8 14:25 编辑 ]

作者: huahua0919 时间: 2008-8-8 14:28

我看错题意了，但是效果一样。解决你的问题过程一样

作者: pusofalse 时间: 2008-8-8 14:41 标题: 回复 19楼的帖子

多谢指出，已修改。

作者: batman 时间: 2008-8-9 11:30

我也来一个，从后向前截取字符的：

@echo off
for /f "delims=" %%i in (1.txt) do (
    set "str=%%i"&set "begin=a"
　　setlocal enabledelayedexpansion
    call :lp
    echo !str!!a!!var!!last!
　　endlocal
)
pause>nul&goto :eof
:lp
set "a=%str:~-1%"&set "str=%str:~,-1%"
if "%a%" geq "0" (
   if "%a%" leq "9" set "flag=a"&set "begin="
)
if defined flag (
   set var=%a%!var!&set "flag="
   ) else (
   if defined begin (
      set last=%a%!last!
      ) else (
　 set /a var*=7&goto :eof
   )
)
goto lp
复制代码

[ 本帖最后由 batman 于 2008-8-9 12:38 编辑 ]

作者: 随风 时间: 2008-8-12 20:52

也来一个
:

@echo off&setlocal EnableDelayedExpansion
for /l %%a in (0 1 9) do set .%%a=%%a
for /f "delims=" %%a in (a.txt) do (
   set flag=&set num=&set sun=&set "str=%%a"
   call :loop
)
pause
:loop
set "var=!str:~-1!"
if defined .!var! (set num=!var!!num!&set flag=a) else (set sun=!var!!sun!&set flag=)
if not defined num set str=!str:~0,-1!&goto loop
if defined flag set str=!str:~0,-1!&goto loop
set /a num*=7
echo !str!!num!!sun:~1!
goto:eof
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)