[数值计算] [已解决]批处理删除指定日期的分钟数之前的文件

kingwu

感谢batcher lazygc50 2位网友的帮助  目前已测试通过！

谢谢

代码如下

rem 指定待删除文件的存放路径
set SrcDir=E:\123
rem 指定分钟数
set TimesAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>null
if %time:~0,2% lss 10 (set hh=0%time:~1,1%) else (set hh=%time:~0,2%)
call :DateToMins %date:~0,4% %date:~5,2% %date:~8,2% %hh% %Time:~3,2% PassMins
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassMins-=%TimesAgo%
call :MinsToDate %PassMins% DstYear DstMonth DstDay DstHour Dstmin
set DstMins=%DstYear%-%DstMonth%-%DstDay% %DstHour%:%Dstmin%
for /r "%SrcDir%" %%a in (*.*) do (
  if "%%~ta" leq "%DstMins%" (
    if exist "%%a" (
     del /f /q "%%a"
    )
  )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof
 
:DateToMins %yy% %mm% %dd% %hh% %mm% result
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,j=j*1440+hh*60+nn
endlocal&set %6=%j%&goto :EOF
:MinsToDate %mins% yy mm dd hh nn
setlocal ENABLEEXTENSIONS
set /a i=%1,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
endlocal&set %6=%nn%&set %5=%hh%&set %4=%dd%&^
set %3=%mm%&set %2=%yy%&goto :EOFCOPY

[ 本帖最后由 kingwu 于 2009-8-21 16:33 编辑 ]

Batcher

参考：http://www.bathome.net/viewthrea ... amp;page=2#pid36200

kingwu

目前参考了他的问题

但是我现在出现的问题是

1.set /a hh=100%hh%%%100,nn=100%nn%%%100,j=j*1440+hh*60+nn
运算符不存在
2.endlocal&set %6=%j%&goto :EOF
语法命令不正确
所以就无法理解了

还望版主细看并指点一二

Batcher

那两句代码都是库函数里面的，它们本身是没有任何问题。
关键是你在调用DateToMins函数的时候传进去的参数是错的：

call ateToMins %date:~0,4% %date:~5,2% %date:~8,2% %Time:~0,2%:%Time:~3,2% PassMins

具体原因及解决思路，在2楼链接中均以提到。

kingwu

插入在下面的地方还是报同样的错误

for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
if %time:~0,2% lss 10 (set hh=0%time:~1,1%) else (set hh=%time:~0,2%)
call ateToMins %date:~0,4% %date:~5,2% %date:~8,2% %Time:~0,2%:%Time:~3,2% PassMins

[ 本帖最后由 kingwu 于 2009-8-21 16:15 编辑 ]

lazygc520

if %time:~0,2% lss 10 (set hh=0%time:~1,1%) else (set hh=%time:~0,2%)
call ateToMins %date:~0,4% %date:~5,2% %date:~8,2% %Time:~0,2%:%Time:~3,2% PassMins
晕，你也不能照单全收啊。
if %time:~0,2% lss 10 (set hh=0%time:~1,1%) else (set hh=%time:~0,2%)
call :DateToMins %date:~0,4% %date:~5,2% %date:~8,2% %hh%:%Time:~3,2% PassMins

kingwu

谢谢！！！！ 目前已经解决！

tangqingfu

先收藏，再学习，谢谢分享！