[日期时间] 批处理如何求得win7的开机时长？

tempasdf

各位：
    在win7中,systeminfo中包含开机时间,如何通过cmd命令判断出本次开机时长大于2天以上?

Five66

非得要用systeminfo中包含开机时间和cmd命令不？
还有楼主你不是发过一个差不多的帖子？

ShowCode

回复 1# tempasdf


http://bbs.bathome.net/thread-66666-1-1.html#pid274306
这个代码保存为 1.bat 在我的Win7里面测试正常

ShowCode

回复 1# tempasdf


Win7-v2.bat

@echo off
for /f "tokens=2 delims=.=" %%a in ('wmic Path Win32_OperatingSystem get LastBootUpTime /value') do (
    set "BootTime=%%a"
)
set "BootTime=%BootTime:~0,4%-%BootTime:~4,2%-%BootTime:~6,2% %BootTime:~8,2%:%BootTime:~10,2%:%BootTime:~12,2%"
for /f "tokens=2 delims=: " %%a in ('powershell "(Get-Date) - (Get-Date '%BootTime%')" ^|findstr /b "Days"') do (
    echo %%a
    if %%a geq 2 (
        echo 大于等于2天
    ) else (
        echo 小于2天
    )
)
pause
复制代码

ShowCode

回复 1# tempasdf


Win7-v3.bat

@echo off
for /f "tokens=2,3 delims=, " %%a in ('systeminfo ^| findstr /i /b "系统启动时间"') do (
    set "BootTime=%%a %%b"
)
for /f "tokens=2 delims=: " %%a in ('powershell "(Get-Date) - (Get-Date '%BootTime%')" ^|findstr /b "Days"') do (
    echo %BootTime%
    echo %%a
    if %%a geq 2 (
        echo 大于等于2天
    ) else (
        echo 小于2天
    )
)
pause
复制代码