[文本处理] 批处理如何检测一段字符/串中是否有指定的字符/串？

BingjianREMIX

如题,概括了一下大概:
具体:
检测一段字符或字符串中是否有指定的字符或字符串
如:检测"echo"和"echo on"中是否有"echo on"

@echo off
set "x=echo"
set "y=echo on"
set "z=echo on"
::两串字符
set a="%x%"
set c="%y%"
::指定字符或串
set b="%z%"
echo %a%| findstr %b% >nul && (
    echo %a%包含%b%
) || (
    echo %a%不包含%b%
)
echo %c%| findstr %b% >nul && (
    echo %c%包含%b%
) || (
    echo %c%不包含%b%
)

pause
复制代码

上述代码得到

E:\office>e:\office\lib\new\reset\检测字符串内是否有指定字符或串.bat
"echo"包含"echo on"
"echo on"包含"echo on"
Press any key to continue . . . 

E:\office>  
复制代码

求解,谢谢

77七

参考： [批处理命令一日一教学 续]（13）字符串查找增强：findstr
帮助信息 第29-32行

BingjianREMIX

回复 2# 77七


    我需要查找"echo on"这个整体,添加/c后finstr出现报错,并且都不匹配

E:\office>e:\office\lib\new\reset\检测字符串内是否有指定字符或串.bat
FINDSTR: Cannot open echo on
"echo"不包含"echo on"
FINDSTR: Cannot open on
FINDSTR: Cannot open echo on
"echo on"不包含"echo on"
Press any key to continue . . . 

E:\office>
复制代码

77七

回复 3# BingjianREMIX


  

@echo off
set "x=echo"
set "y=echo on"
set "z=echo on"
::两串字符
set a="%x%"
set c="%y%"
::指定字符或串
set b="%z%"

set "_b=%b:"=\"%"
echo %a%| findstr /c:"%_b%" >nul && (
    echo %a%包含%b%
) || (
    echo %a%不包含%b%
)

echo %c%| findstr /c:"%_b%" >nul && (
    echo %c%包含%b%
) || (
    echo %c%不包含%b%
)

pause
复制代码

BingjianREMIX

回复 4# 77七


    如果是需要让echo off & cls,echo off & dir等的也能检测出echo off呢

77七

回复 5# BingjianREMIX

set "str1=echo off & cls"
set str2=echo off
setlocal enabledelayedexpansion
echo !str1!|find "%str2%" 1>nul && echo ok
复制代码

for /f "delims=" %%a in ("echo off & cls") do (
        echo %%a|find "echo off" 1>nul && echo ok
)
复制代码

echo echo off ^& cls|find "echo off" 1>nul && echo ok
复制代码

set "str=echo off & cls"
set /p="%str%"<nul|find "echo off" 1>nul && echo ok
复制代码

set "str1=echo off & cls"
set str2=echo off
setlocal enabledelayedexpansion
set "_str=!str1:%str2%=!"
if "!_str!" neq "!str1!" (
	echo ok
)
复制代码