aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa
ccccccccccccccccccccccccccccccccccccccc
eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee
ggggggggggggggggggggggggggggggggggggggg
wwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwww
zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz
复制代码

hhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhh
iiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiii
jjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjj
nnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnn
复制代码

aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa
hhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhhh
ccccccccccccccccccccccccccccccccccccccc
iiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiii
eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee
jjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjjj
ggggggggggggggggggggggggggggggggggggggg
nnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnnn
wwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwww
zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type 11.txt') do (
   set /a m+=1
   set "home!m!=%%a"
)
for /f "delims=" %%b in ('type 12.txt') do (
   set /a n+=1
   set "bat!n!=%%b"
)
if %m% gtr %n% (
   for /l %%c in (1 1 %m%) do (
      if not "!home%%c!"=="" echo !home%%c!
      if not "!bat%%c!"=="" echo !bat%%c!
   )
) else (
   for /l %%d in (1 1 %n%) do (
      if not "!home%%d!"=="" echo !home%%d!
      if not "!bat%%d!"=="" echo !bat%%d!
   )
)
pause
复制代码

@echo off
for /f "delims=" %%i in (1.txt) do set /a n+=1&call,set "_%%n%%=%%i"
for /f "delims=" %%i in (2.txt) do set /a m+=1&call,set ".%%m%%=%%i"
if %n% gtr %m% (set "num=%n%") else (set "num=%m%")
for /l %%i in (1,1,%num%) do (
     if defined _%%i call,echo %%_%%i%%
     if defined .%%i call,echo %%.%%i%%
)
pause>nul
复制代码

@echo off
set "n=-1"&set "flag=a"
:begin
set /a n+=1
if %n% equ 0 (set "m=") else (set "m=skip=%n%")
for /f "%m% delims=" %%i in (1.txt) do echo %%i&if defined flag goto next
set no=a
:next
for /f "%m% delims=" %%i in (2.txt) do echo %%i&goto begin
if not defined no set "flag="&goto begin
pause>nul
复制代码

 
@echo off&set n=-1
for /f "delims=" %%a in (1.txt) do (
set/a n+=1
set flag=
if not defined faith call :lp %%a
if not defined flag echo %%a
)
:lp
if "%1" equ "" set/a n+=1
set m=skip=%n%
if "%m%" equ "skip=0" set "m="
for /f "%m% delims=" %%a in (2.txt) do if "%1" neq "" (echo %1&echo %%a&set flag=a&goto :eof) else echo %%a
set faith=faith
if "%1" equ "" pause
复制代码

@echo off
findstr .* 1.txt>_1.txt
setlocal enabledelayedexpansion
for /f "delims="  %%i in (2.txt) do (
    set /a num+=1
    echo !num!:%%i
    findstr /b /i "!num!:" _1.txt
)
del /q _1.txt
pause
复制代码

@echo off
:: 生成临时文件，主要是为了获得 行数:行内容 格式的文本
findstr /n .* 1.txt>_1.txt
findstr /n .* 2.txt>_2.txt

:: 获取各自的总行数
for /f "delims=:" %%i in (_1.txt) do set num_1=%%i
for /f "delims=:" %%i in (_2.txt) do set num_2=%%i

:: 比较行数谁多谁少
set num=%num_1%
set file_1=_1.txt&set file_2=_2.txt
if %num_1% geq %num_2% (
    set num=%num_2%
    set file_1=_2.txt&set file_2=_1.txt
)

:: 以行数少的文本为标准，交叉输出两文本的同行内容
for /f "tokens=1* delims=:" %%i in (%file_1%) do (
    echo %%i:%%j
    findstr /b /i "%%i:" %file_2%
)

