[文本处理] 批处理如何实现首次/第一次运行重命名文件，再次/第二次运行则还原文件名？

xiewei120120

本人求大牛们给个批使望得到下面的执行效果：
目标文件c:\test\1.gpg，要求使用批处理1.bat重新将1.gpg命名为123.rar.后再运行  1.bat又改回到原来的1.gpg.也就是说使用一个批处理第一次运行把目标文件改名第二次再运行又还原原来的文件名。

[ 本帖最后由 xiewei120120 于 2010-5-28 15:18 编辑 ]

hanyeguxing

@echo off
findstr /b "::#" "%~fs0">nul&&ren "c:\test\123.rar" "1.gpg"||ren "c:\test\1.gpg" "123.rar"&>>"%~fs0" (echo.&echo.::#)
复制代码

第一次运行时，因为批处理内不存在::#的行而执行ren "c:\test\1.gpg" "123.rar"，同时执行echo.&echo.::#输出到批处理中。
以后再运行时，因存在行::#而执行ren "c:\test\123.rar" "1.gpg"。
注意：本批处理只适用于操作两次。

[ 本帖最后由 hanyeguxing 于 2010-5-28 16:37 编辑 ]

xiewei120120

批的功能太强大了谢谢大牛

这个批确实能达到我要求的功能但我测试后发现批在以后的运行后会自动写入::#  这样的话这个批会越来越大,可不可以改进下,在能达到求后不再,生成的的::#.有请 寒夜孤星 兄弟再改进下

[ 本帖最后由 xiewei120120 于 2010-5-28 20:14 编辑 ]

hanyeguxing

1，这个批处理只会写入1次::#
2，

@echo off
if exist han.h (set/p p=<han.h) else set p=0
if %p%==0 (echo.1) else echo.0)>han.h
if %p%==0 (ren "c:\test\1.gpg" "123.rar") else ren "c:\test\123.rar" "1.gpg"
复制代码

第奇数次运行时，执行ren "c:\test\1.gpg" "123.rar"。
第偶数次运行时，执行ren "c:\test\123.rar" "1.gpg"。
han.h为运行记录文件，使用时间内不能删除。删除后从新开始计算。

del

@echo off
set "FilePath=c:\test\1.gpg"
set "NewName=123.rar"

for /f "tokens=1,2 delims=|" %%a in ("%FilePath%|%NewName%") do (
    if exist "%%a" (
        ren "%%a" "%%b"
    ) else (
        if exist "%%~dpa%%b" ren "%%~dpa%%b" "%%~nxa"
    )
)
复制代码

[ 本帖最后由 del 于 2010-5-29 08:52 编辑 ]

xiewei120120

由于本人水平太差,但现在又有工作生活上的对批的特殊要求所以希望大哥级兄弟们再帮小弟写这样一个批,要求:
1要求一个批隐藏运行,
2:监视QQ进程如果发现有此进程运行则断开网络,如果进程退出则恢复网络

[ 本帖最后由 xiewei120120 于 2010-5-29 11:43 编辑 ]

小波子

这实现很简单.但是如果把QQ重命名一下的话.进程里就会有QQ.exe进程了

小波子

@echo off
tasklist >> a.txt
type a.txt|find /i "qq.exe" && taskkill /f /im qq.exe || echo 没有
pause

xiewei120120

原帖由 小波子 于 2010-5-29 11:52 发表
@echo off
tasklist >> a.txt
type a.txt|find /i "qq.exe" && taskkill /f /im qq.exe || echo 没有
pause

这个批应是查到到QQ的进程并终止,但我想要的是随时监视这个QQ进程只要有就断网,如进程退出了则恢复网络