[系统相关] [原创批处理]Windows11设置工具箱

smss

数据源参考https://learn.microsoft.com/zh-cn/windows/apps/develop/launch/launch-settings-app

@echo off&setlocal enabledelayedexpansion&title Windows系统设置工具箱&color 0B
:: 综合配置数据源
set "main_menu=系统核心设置 设备与连接 个性化配置 账户与安全 隐私控制 更新维护 高级工具"
:: 系统核心设置
set "menu1=显示设置|display 电源管理|powersleep 存储感知|storagesense 平板模式|tabletmode 系统信息|about 多任务处理|multitasking 声音设置|sound"
:: 设备与连接
set "menu2=蓝牙设备|bluetooth 打印机扫描仪|printers 已连接设备|connecteddevices 移动热点|network-mobilehotspot USB管理|usb 输入法设置|regionlanguage-chsime-pinyin"
:: 个性化配置
set "menu3=桌面背景|personalization-background 主题管理|themes 锁屏界面|lockscreen 颜色方案|colors 开始菜单|personalization-start 任务栏设置|taskbar"
:: 账户与安全
set "menu4=账户信息|yourinfo 登录选项|signinoptions 动态锁|signinoptions-dynamiclock 生物识别|signinoptions-launchfaceenrollment 企业访问|workplace 同步设置|sync"
:: 隐私控制
set "menu5=位置权限|privacy-location 摄像头|privacy-webcam 麦克风|privacy-microphone 语音输入|privacy-speechtyping 日历权限|privacy-calendar 联系**限|privacy-contacts"
:: 更新维护
set "menu6=系统更新|windowsupdate 更新选项|windowsupdate-options 激活状态|activation 备份恢复|backup 存储清理|storagepolicies 系统恢复|recovery"
:: 高级工具
set "menu7=开发者模式|developers 安全中心|windowsdefender 高级显示|display-advancedgraphics 网络诊断|network-status 代理设置|network-proxy 输入法高级|regionlanguage-chsime-pinyin-udp"
 
:MAIN
call :DrawMenu "main" "Windows 系统设置工具箱" 8 退出
if "%sel%"=="退出" exit
 
:: 动态菜单处理
set "current_menu=menu%sel%"
set "content=!%current_menu%!"
set /a sub_count=0
for %%i in (!content!)do set /a sub_count+=1
set /a max_sub=sub_count + 1
call :DrawMenu "sub" "!content!" !max_sub! 返回
goto MAIN
 
:DrawMenu
set "type=%~1"
set "content=%~2"
set /a max=%~3
set "exit_cmd=%~4"
 
:: 界面生成
cls
echo ================================
echo    %type% 菜单
echo ================================
set /a count=0
 
if "%type%"=="main" (
    for %%i in (%main_menu%)do (
        set /a count+=1
        echo !count!. %%i
    )
) else (
    for %%i in (!content!)do (
        set /a count+=1
        for /f "tokens=1* delims=|" %%a in ("%%i")do (
            echo !count!. %%a
            set "cmd!count!=%%b"
        )
    )
)
 
:: 退出项处理
if %max% gtr 0 (
    echo %max%. %exit_cmd%
    set "exit_num=%max%"
)
 
:: 用户输入
:input
set "choices="
for /l %%n in (1 1 %count%)do set "choices=!choices!%%n"
if defined exit_num set "choices=!choices!!exit_num!"
echo 可选编号：%choices%
 
choice /c %choices% /n /m "请选择操作编号："
set /a sel=!ERRORLEVEL!
 
:: 执行逻辑
if defined exit_num (
    if !sel! equ %exit_num% (
        if "%type%"=="main" (exit)else goto :eof
    )
)
 
if "%type%"=="main" (
    goto :eof
) else (
    if defined cmd!sel! (
        start ms-settings:!cmd%sel%!
    ) else (
        echo 错误: 无效选项[!sel!]
        timeout /t 2 >nul
    )
)
goto inputCOPY

@echo off&setlocal enabledelayedexpansion&title Windows11设置工具箱&color 0B&set "prompt=账户与登录管理 隐私与权限控制 网络与连接配置 系统优化与维护 个性化与显示设置 开发者与高级功能"
:M
cls
echo ================================
echo    Windows 系统设置直达工具
echo ================================
call :C prompt
echo !n!. 退出
call :CHOICE !e!!n!
goto :%ERRORLEVEL%
if %ERRORLEVEL%==7 exit
:1
set "options=signinoptions signinoptions-dynamiclock signinoptions-launchfaceenrollment signinoptions-launchfingerprintenrollment yourinfo sync emailandaccounts"
set "items=登录选项（PIN/生物识别） 动态锁设置 面部识别设置 指纹录入设置 账户信息查看 同步设置 应用账户管理"
goto :SUB
:2
set "options=privacy-microphone privacy-webcam privacy-location privacy-calendar privacy-contacts privacy-speechtyping"
set "items=麦克风权限 摄像头权限 定位服务 日历访问 联系**限 语音输入权限"
goto :SUB
:3
set "options=network-status network-proxy network-mobilehotspot network-cellular regionlanguage-chsime-pinyin regionlanguage-chsime-wubi"
set "items=网络状态 代理设置 移动热点 蜂窝网络 拼音输入法 五笔输入法"
goto :SUB
:4
set "options=windowsupdate windowsupdate-options activation storagesense storagepolicies recovery"
set "items=系统更新检查 高级更新设置 激活状态查看 存储空间清理 文件清理策略 恢复选项"
goto :SUB
:5
set "options=personalization-background themes colors taskbar personalization-start"
set "items=桌面壁纸设置 主题管理 窗口颜色调整 任务栏设置 开始菜单布局"
goto :SUB
:6
set "options=developers windowsdefender recovery display-advancedgraphics regionlanguage-chsime-pinyin-udp regionlanguage-chsime-wubi-udp"
set "items=开发者模式 安全中心 系统恢复选项 高级显示设置 拼音高级设置 五笔高级设置"
goto :SUB
:SUB
cls
echo ================================
call :JQ %ERRORLEVEL% prompt "echo ●▽●. "
echo ================================
call :C items
echo !n!. 返回主菜单
call :CHOICE !e!!n!
if %ERRORLEVEL%==!n! goto M
call :JQ %ERRORLEVEL% options "start ms-settings:"
goto :SUB
:C
set e=
set n=0
for %%i in (!%1!)do set/a n+=1&set "e=!e!!n!"&call :JQ !n! %1 "echo !n!. "
set/a n+=1
exit /b
:JQ
for /f "tokens=%1 delims= " %%i in ("!%2!")do if not "%%i"=="" %~3%%i
exit /b
:CHOICE
choice /c %1 /n /m "请选择操作编号："
exit/bCOPY

Five66

感谢分享
另外吐槽下设置真的不如控制面板 , 控制面板都是很多都是独立的项  , 可以单独打开 , 有多窗口 , 可以同时打开 ,  速度快 , 后退返回也快 , 简洁灵活直观 ,非常windows ;
而且至于设置 , 基本上是集中在一个窗口里通过交互变来变去 , 虽然其中的技术性挺高的 , 但是跟控制面板比起来 , 感觉就只是花里胡哨

qzwqzw

回复 2# Five66


    "设置"的UI设计逻辑是基于现代的触摸屏，以手势触摸为核心动线；"控制面板"是基于过去的显示屏，以鼠标点击为核心动线，设计目的不同，所以风格大行径庭。