[网络连接] 【已解决】请问批处理ipconfig读取多网卡怎么操作

asd674744769

@echo off
for /f "tokens=3*" %%t in ('ipconfig ^/all ^| find "以太网适配器"') do set name3=%%t


if "%name3%"=="" ( 

 
for /f "tokens=4*" %%a in ('netsh interface show interface^|more') do (set name=%%a)


) else (

 
for /f "tokens=4*" %%a in ('netsh interface show interface^|more') do (set name=%%a %%b)

)
echo. & echo 1:%name%
Pause
复制代码

这里运行之后只能显示一个网络适配器，有办法显示多个网络适配器吗

asd674744769

大佬请一下

asd674744769

@echo off & setlocal enabledelayedexpansion
echo. & echo 正在抓取网卡名称……
set m=0
for /f "tokens=1* delims=," %%a in ('ipconfig ^/all ^| find "以太网适配器"') do (
set /a m+=1
set "name!m!=%%a"
set "name=%name:~1,-1%"
)
:Select_Card
echo. & echo 1:%name1% & echo 2:!name2! & echo 3:!name3! & echo 4:!name4! & echo 5:!name5! & echo.




Pause

echo. & echo 选择网卡:%card% & goto :eof


这个能出现多网卡 但是 选择第2列是无法选择的，然后后面的判断命令不知道怎么加
有没有大佬教一下

asd674744769

有没有大佬请教一下

went

@echo off
setlocal enabledelayedexpansion
set "n=0"
for /f "skip=3 tokens=4*" %%i in ('netsh interface show interface') do (
	set /a n+=1
	set "name_!n!=%%i"
)
for /l %%i in (1,1,%n%) do echo %%i:!name_%%i!
pause&exit
复制代码

asd674744769

回复 5# went


    大佬，如果我想 set /p choice=请选择： 列处理的网卡的话 我应该怎么弄

asd674744769

回复 6# asd674744769


    我自己已弄好了 谢谢大佬

asd674744769

回复 5# went


    想请教一下 怎么能把 netsh interface show interface  第4列取完整 因为有空格他名字取不完整

went

回复 8# asd674744769

@echo off
setlocal enabledelayedexpansion
set "n=0"
for /f "skip=3 tokens=3*" %%i in ('netsh interface show interface') do (
	set /a n+=1
	set "name_!n!=%%j"
)
for /l %%i in (1,1,%n%) do echo %%i:!name_%%i!
pause&exit
复制代码

went

回复 6# asd674744769

@echo off
setlocal enabledelayedexpansion
set "n=0"
for /f "skip=3 tokens=3*" %%i in ('netsh interface show interface') do (
	set /a n+=1
	set "name_!n!=%%j"
)
:Select_Card
for /l %%i in (1,1,%n%) do echo %%i:!name_%%i!
set /p "Select_Card=选择网卡（请勿选择本地连接）:"
if "!name_%Select_Card%!"=="" (
	echo. 
	echo 选择错误!
	pause>nul & cls & goto :Select_Card 
)
echo 选择了!name_%Select_Card%!
pause&exit
复制代码

asd674744769

回复 10# went


    感谢，判断语句我都准备写的，大佬都已经写出来了 感谢

asd674744769

回复 11# asd674744769

asd674744769

回复 10# went


    大佬还需要请教你一下   用了你发的最新的那个判断的  我加一条运用 netsh interface ip set address !name_%Select_Card%! static 192.168.225.%random% 255.255.255.0   提示是无法用 这个抓取的名称的 应该是包含了这个空格  请问我需要怎么改

went

回复 13# asd674744769


    加引号试下

netsh interface ip set address "!name_%Select_Card%!" static 192.168.225.%random% 255.255.255.0
复制代码