@echo off

set begin=%date% %time%
setlocal enabledelayedexpansion

set www=http://www.pharmnet.com.cn/search/template/yljg_index.htm

md html 2>nul
md txt 2>nul
del /a /f /q txt\*.txt 2>nul
curl -o html\index.html %www%


for /f "delims=<>= tokens=7" %%a in ('findstr /i "search\/index\.cgi\?c1=19" html\index.html') do (
    cls
    title 正在下载 【%%a】 数据
    md "html\%%a" 2>nul
    cd.>txt\%%a.txt
    pushd "html\%%a"
    curl -o 1.html "http://www.pharmnet.com.cn/search/index.cgi?c1=19&c2=%%a&p=1"
    for /f "delims=<> tokens=10" %%b in ('findstr /i ":共有.*页" 1.html') do (
        curl -o #1.html "http://www.pharmnet.com.cn/search/index.cgi?p=[2-%%b]&cate1=&terms=&c1=19&c2=%%a"
    )
    title 正在转换 【%%a】 数据文件格式
    htox32c /ip /O0 *.html
    title 正在筛选 【%%a】 数据
    echo;&echo 正在筛选 【%%a】 数据，请稍候...
    (for %%c in (*.txt) do (
        for /f "skip=18 tokens=*" %%d in ('findstr /iv "\* 共有 免责声明 关于公司 版权所有" "%%c"') do (
            echo;%%d
        )
    ))>..\..\txt\%%a.txt
    del /a /f /q *.txt
    popd
)

cls
title 提取数据
echo;&echo;&echo         正在按照指定格式提取数据
echo;&echo             请耐心等待...
pushd txt
cd.>tmp
for %%i in (*.txt) do copy /b tmp+%%i tmp>nul
set num=0
(for /f "delims=" %%i in ('findstr /v "联系电话" tmp') do (
    set /a num+=1
    if !num! equ 1 set name=%%i
    if !num! equ 2 (
        set "str=%%i"
        set "postcode=!str:*邮　　编：  =!"
        call set "address=%%str:  邮　　编：  !postcode!=%%"
        if not defined postcode set postcode=不详
        set "address=!address:医院地址：  =!"
        if not defined address set address=不详
        echo 医院名称：!name!
        echo 医院地址：!address!
        echo 邮编：!postcode!
        echo;
        set num=0
    )
))>result
move result ..\处理结果.txt
popd

cls
title 处理完毕
echo;&echo;&echo         已经处理完毕，按任意键打开处理结果
echo 开始时间：%begin%
echo 结束时间：%date% %time%
pause>nul
start 处理结果.txt
复制代码