[文本处理] 【已解决】我用了FOR嵌套怎么才能结束子循环的情况下不影响外边的循环

miqilaosu

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('type 1.txt') do (
set n=1
call set "var=%%i"
	for /l %%a in (1,1,99) do (
		call set "var1=%%var:~0,!n!%%"
		call set "var2=%%var:~!n!,!n!%%"

		if !var1!==!var2! (
			echo,!var1!.
				::跳出子循环
		) else (
			set /a n+=1
				if !var2!=="" ::if跳出子循环
			)
		)
	)
)
pause
复制代码

是这样的，第一个：：跳出子循环的地方我想直接跳出子循环外边的循环继续，第二个我想做个判断!var2!==""的时候跳出子循环，但是发现不能用GOTO 不然就直接全跳出的，查了半天没找到方法，请问各位大神怎么才能实现

WHY

批处理 for 循环里面只能 goto 到循环外部，不能在 for 循环内部 goto
这样应该可以：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('type 1.txt') do (
    set "var=%%i"
    for /l %%a in (1,1,99) do (
        set "var1=!var:~0,%%a!"
        set "var2=!var:~%%a!"
        if "!var1!" == "!var2!" (echo;!var1!)
    )
)
pause
复制代码

或者试试 call :标签

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('type 1.txt') do (
    call :GetString "%%i"
)
pause & goto :EOF

:GetString
set "var=%~1"
for /l %%a in (1,1,99) do (
    set "var1=!var:~0,%%a!"
    set "var2=!var:~%%a!"
    if "!var1!" == "!var2!" (echo;!var1!&goto :EOF)
)
复制代码