[文件操作] 如何复制目录A到指定目录B排除部分文件

bluer88

问题描述：
1、目录A下有多级子目录，子目录中有很多的各类文件；
2、例如目录tmp下面有1.1，1.2，1.8，3.5，10.a_beta，10.a_beta中的文件为

c:\tmp\10.a_beta\a80c8320f34cc.2
c:\tmp\10.a_beta\eaall-x-non1e.3
c:\tmp\10.a_beta\ffc5a7a80c8ad8.caba  
c:\tmp\10.a_beta\a80ec8320f3.1
c:\tmp\10.a_beta\setup.exe
c:\tmp\10.a_beta\22.exe
c:\tmp\10.a_beta\c1\1siqqX
c:\tmp\10.a_beta\c2\W.EXE
c:\tmp\10.a_beta\c3\WDwICON.EXE
c:\tmp\10.a_beta\c4\WD12CNV.DLL
c:\tmp\10.a_beta\c5\D1d2CNV.DLL
c:\tmp\10.a_beta\c6\RD12dCNV.aw
c:\tmp\10.a_beta\c7\1d2CNV.fe
c:\tmp\10.a_beta\c8\RD12CNV.43a
（只列出部分）

求助：
把目录tmp 复制到 另一个位置，目录结构不变的情况，如果只复制不带后缀名的文件，有后续名的文件跳过不要复制。谢谢！！！

zaqmlp

@echo off
mode con lines=3000
set info=互助互利,支付宝扫码头像,感谢打赏
rem 有问题,可加QQ956535081及时沟通
title %info%
set "oldfolder=C:\temp"
set "newfolder=D:\xxx\yyy"
if not exist "%oldfolder%" (echo;"%oldfolder%" no found&goto end)
if "%oldfolder:~-1%" equ "\" set "oldfolder=%oldfolder:~,-1%"
if "%newfolder:~-1%" equ "\" set "newfolder=%newfolder:~,-1%"
for /f "delims=" %%a in ('dir /a-d/b/s "%oldfolder%\"') do (
    if "%%~xa" equ "" (
        set "oldpath=%%~dpa"&set "oldfile=%%a"
        setlocal enabledelayedexpansion
        set "newpath=!oldpath:%oldfolder%=%newfolder%!"
        if not exist "!newpath!" md "!newpath!"
        echo;"!oldfile!" --^> "!newpath!"
        copy /y "!oldfile!" "!newpath!"
        endlocal
    )
)
:end
echo;%info%
pause
exit
复制代码

bluer88

可以运行，且达到效果，感谢！

zaqmlp

回复 3# bluer88
感谢还是红包实际点

zaqmlp

回复 5# Gin_Q

深有同感