批处理之家 - Powered by Discuz! Board

标题: [文本处理] 怎样将IP修改为批处理命令？ [打印本页]

作者: qiuguoke 时间: 2011-5-23 00:44 标题: 怎样将IP修改为批处理命令？

一个文件夹下，有很多TXT文档，每个TXT文档里都只包含一个IP地址(每个TXT中的IP都不同)，假设某文档中的IP为 113.134.101.247
我要将所有TXT文档中的IP修改为下面的形式！

ipseccmd -w REG -p "plocy" -r "permit list" -f 113.134.101.247/255.255.255.255:*+0/255.255.255.255:5001:tcp -n PASS -x
ipseccmd -w REG -p "plocy" -r "permit list" -f 113.134.101.247/255.255.255.255:*+0/255.255.255.255:5002:tcp -n PASS -x
ipseccmd -w REG -p "plocy" -r "permit list" -f 113.134.101.247/255.255.255.255:*+0/255.255.255.255:5003:tcp -n PASS -x
ipseccmd -w REG -p "plocy" -r "permit list" -f 113.134.101.247/255.255.255.255:*+0/255.255.255.255:5109:tcp -n PASS -x

并将这个TXT修改为BAT文件，并运行后删除自身！

作者: mxxcgzxxx 时间: 2011-5-23 06:44

能不能给个文档样式，不知这个IP的具体位置在什么地方，句首还是中间？

作者: batman 时间: 2011-5-23 09:07

请楼主描述下你这样做的意图，不然本论坛不会提供任何帮助。。。

从代码上来看有疑似黑客行为。。。

作者: dennisle 时间: 2011-5-23 09:48

樓主應該是要將TXT文檔裡的IP列為允許連接他的 TCP:5001，5002，5003，5009

作者: qiuguoke 时间: 2011-5-23 09:56

能不能给个文档样式，不知这个IP的具体位置在什么地方，句首还是中间？
mxxcgzxxx 发表于 2011-5-23 06:44

谢谢您，TXT文档里只有一个IP地址，就在首句！

作者: qiuguoke 时间: 2011-5-23 09:57

请楼主描述下你这样做的意图，不然本论坛不会提供任何帮助。。。

从代码上来看有疑似黑客行为。。。
batman 发表于 2011-5-23 09:07

谢谢群主版主的帮助！
这个行命令的目的是允许文本里的IP连接自己本机的5001 5002 5003 5109端口是IPSEC策略不是黑客行为！！！

作者: qiuguoke 时间: 2011-5-23 09:58

樓主應該是要將TXT文檔裡的IP列為允許連接他的 TCP:5001，5002，5003，5009
dennisle 发表于 2011-5-23 09:48

正解。。。

作者: batman 时间: 2011-5-23 10:08

本帖最后由 batman 于 2011-5-23 12:49 编辑

改晕了,只能这样了:

@echo off
@echo off&setlocal enabledelayedexpansion
for %%a in (*.txt) do (
     set /p ip=<"%%a"
     (echo ipseccmd -w REG -p "plocy" -r "permit list" -f !ip!/255.255.255.255:*+0/255.255.255.255:5001:tcp -n PASS -x
      echo ipseccmd -w REG -p "plocy" -r "permit list" -f !ip!/255.255.255.255:*+0/255.255.255.255:5002:tcp -n PASS -x
      echo ipseccmd -w REG -p "plocy" -r "permit list" -f !ip!/255.255.255.255:*+0/255.255.255.255:5003:tcp -n PASS -x
      echo ipseccmd -w REG -p "plocy" -r "permit list" -f !ip!/255.255.255.255:*+0/255.255.255.255:5109:tcp -n PASS -x
      echo del /q ^%%0)>"%%a"
      ren "%%a" "%%~na.bat"
)
for %%a in (*.bat) do (
    if "%%~na" neq "%%~n0" "%%a"
    ping /n 2 127.1>nul
)  
复制代码

作者: CrLf 时间: 2011-5-23 13:55

@echo off&setlocal enabledelayedexpansion
title 任意键中断
if "%1"=="::" goto ping
start /b "" %0 ::
for %%a in (*.txt) do (
    set /p ip=<"%%a"
    (echo @echo off
    for %%b in (5001 5002 5003 5109) do (
        echo ipseccmd -w REG -p "plocy" -r "permit list" -f !ip!/255.255.255.255:*+0/255.255.255.255:%%b:tcp -n PASS -x
    )
    echo del /f %%0)>"%%a"
    ren "%%a" "%%~na.bat"
)
pause>nul
taskkill /f /t /fi "windowtitle eq 任意键中断" /im cmd.exe
taskkill /f /t /fi "windowtitle eq 管理员:  任意键中断" /im cmd.exe

:ping
for %%a in (*.bat) do (
    ping /n 2 127.1>nul
    if "%%~na" neq "%~n0" call "%%a"
)
exit
复制代码

作者: pows1122 时间: 2012-5-16 15:42

都太牛了新手路过可惜很多看不懂

欢迎光临批处理之家 (http://www.bathome.net/)