[文件操作] [已解决]批处理怎样利用ffmpeg合并音频文件？

qd2024

想利用ffmpeg合并音频文件。

当前目录下会有相同前缀的文件夹存在，如

外研单词7A_En      外研单词7A_Ch     

以“_”为分界，“_”前面的文件相同，表示为一组，“_”后面的En表示这此文件夹内的音频为文件名对应的【英】文读音。
                                                                                                  Ch表示这此文件夹内的音频为文件名对应的【中】文读音。
En和Ch文件夹下的音频文件都使用相同的文件名，如“0001crayon”

想实现：
将“外研单词7A_En；外研单词7A_Ch”两个文件夹内的同名mp3文件合并到“外研单词7A”文件夹内，
En文件在前，Ch文件在后，即合并后的音频文件，英文在前，中文在后，如果没有“外研单词7A”文件夹，则自动创建。


-------------------------

以“_”为分界，“_”前面的文件相同，表示为一组，如有多组存在，则依先后分另进行处理。


-------------------------
举例文件
链接：https://pan.baidu.com/s/1KnQNuuzueikPOkpAAh3-5Q?pwd=t4mp
提取码：t4mp
--来自百度网盘超级会员V9的分享


感谢。

77七

@echo off
chcp 65001 >nul
rem 批处理保存为utf-8编码格式，需要ffmpeg
for /f "tokens=1* delims=_" %%a in ('dir /b /ad *_En') do (
	pushd "%%a_%%b"
	for /f "delims=" %%i in ('dir /b /a-d *.mp3') do (
		if exist "%~dp0%%a_Ch\%%i" (
			md "%~dp0%%a" 2>nul
			if not exist "%~dp0%%a\%%i" (
				"%~dp0ffmpeg.exe" -i "concat:%%~fi|%~dp0%%a_Ch\%%i" -acodec copy "%~dp0%%a\%%i"
			)
		)
	)
	popd
)
pause
复制代码

qd2024

回复 2# 77七
谢谢

运行后有下面提示 怎么修改


    'ffmpeg' is not recognized as an internal or external command,
operable program or batch file.
'ffmpeg' is not recognized as an internal or external command,
operable program or batch file.
'ffmpeg' is not recognized as an internal or external command,
operable program or batch file.
'ffmpeg' is not recognized as an internal or external command,
operable program or batch file.
'ffmpeg' is not recognized as an internal or external command,
operable program or batch file.
'ffmpeg' is not recognized as an internal or external command,
operable program or batch file.
Press any key to continue . . .

77七

回复 3# qd2024


   已在2楼修改，重新复制。

qd2024

回复 4# 77七


    测试成功 谢谢

qd2024

回复 4# 77七


    有空吗 再帮忙看看这个能不能实现  
       http://www.bathome.net/viewthread.php?tid=66892&extra=


感谢