[其他] 已解决：批处理文件夹里的图片

yy5958437

文件夹A 里面 第一张图名称是1
文件夹B 里面 第一张图名称是1
文件夹C 里面 第一张图名称是1

要把A里的图1，命名改成A，然后放到Z文件夹
要把B里的图1，命名改成B，然后放到Z文件夹
要把C里的图1，命名改成C，然后放到Z文件夹

77七

@echo off
rem 假设 A B C Z 在同一目录下，图片为jpg格式
for %%a in (A B C) do (
	ren "%%a\1.jpg" "%%a.jpg"
	move "%%a\%%a.jpg" "Z\"
)
pause
复制代码

根据现有的描述，这样应该能符合你的需求。

yy5958437

回复 2# 77七


    感谢大佬，举例的可以实现了，但是我文件夹里面有100个文件夹，有没有办法不输入  A B C ，然后操作所有的


然后还有就是 完了之后，有没有办法把A.JPG B.JPG 再变回去1.jpg

我帝波罗

括号里面的A B C 换成 'dir /ad /b *.*' 试试 英文单引号别漏了

要保留原文件你把ren 换成copy就行了

@echo off

for /F %%a in ('dir /ad /b *.*') do (
	copy "%%a\1.jpg" "%%a.jpg"
	move "%%a\%%a.jpg" "Z\"
)
pause
复制代码

77七

回复 3# yy5958437


  

@echo off
for /d %%a in (*) do (
        if not "%%a" equ "Z" (
                ren "%%a\1.jpg" "%%a.jpg"
                move "%%a\%%a.jpg" "Z\"
        )
)
pause
复制代码

这样行吗
代码2 恢复

@echo off
for /d %%a in (*) do (
	if not "%%a" equ "Z" (
		if exist "Z\%%a.jpg" (
			ren "Z\%%a.jpg" "1.jpg"
			move "Z\1.jpg" "%%a\"
		)
	)
)
pause
复制代码

yy5958437

回复 5# 77七


    大佬，我突然想到是不是可以一步实现呢，求帮帮
    先把A文件夹里面的1.jpg复制一个副本，然后把副本改成A.JPG，然后把A.JPG 移动到Z文件夹，这样原文件夹不变，Z文件夹里面就有对应的图片了

77七

回复 6# yy5958437


  

@echo off
for /d %%a in (*) do (
	if not "%%a" equ "Z" (
		copy "%%a\1.jpg" "Z\%%a.jpg"
	)
)
pause
复制代码

没能理解 “放” 的意思
这样行吗

yy5958437

可以了。非常感谢各位大佬。