[文本处理] [已解决]批处理从1.csv中取出.txt、.ini、.bat、.vbs的完整路径（含扩展名）

yyz219

从1.csv中取出.txt、.ini、.bat、.vbs的完整路径（含扩展名），保存为1.txt
完美解决了：

@echo off
(for /f "delims=" %%i in ('findstr "\.txt \.ini \.bat \.vbs" 1.csv') do (
    for /f tokens^=17^ delims^=^" %%j in (%%i) do (
        for /f "delims=-" %%k in ("%%j") do echo,%%k
    )
))>1.txt
复制代码

pause[/code]*****************************************************************
下面是不能正确输出的1.csv
https://pan.baidu.com/s/1D0-KYijTpeT6mD2UXB3r-g

hfxiang

试一下如下指令

for /f "tokens=1* delims=." %a in ('findstr /i "\<.*.exe" 1.txt') do @where %~a.exe
复制代码

yyz219

试一下如下指令
hfxiang 发表于 2022-9-20 09:35

    我试一试先，辛苦了

yyz219

试一下如下指令
hfxiang 发表于 2022-9-20 09:35

    不行，闪一下，也没有生成1.txt

hfxiang

回复 4# yyz219


2楼的指令在CMD窗口下执行，不是写在bat中执行，输入文件为1.txt，直接在屏幕上输出。

写在bat中执行的指令如下（以下指令提取的是.exe文件，其它的需自行改动）：

@rem 保存文件编码为ANSI
@echo 执行中请等候......
@(for /f "tokens=1* delims=." %%a in ('findstr /i "\<.*.exe" 1.csv') do @where "%%~a.exe")>1.txt 2>nul
@echo 
@echo 执行完毕......
复制代码

qixiaobin0715

最好能在网盘中传一份CSV文件看看。

yyz219

最好能在网盘中传一份CSV文件看看。
qixiaobin0715 发表于 2022-9-20 10:01

https://pan.baidu.com/s/1AhboSmHTB7sLigWmDFuppw

yyz219

回复  yyz219


2楼的指令在CMD窗口下执行，不是写在bat中执行，输入文件为1.txt，直接在屏幕上输出。
...
hfxiang 发表于 2022-9-20 09:53

    我要提取的是文中粉红色的（这个是变化的）

hfxiang

回复 8# yyz219


   
直接在CMD窗口下试试如下指令：

@(for /f "tokens=10 delims=," %a in (1.csv) do @for /f %b in ('echo %~a^|findstr /i ".txt .ini .bat .vbs"')  do @echo "%~b")>1.txt 2>nul
复制代码

qixiaobin0715

回复 7# yyz219

@echo off
setlocal enabledelayedexpansion
for %%x in (.txt .ini .bat .vbs) do set %%x=true
(for /f "delims=" %%i in (1.csv) do (
    for %%j in (%%i) do (
        set str=%%j
    )
    for /f "delims=-" %%k in (!str!) do (
        if defined %%~xk echo,%%k
    )
))>1.txt
pause
复制代码

看看显示是否正确

yyz219

回复  yyz219 看看显示是否正确
qixiaobin0715 发表于 2022-9-20 10:57

    屏幕能够正确显示

再麻烦一下，让它在生成1.txt

谢谢

qixiaobin0715

回复 11# yyz219
已修改

yyz219

回复  yyz219
已修改
qixiaobin0715 发表于 2022-9-20 11:16

    非常感谢，完美解决

qixiaobin0715

如果数据像你提供的那么规整的话，这样效率应当更高些：

@echo off
setlocal enabledelayedexpansion
(for /f "delims=" %%i in ('findstr "\.txt \.ini \.bat \.vbs" 1.csv') do (
    for %%j in (%%i) do set str=%%j
    for /f "delims=-" %%k in (!str!) do echo,%%k
))>1.txt
pause
复制代码

未经测试。

yyz219

如果数据像你提供的那么规整的话，这样效率应当更高些：未经测试。
qixiaobin0715 发表于 2022-9-20 16:37

    非常感谢