[系统相关] 【已解决】求bat代码读取指定硬盘分区的卷标，并通过echo输出

kokoxx

rt，文心一言给出的代码是

for /f "tokens=2 delims==" %%a in ('wmic logicaldisk where deviceid='R:' get name,volumename /value') do (  
    if not "%%a"==" " (  
        echo %%a  
    )  
) 
复制代码

结果运行时反复报错  R: - 别名谓词无效。

我的需求是将wmic logicaldisk where deviceid='r:' get volumename输出的卷标名（单独敲这条命令能正常输出）设置为变量x1，接着echo输出显示

希望大佬能出手指点

hfxiang

回复 1# kokoxx

试一下

wmic logicaldisk where deviceid='c:' get name,volumename /value|findstr =
复制代码

kokoxx

回复 2# hfxiang


    怎么将输出结果中的VolumeName设为可调用的变量？

newswan

修改一处

deviceid^=
复制代码

kokoxx

回复 4# newswan


大佬，我改成

@echo off   
for /f "tokens=2 delims==" %%a in ('wmic logicaldisk where deviceid^='c:' get volumename /value') do (  
    if not "%%a"==" " (  
        echo %%a  
    )  
)  
PAUSE

后可以输出卷标，但是只显示后半部分， 比如c盘卷标是ssd1，输出的卷标是  d1

就像这样

R:\>for /F "tokens=2 delims==" %a in ('wmic logicaldisk where deviceid='c:' get volumename /value') do (if not "%a" == " " (echo %a   ) )

   ) ) " (echo SDD1
  D1

R:\>PAUSE
请按任意键继续. . .

---
补充，我发现输出的卷标名前两个字是空白，但是后面的卷标都是正常的

newswan

回复 5# kokoxx

for /f "usebackq tokens=1,2 delims==" %%a in (` wmic logicaldisk where deviceid^='E:' get volumename /value `) do (
	echo --%%a__%%b--
	if not "%%b" == "" (set label=%%b)
)
echo  %label%
复制代码

hfxiang

回复 3# kokoxx

@echo off   
for /f "tokens=*" %%a in ('"wmic logicaldisk where deviceid=^'c:^' get name,volumename /value"^|findstr ^=') do set "%%a"
echo;“%Name%盘”卷标为：%VolumeName%
echo;
PAUSE
复制代码

aloha20200628

代码及说明如下。
一。用双引号包裹命令表达式 "wmic ..." 以免用转义字符的麻烦
二。用call子过程以便能从循环体尽早退出，不再打理 wmic 输出的多余行

@echo off
(call :getVn x1)
echo,%x1%
exit/b
:getVn
	for /f "skip=1" %%v in (' "wmic logicaldisk where deviceid="r:" get volumename" ') do (set "%1=%%v"&exit/b)
exit/b
复制代码

buyiyang

回复 5# kokoxx


    你的"echo %%a"后面多打了两个空格，因为%%a末尾多了一个回车符，所以后面两个空格回到行首，覆盖了%%a前面两个字符。
参见http://www.bathome.net/thread-65737-1-1.html

kokoxx

回复 9# buyiyang


    这就是专业！