1号线 苹果园 古城 八角游乐园 八宝山 玉泉路 五棵松 万寿路 公主坟 军事博物馆 木樨地 南礼士路 复兴门 西单 天安门西 天安门东 王府井 东单 建国门 永安里 国贸 大望路 四惠
八通线 四惠 四惠东 高碑店 传媒大学 双桥
2号线 安定门 雍和宫 东直门 东四十条 朝阳门 建国门 北京站 崇文门 前门 和平门 宣武门 复兴门 阜成门 车公庄 西直门 积水潭 鼓楼大街
大兴线 天宫门 生物医药基地 义和庄 黄村火车站 黄村西大街 清源路 枣园 高米店南 高米店北 西红门 新宫 公益西桥
4号线 公益西桥 角门西 马家堡 北京南站 陶然亭 菜市口 宣武门 西单 灵境胡同 西四 平安里 新街口 西直门 动物园 国家图书馆 魏公村 人民大学 海淀黄庄 中关村 北京大学东门 圆明园 西苑 北宫门 安河桥北
房山线 苏庄 良乡南关 良乡大学城西 良乡大学城 良乡大学城北 广阳城 篱笆房 长阳 稻田 大葆台
亦庄线 次渠 次渠南 经海路 同济南路 荣昌东街 荣京东街 万源街 亦庄文化园 亦庄桥 旧宫 小红门 肖村 宋家庄
5号线 宋家庄 刘家窖 蒲黄榆 天坛东门 磁器口 崇文门 东单 灯市口 东四 张自忠路 北新桥 雍和宫 和平里北街 惠新西街南口 惠新西街北口 大屯路东 北苑路北 立水桥南 立水桥 天通苑南 天通苑 天通苑北
8号线 森林公园南门 奥林匹克公园 奥体中心 北土城
10号线 劲松 双井 国贸 金台夕照 呼家楼 团结湖 农业展览馆 亮马桥 三元桥 太阳宫 芍药居 惠新西街南口 安贞门 北土城 健德门 牡丹园 西土城 知春路 知春里 海淀黄庄 巴沟
13号线 西直门 大钟寺 知春路 五道口 上地 西二旗 龙泽 回龙观 霍营 立水桥 北苑 望京西 芍药居 光熙门 柳芳 东直门
昌平线 南邵 沙河高教园 沙河 巩华城 朱辛庄 生命科学园 西二旗
机场专线 东直门 三元桥 T2航站楼 T3航站楼
15号线 望京西 望京 崔各庄 马泉营 孙河 国展 花梨坎 后沙峪
复制代码

@ECHO OFF&SETLOCAL ENABLEDELAYEDEXPANSION
set /p input=请输入起点站-终点站:
for /f "tokens=1,2 delims=-, " %%a in ("!input!") do set "start=%%a"&set "end=%%b"
::取得交点。
for /f "tokens=1,2* delims=/ " %%a in (dt.txt) do (
    set "xl_%%a=%%c"
    for %%i in (%%c) do set /a #%%i+=1
)
for /f "tokens=1,2 delims=#=" %%a in ('set #') do (
    if !#%%a! geq 2 set "dd_list=!dd_list! %%a"
    set "#%%a="
)
::取得每个交点可到达的线路。
for /f "tokens=2,3 delims=_=" %%a in ('set xl_') do (
    set "str=%%b"
    for /f "tokens=1,2" %%x in ("!start! !end!") do (
        if not "!str:%%x=!"=="!str!" set "start_xl=!start_xl! %%a"
        if not "!str:%%y=!"=="!str!" set "end_xl=!end_xl! %%a"
    )
    for %%D in (!dd_list!) do (
        if not "!str:%%D=!"=="!str!" (
            set "%%x=!%%x:%%D=@%%D!"
            set "@%%D=!@%%D! %%a "
)))
::检查是否可直达
for %%a in (!start_xl!) do for %%b in (!end_xl!) do if %%a==%%b set "路线=^"!start! !end!^""
if not "!路线!"=="" goto :metic
::计算换乘路线
set "查询表=^"!start!=!start_xl!^""
set "剩余交点表=!dd_list!"
:loop
for %%i in (!查询表!) do (
for /f "tokens=1* delims==" %%A in ("%%~i") do (
for %%a in (%%B) do (
    for %%b in (!剩余交点表!) do (
        for %%c in (!@%%b!) do (
            if %%a==%%c (
                set "转车点=!转车点! %%b"
                set "剩余查询表=!剩余查询表! ^"%%A %%b=!@%%b:%%c=!^""
                for %%d in (!end_xl!) do for %%e in (!@%%b!) do if %%e==%%d (
                    set "路线=!路线! ^"%%A %%b !end!^" "
)))))))
for %%a in (!剩余交点表!) do for %%b in (!转车点!) do set "剩余交点表=!剩余交点表:%%b=!"
set "查询表=!剩余查询表!"
set "剩余查询表="
if !路线!.==. goto :loop
::计算站点
:metic
echo,路线:!路线!
goto :eof
复制代码