:: 对多出的行内容，一次性输出，减少了对比次数，从而提高效率
more +%num% %file_2%
del /q _1.txt _2.txt
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set "num=0"
for %%a in (1.txt 2.txt) do (
    for /f "delims=" %%i in (%%a) do (
        set /a n+=1
        if !n! gtr !num! set "num=!n!"
        set /p=%%i <nul>>temp.txt
    )
    echo.>>temp.txt&set "n=0"
)
:lp
set /a n+=1
for /f "tokens=%n%" %%i in (temp.txt) do echo %%i
if %n% neq %num% goto lp
del /q temp.txt&pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set m=-1
for /f %%i in (1.txt) do set /a m+=2&set _!m!=%%i
for /f %%j in (2.txt) do set /a n+=2&set _!n!=%%j
if %m% gtr %n% (set max=%m%) else (set max=%n%)
for /l %%k in (1 1 %max%) do (
    if defined _%%k call,echo %%_%%k%%
)
pause
复制代码

 
@echo off&setlocal enabledelayedexpansion
for /f "delims="  %%a in (1.txt) do (set /a n+=1&set #!n!=%%a)
for /f "delims=" %%a in (2.txt) do (
    set/a m+=1
    echo %%a
    if defined #!m! for %%b in (!m!) do echo !#%%b!
)
set/a m+=1
for /l %%a in (!m!,1,!n!) do echo !#%%a!
复制代码

@echo off
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9]\]"^|sort') do echo.%%b >>out.txt
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9][0-9]\]"^|sort') do echo.%%b >>out.txt

pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type 1.txt') do set /a a+=1
for /f "delims=" %%a in ('type 2.txt') do set /a b+=1
set /a t1+=!a!-!b!
set /a t2+=!b!-!a!
for /f "delims=" %%a in ('type 1.txt') do (
set m=
set /a n+=1
for /f "delims=" %%b in ('type 2.txt') do (
set /a m+=1
if "!n!" == "!m!" (
echo %%a
echo %%b
)
)
)
if !a! gtr !b! more 1.txt +!t1!
if !a! lss !b! more 2.txt +!t2!
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set/a n=0,m=0
for /f "delims=" %%a in (2.txt) do set/a n+=1&set #!n!=%%a
for /f "delims=" %%a in (1.txt) do (
set/a m+=1
if defined #!m! (echo %%a&call echo %%#!m!%%) else echo %%a
)
set /a m+=1
if !n! gtr !m! for /l %%i in (!m!,1,!n!) do echo !#%%i!

pause
复制代码

for /l %%i in (1,1,40) do (
echo A:%%i >>a.txt
echo B:%%i>>b.txt
)
复制代码

@echo off
set /p line1=<1.txt&set /p line2=<2.txt
echo %line1%&echo %line2%
:loop
set /a lines+=1
set erl=0
for /f "skip=%lines%" %%a in (1.txt) do echo %%a&set /a erl+=1&goto loop_1
:loop_1
for /f "skip=%lines%" %%a in (2.txt) do echo %%a&goto loop
if %erl%==0 (pause) else (goto loop)
复制代码

@echo off
for /f %%a in (1.txt) do echo %%a&for /f %%b in (2.txt) do echo %%b&goto loop
:loop
set /a lines+=1
set erl=0
for /f "skip=%lines%" %%a in (1.txt) do echo %%a&set /a erl+=1&goto loop_1
:loop_1
for /f "skip=%lines%" %%a in (2.txt) do echo %%a&goto loop
if %erl%==0 (pause) else (goto loop)
复制代码

for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9][0-9][0-9]\]"^|sort') do echo.%%b >>out.txt

 
复制代码

@(for /f "tokens=1* delims=: " %%a in ('fc /lb10000 /n ?.txt %SystemDrive%\io.sys^|find ": "^|sort') do @echo.%%b)>out2.txt
复制代码

@echo off
for %%f in (1.txt 2.txt) do findstr $ %%f? > %temp%\~%%~nf.%~n0
(for /f "tokens=2* delims=:" %%a in ('fc /lb10000 /n %temp%\~*.%~n0 %SystemDrive%\io.sys^|find ": "^|sort') do echo.%%b)>out3.txt
del %temp%\~*.%~n0
复制代码

