@echo off&title 输出任意个字符的排列组合
set/p str=输入字符，并用空格隔开
rem ------------------
rem 你的代码
复制代码

@echo off
call:perm "a b c xy z"
pause

:perm <"c1 c2 ..."> // code by plp
setlocal enabledelayedexpansion&set "s=%~1 "
if "!s: =!" == ""  (echo %~2)else for %%b in (%~1)do call:perm "!s:%%b =!" "%~2 %%b"
endlocal&goto:eof
复制代码

@echo off&setlocal enabledelayedexpansion
call:perm "a b c xy z"
pause

:perm <"c1 c2 ..."> // code by plp
setlocal&set "s=%~1 "&if "!s: =!" == ""  (echo %~2)else for %%b in (%~1)do call:perm "!s:%%b =!" "%~2 %%b"
复制代码

@echo off
call:perm "< & > plp |"
pause

:perm <"s1 s2 ..."> 
setlocal enabledelayedexpansion&set "s= %~1"&for /f "tokens=*" %%a in ("%~1")do Set "ss=%%a"
if "!s: =!" == ""  (echo "%~2 ") else for %%b in ("!ss: =" "!")do call:perm "!s: %%~b=!" "%~2 %%~b"
endlocal&goto:eof
复制代码

@echo off&setlocal enabledelayedexpansion
call:perm "< & > plp |"
pause

:perm <"s1 s2 ..."> 
setlocal&set "s= %~1"&for /f "tokens=*" %%a in ("%~1")do Set "ss=%%a"
if "!s: =!" == ""  (echo "%~2 ") else for %%b in ("!ss: =" "!")do call:perm "!s: %%~b=!" "%~2 %%~b"
复制代码

@echo off
setlocal enabledelayedexpansion
set /p inp="仅支持排列几个普通字符，不要乱输哦:"
call :func "%inp%" ""
pause
exit

:func
if "%~1"=="" (echo _%~2 &goto :eof)
setlocal
set strnow=%~1
set /a lp=0,lpb=lp+1
 :lp
  call :func "!strnow:~0,%lp%!!strnow:~%lpb%!" "%~2!strnow:~%lp%,1!"
  if not "!strnow:~%lpb%!"=="" (
   set /a lp+=1,lpb=lp+1
   goto :lp
  )
endlocal
复制代码

@echo off
call :func "abcd" ""
pause &exit

:func
 setlocal
 if %1=="" (
    if not %2=="" (echo %2)
    goto :eof
 )
 set strnow=%~1
   call :func "%strnow:~1%" "%~2%strnow:~0,1%"
   call :func "%strnow:~1%" "%~2"
 endlocal
复制代码

@echo off &setlocal enabledelayedexpansion

set element=a b c

:gettitle
for %%x in (%element%) do (
  set "fo=for %%%%x in ("%%x" "") do (!fo!"
  set end="!end!)"
  set result=!result!%%~%%x
)

%fo%
  echo "%result%"
%end:"=%
pause
复制代码

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set "str=a b c d e f"
for %%i in (%str%) do (
    set /a n+=1,_%%i=n
)
echo, !str!
for /l %%a in (1,1,10000000) do (
    set "last="&set "flag="&set "pos=0"
    for %%b in (!str!) do (
        set /a pos+=1
        if defined last (
            set /a n1=_%%b,n2=_!last!
            if !n1! gtr !n2! set flag=!last! !pos!
            set "last=%%b"
        ) else (
            set "last=%%b"
        )
    )
    if not defined flag call :end %%a
    for /f %%b in ("!flag!") do for %%c in (!str!) do if !_%%c! gtr !_%%b! set "th=%%c"
    for /f "tokens=1,3" %%b in ("!flag! !th!") do (
        set "temp=!str:%%b=#!"
        set "temp=!temp:%%c=%%b!"
        set "str=!temp:#=%%c!"
    )
    set "ppos="&set "cut1="&set "cut2="&set "array="
    for %%b in (!str!) do (
        set /a ppos+=1
        for /f "tokens=2" %%c in ("!flag!") do (
            if !ppos! geq %%c (
                set "cut2=!cut2! %%b"
            ) else (
                set "cut1=!cut1! %%b"
            )
        )
    )
    for %%i in (!cut2!) do (
        set "array=%%i !array!"
        for %%j in (!array!) do (
            if %%i gtr %%j (
                set "array=!array:%%i=#!"
                set "array=!array:%%j=%%i!"
                set "array=!array:#=%%j!"
            )
        )
    )
    set str=!cut1! !array!
    echo,!str!
)
:end
echo,一共%1个排列.
pause>nul&exit
复制代码