请输入起点站-终点站:华强路 岗厦北
路线: "华强路 世界之窗 岗厦北"  "华强路 大剧院 岗厦北"

请输入起点站-终点站:岗厦 岗厦北
路线:"岗厦 岗厦北"
可能是字符替换导致出问题了 =。=
复制代码

                                                                                   ,,,,,,,,,,,,,,,,,,,,,,,,.
                                                                                  Gr;.sr.rr.rr.rr.rs,;s:,sr
                                                                                 S@                        
                                                                                 r@                        
                                                                                 r@                        
                                                                                 r@                        
                                                                                 r@                        
                                                                                 r@                        
                                                                                 r@                        
                                                                                 r@                        
                                                                                 ;B                        
                              ..      .             ..  .                        S@                        
                         .@#@@BH@@A#@#A@@BB@@A#@#A@@@@@MH@#H@#A@#A@#A@@A@@@@@@BA#@@;                        
                        B@s                                                      ;@#@:                     
                      S@A                                                           ;@@                     
                    @                                                               3@S                  
                   @@                                                                   @r                  
                 3@X                                                                    @s                  
               ;@@                                                                      @r                  
             ,#@,                                                                       @s                  
            H@r                                     .                                   @r                  
          i@B                                       @A                          .#i     @s                  
        :@@                                         @B                        s@@@@     @;                  
       #r:                        .. . .. .  ... .; @@   ..  ...  ...      i@@#: r@  .  @5                  
     5@3                     MH3A3hAGAh3A9G&GA99&&@h@@rSX&&X29Ah229&h2ssH@@@#r,;;M@rX952@M5hi               
   :@X                       #                      GS                rMMr       ;@                        
  @@2 ,;;:          ;ssrrsr:,@2:;;;;;:;;:;;:;;:;;;r:@@,:;:;;;;:;;;;;A@9.         r#                        
  3is2&2r;          rhhS23r2@HXSXSS35iX2i22i2Xi22XA2@@rSXiSX2Xi5X5XS;            s#                        
                          ;2.                       92                           i@                        
                        ;Hi                         H3                           s@                        
                      ,#X                           &5                           5@                        
                     AB.                            @&                           :r                        
                   S#;                              #A                                                      
                 ;M2                                @H                                                      
               .&H,                                 ::                                                      
              5#r                                                                                          
            r@5                                                                                             
          ,MA                                                                                               
        .A#:                                                                                                
       .;.                                                                                                  

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims= " %%i in (dt.txt) do (
    set max=0
    for %%a in (%%j) do (
         set xian.%%i=!xian.%%i! %%a
         if defined zan.%%a set jie.%%a=!zan.%%a! %%i
         set zan.%%a=!zan.%%a! %%i
         set /a max+=1
         set /a ###%%i.%%a=!max!
    )
)
:: 获取所有线上的节点站名
for /f "tokens=2,3 delims=.=" %%i in ('set jie.') do (
    for %%a in (%%j) do set #%%a=!#%%a! %%i
)
:start
setlocal&cls
set /p xxx=输入起点站和终点站如: 华强路 岗厦北
for /f "tokens=1,2 delims= " %%a in ("!xxx!") do (
    set qix=!zan.%%a!&set "zx=!zan.%%b!"
    set qidian=%%a&set "zongdian=%%b"
    for %%i in (!zan.%%b!) do set zd.%%i=%%i
)
echo !qidian! --- !zongdian!     !qix!  ---  !zx!
echo;.............................................&echo;
:: 判断是否在同一条线
for %%a in (!qix!) do (
    for %%b in (!zx!) do if "%%a"=="%%b" (
        set tong=!tong! %%a
        call :tong !qidian! !zongdian!
        echo !ok!  共 !zzu! 站
        echo;.............................................
    )
)
if defined tong echo;&pause&endlocal&goto :start
rem        起点线    终点线  
call :kai "!qix!"
for /f "tokens=1* delims==" %%i in ('set $') do (
    set "%%i="&set /a mmm=0
    set tong=!qix!&set L1=!qidian!
    for %%k in (%%j) do (
        for /f "tokens=1,2 delims=/" %%a in ("%%k") do (
            set num=%%a&set tong2=%%b
        )
        call :tong !L1! !num!
        set /a mmm+=zzu,%%i+=1
        set tong=!tong2!&set L1=!num!
        echo            !ok! !zzu! 站
    )
    set tong=!zx!
    call :tong !num! !zongdian!
    set /a mmm+=zzu&set "mmm=  !mmm!"
    echo 累计!mmm:~-3!站  !ok! !zzu!站              
    echo;.............................................&echo;
)
echo;&pause&endlocal&goto :start
:kai
for %%a in (%~1) do (
    set t.%%a=a
    for %%b in (!#%%a!) do (rem %%b为%%a线上的节点站名
        for %%c in (!jie.%%b!) do (rem %%c为节点站上的线名
            if not defined t.%%c (
                if not defined zd.%%c (
                    set @=!@! %%b/%%c
                    call :kai "%%c"
                    set "t.%%c="
                    set @=!@: %%b/%%c=!
                    ) else (
                        set /a fl.+=1
                        set $!fl.!=!@! %%b/%%c
                )
            )
        )
    )
)
goto :EOF
:tong
for %%a in (!tong!) do (
    set strq=!###%%a.%1!
    set strz=!###%%a.%2!
    set /a zzu=strq-strz
    set zzu=!zzu:-=!
    set ok=%%a/%1 --- %%a/%2
)
goto :EOF
复制代码