@echo off
setlocal enabledelayedexpansion
set "xp=goto :eof"
for /f "delims=" %%i in (1.txt) do (set "me=%%j"&echo %%i&call :a)
set xp=&set vs=pause
goto a
:a
for /f "%a% delims=" %%j in (2.txt) do (echo %%j&set /a b+=1&set a=skip=!b!
%xp%)
%vs%
复制代码

@echo off&setlocal enabledelayedexpansion
::先获取行数并把 行数较大的文本设为和t1另一个为t2
for %%a in ('sed "$=" a.txt') do (
	for %%b in ('sed "$=" b.txt') do (
		if %%a gtr %%b (
			set "t1=a.txt" 
			set "t2=b.txt" 
		) else (			
				set "t1=b.txt" 
				set "t2=a.txt"
			)
	)
)
::交叉输出t1和t2
for /f "delims=" %%i in (!t1!) do (
	set /a n+=1
	echo %%i
	for /f "tokens=1,* delims=:" %%j in ('findstr /n ".*" !t2!') do (
		if %%j equ !n! echo %%k
	)
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1 delims=:" %%i in ('findstr /n .* a.txt') do set num1=%%i
for /f "tokens=1 delims=:" %%i in ('findstr /n .* b.txt') do set num2=%%i
if !num1! geq !num2! ( goto start
  ) else ( 
  ren  a.txt c.txt
  ren  b.txt a.txt
  ren  c.txt b.txt
)
:start
set /a line=0
for /f "delims=" %%a in (a.txt) do (
    echo %%a 
    set /a c=0
    for /f "delims=" %%b in ('more +!line! "b.txt"') do (
    set /a c+=1 
    if !c! equ 1 echo %%b
    )
    set /a line+=1
)
pause>nul
复制代码

@echo off
(for /f "delims=" %%a in ('findstr /n .* a.txt') do echo [%%a)>ab.txt
find /v /n "" b.txt|more>>ab.txt +2
for /f "tokens=1* delims=:]" %%a in ('sort ab.txt') do echo;%%b
pause
复制代码

@echo off
findstr /n .* 1.txt>tmp1
find /n /v "" 2.txt|more>tmp2 +2
for /f "tokens=2*delims=]:" %%a in ('fc /lb1000 /n tmp1 tmp2^|sort') do echo;%%b
del /q tmp?
pause
复制代码

@echo off
(for /f "delims=" %%a in (1.txt) do (
    endlocal
    echo;%%a
    setlocal enabledelayedexpansion
    set /p t2=
    if defined t2 echo;!t2!
))<2.txt>合并.txt
::由于可以有两个不同的输入来源并存，所以双文本合并就成为轻而易举的事了
复制代码

@echo off&setlocal enabledelayedexpansion
(for /l %%a in (1,1,50) do set /p n%%a=)<1.txt
(for /l %%a in (1,1,50) do set /p m%%a=)<2.txt
for /l %%a in (1,1,50) do (
    if not "!n%%a!"=="" echo;!n%%a!
    if not "!m%%a!"=="" echo;!m%%a!
)
pause
复制代码

@echo off & setlocal enabledelayedexpansion
cd /d %~dp0
::思路：通过行数定位结合more +n命令。
set /a nn=0
for /f "delims=" %%i in (1.txt) do (
	echo;%%i
	call :lp !nn! & set /a "nn+=1"

)
pause>nul & goto :eof


:lp
::more 第一行是以0计数开始 
for /f "delims=" %%x in ('more +%1 2.txt') do echo;%%x & goto :eof
复制代码

@echo off
set /a m=1000,n=1001
setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do set /a m+=2&set #!m!=%%a
for /f "delims=" %%b in (b.txt) do set /a n+=2&set #!n!=%%b
for /f "tokens=2 delims==" %%c in ('set #') do echo %%c
pause
复制代码