@echo off&SETLOCAL ENABLEDELAYEDEXPANSION
set "str=1 11 12 a ab acd"
set time1=!time!
for %%i in (%str%) do (
    set /a n+=1,_@%%i@=n
    set "tstr=!tstr! @%%i@"
)
set "str=!tstr!"
echo,!str:@=!
for /l %%a in (1,1,10000000) do (
    set "last="&set "flag="&set "pos=0"
    for %%b in (!str!) do (
        set /a pos+=1
        if defined last (
            set /a n1=_%%b,n2=_!last!
            if !n1! gtr !n2! set flag=!last! !pos!
            set "last=%%b"
        ) else (
            set "last=%%b"
        )
    )
    if not defined flag call :end %%a
    for /f %%b in ("!flag!") do for %%c in (!str!) do if !_%%c! gtr !_%%b! set "th=%%c"
    for /f "tokens=1,3" %%b in ("!flag! !th!") do (
        set "temp=!str:%%b=#!"
        set "temp=!temp:%%c=%%b!"
        set "str=!temp:#=%%c!"
    )
    set "ppos="&set "cut1="&set "cut2="&set "array="
    for %%b in (!str!) do (
        set /a ppos+=1
        for /f "tokens=2" %%c in ("!flag!") do (
            if !ppos! geq %%c (
                set "cut2=!cut2! %%b"
            ) else (
                set "cut1=!cut1! %%b"
            )
        )
    )
    for %%i in (!cut2!) do (
        set "array=%%i !array!"
        for %%j in (!array!) do (
            if %%i gtr %%j (
                set "array=!array:%%i=#!"
                set "array=!array:%%j=%%i!"
                set "array=!array:#=%%j!"
            )
        )
    )
    set str=!cut1! !array!
    echo,!str:@=!
)
:end
echo,一共%1个排列. !time1!--^>!time!
pause>nul&exit
复制代码

@echo off
set a=%%a&set b=%%b&set c=%%c
set "fo=for %a% in (a b c) do for %b% in (a b c) do for %c% in (a b c) do if not %a%==%b% if not %b%==%c% if not %a%==%c% echo %a%%b%%c%"
%fo%
复制代码

@echo off&setlocal EnableDelayedExpansion
call:makefun _perm "a b c d xy"
%_perm%
pause&exit

:makefun <funname> <"charlist">
Set n=-1&Set s0=%~2&Set p=&set f=&for %%a in (%~2)do Set/a n+=1
for /l %%a in (0 1 %n%)do (Set/a m=%%a+1
Set "f=!f!&for %%%%a in (^!s%%a^!)do Set s!m!=^!s%%a:%%%%a=^!"
Set p=!p! %%%%a)
set %1=!f:~1,-15!ECHO !p!&goto:eof
复制代码

@echo off
call :func "abcdefghijklmnopqrstuvwxyz" "" 0
pause &exit

:func
    setlocal
    set /a v=%3
    if %v% equ 3 (echo %~2 &goto :eof)
    if %1  == "" (goto :eof)
    set strnow=%~1
    call :func "%strnow:~1%" "%~2%strnow:~0,1%" %v%+1
    call :func "%strnow:~1%" "%~2" %v%
    endlocal
复制代码

@echo off &setlocal enabledelayedexpansion
set alphabet=abcdefghijklmnopqrstuvwxyz
for /l %%a in (0,1,25) do set eles=!eles! !alphabet:~%%a,1!
call :func "%eles%" "" 0
pause &exit

:func
    setlocal
    set /a v=%3
    if %v% equ 3 ( echo %~2 &goto :eof)
    set eles=%~1
    for %%a in ( %eles% ) do call :func "!eles:%%a=!" "%~2%%a" %v%+1
    endlocal
复制代码