@ECHO OFF&SETLOCAL ENABLEDELAYEDEXPANSION
set /p input=请输入起点站-终点站:
for /f "tokens=1,2 delims=-, " %%a in ("!input!") do set "start=%%a"&set "end=%%b"
::取得交点。
for /f "tokens=1* delims= " %%a in (dt.txt) do (
    set "xl_%%a=%%b"
    for %%i in (%%b) do set /a #%%i+=1
)
for /f "tokens=1,2 delims=#=" %%a in ('set #') do (
    if !#%%a! geq 2 set "dd_list=!dd_list! %%a"
    set "#%%a="
)
::取得每个交点可到达的线路。
for /f "tokens=2,3 delims=_=" %%a in ('set xl_') do (
    set "str=%%b"
    for /f "tokens=1,2" %%x in ("!start! !end!") do (
        if not "!str:%%x=#!"=="!str!" set "start_xl=!start_xl! %%a"
        if not "!str:%%y=#!"=="!str!" set "end_xl=!end_xl! %%a"
    )
    for %%D in (!dd_list!) do (
        if not "!str:%%D=!"=="!str!" (
            set "%%x=!%%x:%%D=@%%D!"
            set "@%%D=!@%%D! %%a "
)))
::检查是否可直达
for %%a in (!start_xl!) do for %%b in (!end_xl!) do if %%a==%%b set "路线=^"!start! !end!^""
if not "!路线!"=="" goto :metic
::计算换乘路线
set "查询表=^"!start!=!start_xl!^""
set "剩余交点表=!dd_list!"
:loop
for %%i in (!查询表!) do (
for /f "tokens=1* delims==" %%A in ("%%~i") do (
for %%a in (%%B) do (
    for %%b in (!剩余交点表!) do (
        for %%c in (!@%%b!) do (
            if %%a==%%c (
                set "转车点=!转车点! %%b"
                set "剩余查询表=!剩余查询表! ^"%%A %%b=!@%%b:%%c=!^""
                for %%d in (!end_xl!) do for %%e in (!@%%b!) do if %%e==%%d (
                    set "路线=!路线! ^"%%A %%b !end!^" "
)))))))
for %%a in (!剩余交点表!) do for %%b in (!转车点!) do set "剩余交点表=!剩余交点表:%%b=!"
set "查询表=!剩余查询表!"
set "剩余查询表="
set 最多换乘次数+=1
rem if !最多换乘次数! geq 5 goto :metic
rem 注释掉下面这句，使用上面这句可以找到更多换乘次数的路线。
if !路线!.==. goto :loop
::计算站点
:metic
if !路线!.==. echo,无法找到换乘路径&goto :eof
set /a xn=0
for %%a in (!路线!) do (
    set /a xn+=1
    set "线路_!xn!=%%~a"
    set "now="
    set "last="
    set /a 换乘次数_!xn!=0
    for %%a in (%%~a) do (
        set /a 换乘次数_!xn!+=1
        if defined now set "last=!now!"
        set "now=%%a"
        if defined last call :js !xn! !last! !now!
    )
    set /a 换乘次数_!xn!-=2
)
for /l %%i in (1,1,!xn!) do echo,线路%%i:"!线路_%%i: =--!"，换乘 !换乘次数_%%i! 次，途经 !num_%%i! 站
goto :eof
:js
for /f "tokens=1,2 delims==" %%a in ('set xl_') do (
    set "xl=%%b"
    if not "!xl:%2=!"=="!xl!" if not "!xl:%3=!"=="!xl!" (
        set /a n=0
        for %%x in (%%b) do (
            set /a n+=1
            if %%x.==%2. set /a st=n
            if %%x.==%3. set /a et=n
        )
        set /a num=st-et
        if !num! lss 0 set /a num=0-num
        set /a num_%1+=num
)   )
复制代码

请输入起点站-终点站:奥体中心 西直门
线路1:"奥体中心--北土城--海淀黄庄--西直门"，换乘 2 次，途经 12 站
线路2:"奥体中心--北土城--知春路--西直门"，换乘 2 次，途经 7 站
线路3:"奥体中心--北土城--芍药居--西直门"，换乘 2 次，途经 16 站
复制代码

统一格式为
城市名-gj.txt
X路(首班时间/末班时间/票价/是否单行线)：站点名-站点名...
复制代码

城市名-dt.txt
X线(票价)：站点名-站点名...
复制代码