批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理怎样批量替换固定字符串？ [打印本页]

作者: qiuguoke 时间: 2011-5-22 23:37 标题: 批处理怎样批量替换固定字符串？

比如：
某个文件夹下有很多TXT文件，这些文件都包含特定字符串 aaa,bbb,ccc...我现在想批量替换所有文件中的所有aaa为字符串AAA，替换所有的bbb为字符串BBB，ccc为字符串CCC....并且批量将扩展名由TXT改为BAT，并执行这些BAT，原文件名不变！

注：不是批量替换大小写！！ aaa AAA bbb BBB....代表的是不同的字符串！！

作者: batman 时间: 2011-5-23 00:03

@echo off&setlocal enabledelayedexpansion
for %%a in (*.txt) do (
     (for /f "usebackq delims=" %%b in ("%%a") do  (
          set "str=%%b"
          for %%b in (aaa-AAA bbb-BBB ccc-CCC) do (
               for /f "tokens=1,2 delims=-" %%c in ("%%b") do set "str=!str:%%c=%%d!"
          )
          echo !str!
      ))>$
      move $ "%%a"&ren "%%a" "%%~na.bat"
)
      
          
复制代码

作者: 领航者 时间: 2011-5-23 09:43

2# batman

for %%b in (aaa-AAA bbb-BBB ccc-CCC)
括号中的格式看不懂,
第九行十行也看不懂

作者: CrLf 时间: 2011-5-23 13:33

简化一下：

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
	set tmp=%%a
	for %%b in ("aaa=AAA" "bbb=BBB" "ccc=CCC") do (
		set tmp=!tmp:%%~b!
	)
	echo;!tmp!
)
pause
复制代码

不支持判断大小写字母

欢迎光临批处理之家 (http://www.bathome.net/)