[文件操作] [已解决]批处理如何把A文件夹的内容复制到不明路径文件中？

yml2ghy

已知文件夹A路径，如何把A文件夹的内容复制到不明路径B文件夹中，ps：B文件夹名称在所有盘符中具有唯一性

谢谢大佬观帖，如有帮助，留下联系方式，小弟奉上一点茶水钱以表心意 :loveliness:

miqilaosu

for /f %%i in ('dir /ad /b /s C:\') do (
if "%%~ni"=="B文件夹名"  xcopy "C:\A" "%%i" &exit
)
复制代码

都是新人，互相学习，用BAT搜太慢了，这还是只搜一个盘符，要是几个盘符搜的话很累啊,幸亏你只搜文件夹
希望有大神弄个快速搜索的方法

zaqmlp

@echo off
set info=互助互利,支付宝扫码头像,感谢赞助
rem 有问题,可加QQ956535081及时沟通
title %info%
cd /d "%~dp0"
set "文件夹1=C:\A"
set "文件夹2=B"
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist "%%a:\" (
        (echo;@echo off
        echo;title \@*@/[%%a]
        echo;echo;searching %%a: ……
        echo;for /r "%%a:\" /d %%%%i in ^(*^) do ^(
        echo;   if /i "%%%%~nxi" equ "%文件夹2%" ^(
        echo;       echo;%%%%i
        echo;       xcopy "%文件夹1%" "%%%%i\" /e /q /y
        echo;       exit
        echo;   ^)
        echo;^)
        echo;exit)>"%tmp%\#%%a.bat"
        start /min "" "%tmp%\#%%a.bat"
        >nul ping /n 2 0
    )
)
:loop
cls
tasklist /fi "IMAGENAME eq cmd.exe" /v /fo csv /nh|find /i "\@*@/"&&(
    >nul ping /n 2 0
    goto loop
)
echo;%info%
pause
复制代码

yml2ghy

回复 3# zaqmlp


    感谢，已支持，查收。如果能后台操作不显示就好了

yml2ghy

回复 2# miqilaosu


    谢谢顶帖

Batcher

B文件夹名称在所有盘符中具有唯一性

如果所在盘符是确定的，只需要在那个盘符下面搜索就行了。