Board logo

标题: [转载教程] SED单行脚本快速参考(sed1line) [打印本页]
作者: Batcher    时间: 2008-9-21 20:47     标题: SED单行脚本快速参考(sed1line)

  1. SED单行脚本快速参考（Unix 流编辑器）                       2005年12月29日

  2. 英文标题：USEFUL ONE-LINE SCRIPTS FOR SED (Unix stream editor)

  3. 原标题：HANDY ONE-LINERS FOR SED (Unix stream editor)

  4. 整理：Eric Pement  - 电邮：pemente[at]northpark[dot]edu         版本5.5

  5. 译者：Joe Hong     - 电邮：hq00e[at]126[dot]com

  6. 在以下地址可找到本文档的最新（英文）版本：

  7.    

  8. http://sed.sourceforge.net/sed1line.txt

  9.    

  10. http://www.pement.org/sed/sed1line.txt

  11. 其他语言版本：

  12.   中文          - 

  13. http://sed.sourceforge.net/sed1line_zh-CN.html

  14.   捷克语        - 

  15. http://sed.sourceforge.net/sed1line_cz.html

  16.   荷语          - 

  17. http://sed.sourceforge.net/sed1line_nl.html

  18.   法语          - 

  19. http://sed.sourceforge.net/sed1line_fr.html

  20.   德语          - 

  21. http://sed.sourceforge.net/sed1line_de.html

  22.   葡语          - 

  23. http://sed.sourceforge.net/sed1line_pt-BR.html

  24. 文本间隔：

  25. --------

  26. # 在每一行后面增加一空行

  27. sed G

  28. # 将原来的所有空行删除并在每一行后面增加一空行。

  29. # 这样在输出的文本中每一行后面将有且只有一空行。

  30. sed '/^$/d;G'

  31. # 在每一行后面增加两行空行

  32. sed 'G;G'

  33. # 将第一个脚本所产生的所有空行删除（即删除所有偶数行）

  34. sed 'n;d'

  35. # 在匹配式样“regex”的行之前插入一空行

  36. sed '/regex/{x;p;x;}'

  37. # 在匹配式样“regex”的行之后插入一空行

  38. sed '/regex/G'

  39. # 在匹配式样“regex”的行之前和之后各插入一空行

  40. sed '/regex/{x;p;x;G;}'

  41. 编号：

  42. --------

  43. # 为文件中的每一行进行编号（简单的左对齐方式）。这里使用了“制表符”

  44. # （tab，见本文末尾关于'\t'的用法的描述）而不是空格来对齐边缘。

  45. sed = filename | sed 'N;s/\n/\t/'

  46. # 对文件中的所有行编号（行号在左，文字右端对齐）。

  47. sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'

  48. # 对文件中的所有行编号，但只显示非空白行的行号。

  49. sed '/./=' filename | sed '/./N; s/\n/ /'

  50. # 计算行数 （模拟 "wc -l"）

  51. sed -n '$='

  52. 文本转换和替代：

  53. --------

  54. # Unix环境：转换DOS的新行符（CR/LF）为Unix格式。

  55. sed 's/.$//'                     # 假设所有行以CR/LF结束

  56. sed 's/^M$//'                    # 在bash/tcsh中，将按Ctrl-M改为按Ctrl-V

  57. sed 's/\x0D$//'                  # ssed、gsed 3.02.80，及更高版本

  58. # Unix环境：转换Unix的新行符（LF）为DOS格式。

  59. sed "s/$/`echo -e \\\r`/"        # 在ksh下所使用的命令

  60. sed 's/$'"/`echo \\\r`/"         # 在bash下所使用的命令

  61. sed "s/$/`echo \\\r`/"           # 在zsh下所使用的命令

  62. sed 's/$/\r/'                    # gsed 3.02.80 及更高版本

  63. # DOS环境：转换Unix新行符（LF）为DOS格式。

  64. sed "s/$//"                      # 方法 1

  65. sed -n p                         # 方法 2

  66. # DOS环境：转换DOS新行符（CR/LF）为Unix格式。

  67. # 下面的脚本只对UnxUtils sed 4.0.7 及更高版本有效。要识别UnxUtils版本的

  68. #  sed可以通过其特有的“--text”选项。你可以使用帮助选项（“--help”）看

  69. # 其中有无一个“--text”项以此来判断所使用的是否是UnxUtils版本。其它DOS

  70. # 版本的的sed则无法进行这一转换。但可以用“tr”来实现这一转换。

  71. sed "s/\r//" infile >outfile     # UnxUtils sed v4.0.7 或更高版本

  72. tr -d \r outfile        # GNU tr 1.22 或更高版本

  73. # 将每一行前导的“空白字符”（空格，制表符）删除

  74. # 使之左对齐

  75. sed 's/^[ \t]*//'                # 见本文末尾关于'\t'用法的描述

  76. # 将每一行拖尾的“空白字符”（空格，制表符）删除

  77. sed 's/[ \t]*$//'                # 见本文末尾关于'\t'用法的描述

  78. # 将每一行中的前导和拖尾的空白字符删除

  79. sed 's/^[ \t]*//;s/[ \t]*$//'

  80. # 在每一行开头处插入5个空格（使全文向右移动5个字符的位置）

  81. sed 's/^/     /'

  82. # 以79个字符为宽度，将所有文本右对齐

  83. sed -e :a -e 's/^.\{1,78\}$/ &/;ta'  # 78个字符外加最后的一个空格

  84. # 以79个字符为宽度，使所有文本居中。在方法1中，为了让文本居中每一行的前

  85. # 头和后头都填充了空格。 在方法2中，在居中文本的过程中只在文本的前面填充

  86. # 空格，并且最终这些空格将有一半会被删除。此外每一行的后头并未填充空格。

  87. sed  -e :a -e 's/^.\{1,77\}$/ & /;ta'                     # 方法1

  88. sed  -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/'  # 方法2

  89. # 在每一行中查找字串“foo”，并将找到的“foo”替换为“bar”

  90. sed 's/foo/bar/'                 # 只替换每一行中的第一个“foo”字串

  91. sed 's/foo/bar/4'                # 只替换每一行中的第四个“foo”字串

  92. sed 's/foo/bar/g'                # 将每一行中的所有“foo”都换成“bar”

  93. sed 's/\(.*\)foo\(.*foo\)/\1bar\2/' # 替换倒数第二个“foo”

  94. sed 's/\(.*\)foo/\1bar/'            # 替换最后一个“foo”

  95. # 只在行中出现字串“baz”的情况下将“foo”替换成“bar”

  96. sed '/baz/s/foo/bar/g'

  97. # 将“foo”替换成“bar”，并且只在行中未出现字串“baz”的情况下替换

  98. sed '/baz/!s/foo/bar/g'

  99. # 不管是“scarlet”“ruby”还是“puce”，一律换成“red”

  100. sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g'  #对多数的sed都有效

  101. gsed 's/scarlet\|ruby\|puce/red/g'               # 只对GNU sed有效

  102. # 倒置所有行，第一行成为最后一行，依次类推（模拟“tac”）。

  103. # 由于某些原因，使用下面命令时HHsed v1.5会将文件中的空行删除

  104. sed '1!G;h;$!d'               # 方法1

  105. sed -n '1!G;h;$p'             # 方法2

  106. # 将行中的字符逆序排列，第一个字成为最后一字，……（模拟“rev”）

  107. sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'

  108. # 将每两行连接成一行（类似“paste”）

  109. sed '$!N;s/\n/ /'

  110. # 如果当前行以反斜杠“\”结束，则将下一行并到当前行末尾

  111. # 并去掉原来行尾的反斜杠

  112. sed -e :a -e '/\\$/N; s/\\\n//; ta'

  113. # 如果当前行以等号开头，将当前行并到上一行末尾

  114. # 并以单个空格代替原来行头的“=”

  115. sed -e :a -e '$!N;s/\n=/ /;ta' -e 'P;D'

  116. # 为数字字串增加逗号分隔符号，将“1234567”改为“1,234,567”

  117. gsed ':a;s/\B[0-9]\{3\}\>/,&/;ta'                     # GNU sed

  118. sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta'  # 其他sed

  119. # 为带有小数点和负号的数值增加逗号分隔符（GNU sed）

  120. gsed -r ':a;s/(^|[^0-9.])([0-9]+)([0-9]{3})/\1\2,\3/g;ta'

  121. # 在每5行后增加一空白行 （在第5，10，15，20，等行后增加一空白行）

  122. gsed '0~5G'                      # 只对GNU sed有效

  123. sed 'n;n;n;n;G;'                 # 其他sed

  124. 选择性地显示特定行：

  125. --------

  126. # 显示文件中的前10行 （模拟“head”的行为）

  127. sed 10q

  128. # 显示文件中的第一行 （模拟“head -1”命令）

  129. sed q

  130. # 显示文件中的最后10行 （模拟“tail”）

  131. sed -e :a -e '$q;N;11,$D;ba'

  132. # 显示文件中的最后2行（模拟“tail -2”命令）

  133. sed '$!N;$!D'

  134. # 显示文件中的最后一行（模拟“tail -1”）

  135. sed '$!d'                        # 方法1

  136. sed -n '$p'                      # 方法2

  137. # 显示文件中的倒数第二行

  138. sed -e '$!{h;d;}' -e x              # 当文件中只有一行时，输入空行

  139. sed -e '1{$q;}' -e '$!{h;d;}' -e x  # 当文件中只有一行时，显示该行

  140. sed -e '1{$d;}' -e '$!{h;d;}' -e x  # 当文件中只有一行时，不输出

  141. # 只显示匹配正则表达式的行（模拟“grep”）

  142. sed -n '/regexp/p'               # 方法1

  143. sed '/regexp/!d'                 # 方法2

  144. # 只显示“不”匹配正则表达式的行（模拟“grep -v”）

  145. sed -n '/regexp/!p'              # 方法1，与前面的命令相对应

  146. sed '/regexp/d'                  # 方法2，类似的语法

  147. # 查找“regexp”并将匹配行的上一行显示出来，但并不显示匹配行

  148. sed -n '/regexp/{g;1!p;};h'

  149. # 查找“regexp”并将匹配行的下一行显示出来，但并不显示匹配行

  150. sed -n '/regexp/{n;p;}'

  151. # 显示包含“regexp”的行及其前后行，并在第一行之前加上“regexp”所

  152. # 在行的行号 （类似“grep -A1 -B1”）

  153. sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h

  154. # 显示包含“AAA”、“BBB”或“CCC”的行（任意次序）

  155. sed '/AAA/!d; /BBB/!d; /CCC/!d'  # 字串的次序不影响结果

  156. # 显示包含“AAA”、“BBB”和“CCC”的行（固定次序）

  157. sed '/AAA.*BBB.*CCC/!d'

  158. # 显示包含“AAA”“BBB”或“CCC”的行 （模拟“egrep”）

  159. sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d    # 多数sed

  160. gsed '/AAA\|BBB\|CCC/!d'                        # 对GNU sed有效

  161. # 显示包含“AAA”的段落 （段落间以空行分隔）

  162. # HHsed v1.5 必须在“x;”后加入“G;”，接下来的3个脚本都是这样

  163. sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'

  164. # 显示包含“AAA”“BBB”和“CCC”三个字串的段落 （任意次序）

  165. sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'

  166. # 显示包含“AAA”、“BBB”、“CCC”三者中任一字串的段落 （任意次序）

  167. sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d

  168. gsed '/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d'         # 只对GNU sed有效

  169. # 显示包含65个或以上字符的行

  170. sed -n '/^.\{65\}/p'

  171. # 显示包含65个以下字符的行

  172. sed -n '/^.\{65\}/!p'            # 方法1，与上面的脚本相对应

  173. sed '/^.\{65\}/d'                # 方法2，更简便一点的方法

  174. # 显示部分文本——从包含正则表达式的行开始到最后一行结束

  175. sed -n '/regexp/,$p'

  176. # 显示部分文本——指定行号范围（从第8至第12行，含8和12行）

  177. sed -n '8,12p'                   # 方法1

  178. sed '8,12!d'                     # 方法2

  179. # 显示第52行

  180. sed -n '52p'                     # 方法1

  181. sed '52!d'                       # 方法2

  182. sed '52q;d'                      # 方法3, 处理大文件时更有效率

  183. # 从第3行开始，每7行显示一次    

  184. gsed -n '3~7p'                   # 只对GNU sed有效

  185. sed -n '3,${p;n;n;n;n;n;n;}'     # 其他sed

  186. # 显示两个正则表达式之间的文本（包含）

  187. sed -n '/Iowa/,/Montana/p'       # 区分大小写方式

  188. 选择性地删除特定行：

  189. --------

  190. # 显示通篇文档，除了两个正则表达式之间的内容

  191. sed '/Iowa/,/Montana/d'

  192. # 删除文件中相邻的重复行（模拟“uniq”）

  193. # 只保留重复行中的第一行，其他行删除

  194. sed '$!N; /^\(.*\)\n\1$/!P; D'

  195. # 删除文件中的重复行，不管有无相邻。注意hold space所能支持的缓存

  196. # 大小，或者使用GNU sed。

  197. sed -n 'G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P'

  198. # 删除除重复行外的所有行（模拟“uniq -d”）

  199. sed '$!N; s/^\(.*\)\n\1$/\1/; t; D'

  200. # 删除文件中开头的10行

  201. sed '1,10d'

  202. # 删除文件中的最后一行

  203. sed '$d'

  204. # 删除文件中的最后两行

  205. sed 'N;$!P;$!D;$d'

  206. # 删除文件中的最后10行

  207. sed -e :a -e '$d;N;2,10ba' -e 'P;D'   # 方法1

  208. sed -n -e :a -e '1,10!{P;N;D;};N;ba'  # 方法2

  209. # 删除8的倍数行

  210. gsed '0~8d'                           # 只对GNU sed有效

  211. sed 'n;n;n;n;n;n;n;d;'                # 其他sed

  212. # 删除匹配式样的行

  213. sed '/pattern/d'                      # 删除含pattern的行。当然pattern

  214.                                        # 可以换成任何有效的正则表达式

  215. # 删除文件中的所有空行（与“grep '.' ”效果相同）

  216. sed '/^$/d'                           # 方法1

  217. sed '/./!d'                           # 方法2

  218. # 只保留多个相邻空行的第一行。并且删除文件顶部和尾部的空行。

  219. # （模拟“cat -s”）

  220. sed '/./,/^$/!d'        #方法1，删除文件顶部的空行，允许尾部保留一空行

  221. sed '/^$/N;/\n$/D'      #方法2，允许顶部保留一空行，尾部不留空行

  222. # 只保留多个相邻空行的前两行。

  223. sed '/^$/N;/\n$/N;//D'

  224. # 删除文件顶部的所有空行

  225. sed '/./,$!d'

  226. # 删除文件尾部的所有空行

  227. sed -e :a -e '/^\n*$/{$d;N;ba' -e '}'  # 对所有sed有效

  228. sed -e :a -e '/^\n*$/N;/\n$/ba'        # 同上，但只对 gsed 3.02.*有效

  229. # 删除每个段落的最后一行

  230. sed -n '/^$/{p;h;};/./{x;/./p;}'

  231. 特殊应用：

  232. --------

  233. # 移除手册页（man page）中的nroff标记。在Unix System V或bash shell下使

  234. # 用'echo'命令时可能需要加上 -e 选项。

  235. sed "s/.`echo \\\b`//g"    # 外层的双括号是必须的（Unix环境）

  236. sed 's/.^H//g'             # 在bash或tcsh中, 按 Ctrl-V 再按 Ctrl-H

  237. sed 's/.\x08//g'           # sed 1.5，GNU sed，ssed所使用的十六进制的表示方法

  238. # 提取新闻组或 e-mail 的邮件头

  239. sed '/^$/q'                # 删除第一行空行后的所有内容

  240. # 提取新闻组或 e-mail 的正文部分

  241. sed '1,/^$/d'              # 删除第一行空行之前的所有内容

  242. # 从邮件头提取“Subject”（标题栏字段），并移除开头的“Subject:”字样

  243. sed '/^Subject: */!d; s///;q'

  244. # 从邮件头获得回复地址

  245. sed '/^Reply-To:/q; /^From:/h; /./d;g;q'

  246. # 获取邮件地址。在上一个脚本所产生的那一行邮件头的基础上进一步的将非电邮

  247. # 地址的部分剃除。（见上一脚本）

  248. sed 's/ *(.*)//; s/>.*//; s/.*[: /'

  249. # 将每一行开头处的尖括号和空格删除（解除引用）

  250. sed 's/^> //'

  251. # 移除大部分的HTML标签（包括跨行标签）

  252. sed -e :a -e 's/]*>//g;/zipup.bat

  253. dir /b *.txt | sed "s/^\(.*\)\.TXT/pkzip -mo \1 \1.TXT/" >>zipup.bat

  254. 使用SED：Sed接受一个或多个编辑命令，并且每读入一行后就依次应用这些命令。

  255. 当读入第一行输入后，sed对其应用所有的命令，然后将结果输出。接着再读入第二

  256. 行输入，对其应用所有的命令……并重复这个过程。上一个例子中sed由标准输入设

  257. 备（即命令解释器，通常是以管道输入的形式）获得输入。在命令行给出一个或多

  258. 个文件名作为参数时，这些文件取代标准输入设备成为sed的输入。sed的输出将被

  259. 送到标准输出（显示器）。因此：

  260. cat filename | sed '10q'         # 使用管道输入

  261. sed '10q' filename               # 同样效果，但不使用管道输入

  262. sed '10q' filename > newfile     # 将输出转移（重定向）到磁盘上

  263. 要了解sed命令的使用说明，包括如何通过脚本文件（而非从命令行）来使用这些命

  264. 令，请参阅《sed & awk》第二版，作者Dale Dougherty和Arnold Robbins

  265. （O'Reilly，1997；http://www.ora.com），《UNIX Text Processing》，作者

  266. Dale Dougherty和Tim O'Reilly（Hayden Books，1987）或者是Mike Arst写的教

  267. 程——压缩包的名称是“U-SEDIT2.ZIP”（在许多站点上都找得到）。要发掘sed

  268. 的潜力，则必须对“正则表达式”有足够的理解。正则表达式的资料可以看

  269. 《Mastering Regular Expressions》作者Jeffrey Friedl（O'reilly 1997）。

  270. Unix系统所提供的手册页（“man”）也会有所帮助（试一下这些命令

  271. “man sed”、“man regexp”，或者看“man ed”中关于正则表达式的部分），但

  272. 手册提供的信息比较“抽象”——这也是它一直为人所诟病的。不过，它本来就不

  273. 是用来教初学者如何使用sed或正则表达式的教材，而只是为那些熟悉这些工具的人

  274. 提供的一些文本参考。

  275. 括号语法：前面的例子对sed命令基本上都使用单引号（'...'）而非双引号

  276. （"..."）这是因为sed通常是在Unix平台上使用。单引号下，Unix的shell（命令

  277. 解释器）不会对美元符（$）和后引号（`...`）进行解释和执行。而在双引号下

  278. 美元符会被展开为变量或参数的值，后引号中的命令被执行并以输出的结果代替

  279. 后引号中的内容。而在“csh”及其衍生的shell中使用感叹号（!）时需要在其前

  280. 面加上转义用的反斜杠（就像这样：\!）以保证上面所使用的例子能正常运行

  281. （包括使用单引号的情况下）。DOS版本的Sed则一律使用双引号（"..."）而不是

  282. 引号来圈起命令。

  283. '\t'的用法：为了使本文保持行文简洁，我们在脚本中使用'\t'来表示一个制表

  284. 符。但是现在大部分版本的sed还不能识别'\t'的简写方式，因此当在命令行中为

  285. 脚本输入制表符时，你应该直接按TAB键来输入制表符而不是输入'\t'。下列的工

  286. 具软件都支持'\t'做为一个正则表达式的字元来表示制表符：awk、perl、HHsed、

  287. sedmod以及GNU sed v3.02.80。

  288. 不同版本的SED：不同的版本间的sed会有些不同之处，可以想象它们之间在语法上

  289. 会有差异。具体而言，它们中大部分不支持在编辑命令中间使用标签（:name）或分

  290. 支命令（b,t），除非是放在那些的末尾。这篇文档中我们尽量选用了可移植性较高

  291. 的语法，以使大多数版本的sed的用户都能使用这些脚本。不过GNU版本的sed允许使

  292. 用更简洁的语法。想像一下当读者看到一个很长的命令时的心情：

  293.    sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d

  294. 好消息是GNU sed能让命令更紧凑：

  295.    sed '/AAA/b;/BBB/b;/CCC/b;d'      # 甚至可以写成

  296.    sed '/AAA\|BBB\|CCC/b;d'

  297. 此外，请注意虽然许多版本的sed接受象“/one/ s/RE1/RE2/”这种在's'前带有空

  298. 格的命令，但这些版本中有些却不接受这样的命令:“/one/! s/RE1/RE2/”。这时

  299. 只需要把中间的空格去掉就行了。

  300. 速度优化：当由于某种原因（比如输入文件较大、处理器或硬盘较慢等）需要提高

  301. 命令执行速度时，可以考虑在替换命令（“s/.../.../”）前面加上地址表达式来

  302. 提高速度。举例来说：

  303.    sed 's/foo/bar/g' filename         # 标准替换命令

  304.    sed '/foo/ s/foo/bar/g' filename   # 速度更快

  305.    sed '/foo/ s//bar/g' filename      # 简写形式

  306. 当只需要显示文件的前面的部分或需要删除后面的内容时，可以在脚本中使用“q”

  307. 命令（退出命令）。在处理大的文件时，这会节省大量时间。因此：

  308.    sed -n '45,50p' filename           # 显示第45到50行

  309.    sed -n '51q;45,50p' filename       # 一样，但快得多

  310. 如果你有其他的单行脚本想与大家分享或者你发现了本文档中错误的地方，请发电

  311. 子邮件给本文档的作者（Eric Pement）。邮件中请记得提供你所使用的sed版本、 

  312. 该sed所运行的操作系统及对问题的适当描述。本文所指的单行脚本指命令行的长

  313. 度在65个字符或65个以下的sed脚本〔译注1〕。本文档的各种脚本是由以下所列作

  314. 者所写或提供：

  315. Al Aab                               # 建立了“seders”邮件列表

  316. Edgar Allen                          # 许多方面

  317. Yiorgos Adamopoulos                  # 许多方面

  318. Dale Dougherty                       # 《sed & awk》作者

  319. Carlos Duarte                        # 《do it with sed》作者

  320. Eric Pement                          # 本文档的作者

  321. Ken Pizzini                          # GNU sed v3.02 的作者

  322. S.G. Ravenhall                       # 去html标签脚本

  323. Greg Ubben                           # 有诸多贡献并提供了许多帮助

  324. -------------------------------------------------------------------------

  325. 译注1：大部分情况下，sed脚本无论多长都能写成单行的形式（通过`-e'选项和`;'

  326. 号）——只要命令解释器支持，所以这里说的单行脚本除了能写成一行还对长度有

  327. 所限制。因为这些单行脚本的意义不在于它们是以单行的形式出现。而是让用户能

  328. 方便地在命令行中使用这些紧凑的脚本才是其意义所在。
复制代码




欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2