[文件操作] 批处理如何在循环中保存变量？

tiandyoin

:test_不要在endlocal & call set 后面加 & rem )
@	echo off
	set "srcFile=a.reg"
	set "dstFile=b.reg"
	type "%~f0">"%TEMP%\$$$"
	type nul>"%dstFile%"
	set flag_is_hex=0
        set sum=
	@setlocal DisableDelayedExpansion & rem (
	for /f "delims=" %%a in ('findstr /n .* "%TEMP%\$$$"') do (
		set "line=%%a"
		@setlocal EnableDelayedExpansion & rem (
		set line=!line:*:=!
@		set line
		if not defined line (
			(echo;)>>"%dstFile%"
		) else (
@			echo flag_is_hex1=!flag_is_hex!&pause
			if "!flag_is_hex!"=="0" (
@				echo flag_is_hex2=!flag_is_hex!&pause
                                set sum=!sum!!line!
			) else (
				rem 预期不可能会跑到这里来，但实际很奇怪的跑到了这里
@				echo flag_is_hex3=!flag_is_hex!&pause
			)
		)
		@endlocal & call set flag_is_hex=%%flag_is_hex%% & call set sum=%%sum%% & rem )
	)
	@endlocal & rem )
	pause
@goto :EOF
复制代码

遇到个奇怪的问题，把 @endlocal & call set flag_is_hex=%%flag_is_hex%% & rem )
后面的  & rem ) 语句去掉就正常了。
但我不明白它为什么为跑到错误的分支。求大神解惑

另外，似乎没有办法把 sum 原样地保存到下一次循环，
使用 %%sum%% 也会对 sum 里面的变量求值，如sum 里面有 %TEMP%, 这个值会被展开
如何在循环中保存变量，对我来说一直是个难题。。。

qixiaobin0715

1.没看明白在代码中为何要加上那么多rem，到底会起什么作用；
2.setlocal endlocal----endlocal之间的设置变量会在执行到endlocal后全部归空，相当于结束此段内部环境变量的设置。所以下一次循环开始时sum就是一个空值。

Five66

难道不是因为把流程搞混了? 还有加那么多没意义的 & rem ( 和& rem )做啥?

想在setlocal EnableDelayedExpansion后继续使用变量就将变量带出去
或者单独弄一个call 流程

aloha20200628

回复 1# tiandyoin

   关于 !var! 变量在符合语句中如何 ‘续命’ 给 %var% 变量，是批处的一个经典话题，已知 endlocal &set "gv=%lv%" 或 endlocal &set "gv=%%lv%%" 两个句式可用于非复合语块，但在复合语块中则无效（因cmd预处理所致），这就是为何一楼代码27行赋值无效而导致 if 分支错判的关键原因...
   要在复合语块中实现!v! ‘续命’ 给%v%，可参考以下代码示例（关键是逃逸cmd预处理）

一。一个变量 !_#xx! ‘续命’ 给变量 %_#xx%

@echo off &setlocal &set/a "_#xx=0"
for /l %%n in (1,1,3) do (
    setlocal enabledelayedexpansion
    set/a "_#xx+=1, xx+=1"
    for /f "delims=" %%a in ('set _#') do (endlocal&set "%%a")
)
set _#
echo,xx=%xx%
pause&exit/b
复制代码

二。多个!v! 变量 !_#xx!, !_#yy!, !_#zz! ‘续命’ 给变量 %_#xx%, %_#yy%, %_#zz%

@echo off &setlocal &set/a "_#xx=_#yy=_#zz=0"
for /l %%n in (1,1,3) do (
    setlocal enabledelayedexpansion
    set/a "_#xx+=1, _#yy+=5, _#zz+=10, xyz+=1"
    set "k=1" &for /f "delims=" %%a in ('set _#') do (
        if defined k (endlocal&set "k=")
        set "%%a")
)
set _#
echo,xyz=%xyz%
pause&exit/b
复制代码

tiandyoin

回复 4# aloha20200628


    妙呀，我怎么没想到万能的 for ，只要放在 %%a 里面就可以了。

type 2>nul
endlocal & if errorlevel 1 set ...
::也可以带出err，不过只能赋值常量标记
复制代码

tiandyoin

回复 3# Five66


我使用 Notepad++ 等一些高级编辑器，只要选中左(右)括号，就可以定位到对应的右(左)括号

77七

@endlocal & call set flag_is_hex=%%flag_is_hex%%空格& call set sum=%%sum%%空格& rem )
变量值会包括空格

Five66

回复 6# tiandyoin


    啊 ,你这代码没有其他字面值的括号干扰吧 ,不加编辑器不也能正确匹配??