xp3000

回复 asy666
在原帖子上改了，你没改两行

77七

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.mp3 *.m4a ^| find /c /v ""') do set c=%%i
for /l %%l in (0,500,3500) do (
        set m=000%%l
        set /a k=%%l+499
        set n=000!k!
        if !k! geq !c! (
                set l=000!c!
                set "folder=!m:~-4!-!l:~-4!（完）"
        ) else (
                set "folder=!m:~-4!-!n:~-4!"
        )
        md "!folder!"
        for /f "delims=" %%i in ('dir /b /a-d *.mp3 *.m4a') do (
                if "%%~ni" leq "!n:~-4!" (
                        move "%%i" "!folder!" 1>nul
                )
        )
        if defined l (
                goto :next
        )
)
:next
ren "0000-0499" "0001-0499"
复制代码

qixiaobin0715

这样应当也行，写的较乱，未仔细审核和测试，只是提供另外一种思路：

@echo off
for /f "delims=" %%i in ('dir /b /a-d^|find /c ".mp3 .m4v"') do set m1=%%i
set m2=0
set m3=4
setlocal enabledelayedexpansion
for /l %%i in (499,500,%m1%) do (
    set n=%%i
    set /a n1=%%i-499
    set n1=000!n1!
    set n2=000%%i
    if %%i equ 499 (
        set Folder=0001-0499
    ) else (
        set Folder=!n1:~-4!-!n2:~-4!
    )
    md "!Folder!"
    for /l %%j in (!m2!,1,!m3!) do (
        set x=0%%j
        set y=%%j
        move "!x:~-2!??.mp3" "!Folder!"
        move "!x:~-2!??.m4v" "!Folder!"
    )
    set /a m2=y+1
    set /a m3=m2+4
)
if !m1! equ !n! (
    set /a n+=1
    set n1=000!n!
    set n2=000!m1!
    set Folder=!n1:~-4!-!n2:~-4!（完）
    md "!Folder!"
    move "*mp3" "!Folder!"
    move "*m4v" "!Folder!"
) else (
    ren "!Folder!" "!Folder!（完）"
)
pause
复制代码

后来发现上述代码未考虑周全，错误较多，不必测试了。

asy666

回复 17# 77七


    这个可以，谢谢了

asy666

回复 16# xp3000


    好了，这次可以了，完美。谢谢大佬

terse

原来的代码理解错误。重写的是按文件名序号，移动到对应文件夹 不知结果是否符合

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.mp3 *.m4v^|find /v /c ""') do set /a n=%%i
set /an+=10000,d=500,b=d-1
if %n% gtr 10000 (
   for /l %%i in (10000,!d!,!n!) do (
        set /a "start=%%i,end=start+b,start+=^!(start-10000)"
        if !end! geq !n! (
           set old=!start:~-4!-!n:~-4!（完）
        ) else  set old=!start:~-4!-!end:~-4!
        set "_start=1!old:~,2!"
        set "_end=1!old:~5,2!"
        md "!old!" 2>nul
        for /l %%j in  (!_start!,1,!_end!) do (
             set s=%%j
             move "!s:~1!*.mp3" "!old!" >nul 2>nul
             move "!s:~1!*.m4v" "!old!" >nul 2>nul
        )
     )
)
复制代码

qixiaobin0715

18楼写的匆忙，错误较多。结合本帖中各位大佬的思路，简化18楼的代码：

@echo off
for /f "delims=" %%i in ('dir /b /a-d *.mp3 *.m4v^|find /v /c ""') do set m=%%i
set /a m1=100,m2=104
set /a m+=10000
setlocal enabledelayedexpansion
for /l %%i in (10000,500,%m%) do (
    set /a n1=%%i,n2=%%i+499
    set Folder=!n1:~-4!-!n2:~-4!
    md "!Folder!"
    for /l %%j in (!m1!,1,!m2!) do (
        set x=%%j
        move "!x:~-2!*.mp3" "!Folder!">nul 2>nul
        move "!x:~-2!*.m4v" "!Folder!">nul 2>nul
    )
    set /a m1=x+1,m2=m1+4
)
ren "!Folder!" "!Folder:~,5!!m:~1!（完）"
ren "0000-0499" "0001-0499"
pause
复制代码

bat另存为ANSI编码

77七

回复 21# terse

大佬，我试了两段代码，第一个文件夹0001-0499都是移动了500个文件进去

terse

回复 23# 77七
重新翻看一下帖子
楼主的意思应该是按文件名MOVE到对应的文件夹  那样的话就开始就错了