qixiaobin0715

回复 4# zhengwei007
想法太美好，现实很骨感。哪里又有通用代码，况且你要处理的文件又不是很规范。

aloha20200628

回复 11# zhengwei007

用7楼代码随机测试了11楼提供的几个文件（代码中的 1.xml 改为测试文件名），均予通过...
以下代码是将7楼代码改为批量处理版本，可将当前目录下的全部 *.xml 中的目标字段值析取整合到 new.xml，测试结果共析取9208条数据，与源文件名区间号码一致...

@echo off &setlocal enabledelayedexpansion &echo,稍候...
set "lst=,item id, type, name,icon,bodypart,armor_type,weight,soulshots,spiritshots,crystal_type,p_dam,rnd_dam,weapon_type,critical,hit_modify,atk_speed,m_dam,price,sellable,dropable,tradeable,pAtk,mAtk,rCrit,accCombat,pAtkSpd,pAtk1,mAtk1,pDef,"
set "v=!lst!"
(echo,item,type,name,icon,bodypart,armor_type,weight,soulshots,spiritshots,crystal_type,p_dam,rnd_dam,weapon_type,critical,hit_modify,atk_speed,m_dam,price,sellable,dropable,tradeable,pAtk,mAtk,rCrit,accCombat,pAtkSpd,pAtk1,mAtk1,pDef
for /f "delims=" %%F in ('dir/b/a-d *.xml') do for /f tokens^=1-7^delims^=^	^<^=^" %%a in (
   'findstr /rbi /c:"		*.*=\"^" /c:"	^</item^>" "%%F" ') do (
   if /i "%%a"=="item id" (
       set "v=!v:%%a,=%%b,!"&set "v=!v:%%c,=%%d,!"&set "v=!v:%%e,=%%f,!"
   ) else if "%%e"==" />" (set "v=!v:%%b,=%%d,!"
   ) else if "%%g"==" />" (
       set "go=1"&for %%s in ("%%f","%%f1") do if defined go if "!v:%%~s,=%%b,!" neq "!v!" (
       set "go="&set "v=!v:%%~s,=%%b,!")
   ) else if /i "%%a"=="/item>" ((for %%s in (!lst!) do set "v=!v:,%%s,=,,!")&echo,!v:~1,-1!&set "v=!lst!")
))>"new.xml"
endlocal&pause&exit/b
复制代码

zhengwei007

谢谢各位大佬，已经解决了，我发现修改后和别的内容根本不能通用，我是想的有点多了，再次感谢。

qixiaobin0715

所谓通用可以说基本上是不存在的，下面代码只是兼容性要好一些。如果你能够看得懂，处理与1楼结构基本相似的文本，经过适当修改可能会行得通。文本中如果存在*？等这样的字符可能会影响处理结果：

@echo off
set "TableHeader=id,type,name,icon,bodypart,armor_type,weight,soulshots,spiritshots,crystal_type,p_dam,rnd_dam,weapon_type,critical,hit_modify,atk_speed,m_dam,price,sellable,dropable,tradeable,pAtk,mAtk,rCrit,accCombat,pAtkSpd,pAtk,mAtk,pDef"
for %%i in (%TableHeader%) do set "_%%i=true"
(echo,%TableHeader%
setlocal enabledelayedexpansion
for /f "tokens=2 delims=<>" %%i in ('type *.xml 2^>nul^|findstr "<item </item> <set <add"') do (
    set ns=
    set v=
    if not "%%i"=="/item" (
        for %%k in (%%i) do (
            if defined _!str! (
                if defined !str! (
                    set "ns=%%~k"
                ) else (
                    set "!str!=%%k"
                )
            ) else (
                if defined _%%~k (
                    set "ns=%%~k"
                ) else if "!str!"=="val" (
                    set "v=%%k"
                )
            )
            set "str=%%k"
        )
        if defined ns (
            if defined v set "!ns!=!v!"
        )
    ) else (
        for %%k in (%TableHeader%) do (
            if defined line (set "line=!line!,!%%k!") else set "line=!%%k!"
            set %%k=
        )
        echo,!line!
        set line=
    )
))>1.csv
pause
复制代码

aloha20200628

回复 18# zhengwei007

其实本帖类似一个 '快递' 游戏 链表变量 lst 类似一排 '收货人'，源文件每行类似一串 '发货点'，代码逐行处理，'取货传至收货人'，因此先用 findstr 要一网打尽所有 '收货点'，不能遗漏，再逐行处理去准确寻址 '发货点'，最后还要确保链表中的 '收货人' 与 '发货点' 一一对应，传收无误。由此可见，链表中的数据项与源文件中目标行对应的属性名及位置关系要有一定规律，不能错乱，只要不乱，这个 '游戏' 就可以玩下去，数据项不怕多，当然链表最大长度是8K字符量...如此而已

zhengwei007

谢谢楼上的大佬们。