[文本处理] 【已解决】请教批处理用什么方法可递增显示变量？

licunwei

请教，我想用递增的方式显示下面2个变量，大佬些 有什么方法，请教下。下面命令是错误的，为了表达意思而已。加一个检测出有几张网卡就只能循环几次更完美。

@echo off
Setlocal enabledelayedexpansion
for /f "tokens=2 delims==" %%A in ('wmic nic where "NetEnabled='TRUE'" get NetConnectionID /value^|find "="') do (
set /a m+=1
set "winx!m!=%%A"
)
echo %winx1%   %winx2%

set "m=0"
:A
set /a "m+=1"
echo %winx!m!%
pause
goto A
复制代码

ShowCode

回复 1# licunwei

@echo off
setlocal enabledelayedexpansion
for /f "tokens=2 delims==" %%A in ('wmic nic where "NetEnabled='TRUE'" get NetConnectionID /value ^| find "="') do (
    set /a m+=1
    set "winx!m!=%%A"
)
for /l %%i in (1,1,!m!) do (
    echo winx%%i=!winx%%i!
)
复制代码

licunwei

回复 2# ShowCode

不是我要的效果，我是要递增的方式显示 。大神能否帮忙改下。

licunwei

回复 2# ShowCode


我要的是能够变量名称加1的方式来显示。%winx1% 加1  %winx2%   加1  %winx3%  这样循环递增到没有数据为止。

newswan

@echo off

set wm1=1
set wm2=2
set wm3=3
for /f "usebackq" %%a in (` set wm`) do (
	echo %%a
)
复制代码

ShowCode

回复 4# licunwei

@echo off
setlocal enabledelayedexpansion
for /f "tokens=2 delims==" %%A in ('wmic nic where "NetEnabled='TRUE'" get NetConnectionID /value ^| find "="') do (
    set /a m+=1
    set "winx!m!=%%A"
)
set "n=0"
:Loop
set /a "n+=1"
echo,!winx%n%!
pause
if !n! lss !m! (
    goto :Loop
)
复制代码

licunwei

回复 6# ShowCode


完美   谢谢