批处理求1-10000以内的所有水仙花数？

youxi01

水仙花数是这样的数字：这个数各个数位上数字的立方和等于该数。比如 153=1*1*1+5*5*5+3*3*3

more

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,9) do (
for /l %%b in (0,1,9) do (
set /a bb=%%a*%%a+%%b*%%b
if !bb!==%%a%%b echo   %%a%%b 是水仙花数
for /l %%c in (0,1,9) do (
set /a aa=%%a*%%a*%%a+%%b*%%b*%%b+%%c*%%c*%%c
if !aa!==%%a%%b%%c echo   %%a%%b%%c 是水仙花数
for /l %%d in (0,1,9) do (
set /a cc=%%a*%%a*%%a+%%b*%%b*%%b+%%c*%%c*%%c+%%d*%%d*%%d
if !cc!==%%a%%b%%c%%d echo %%a%%b%%c%%d 是水仙花数
))))
echo.&pauseCOPY

梦想种子

@echo off
setlocal enabledelayedexpansion
set "u1="
for /l %%i in (0,1,9) do set /a t%%i=%%i*%%i*%%i
for /l %%i in (1,1,10000) do (
set k=%%i
set /a a=%%i/10000
set /a b=%%i/1000"%%"10
set /a c=%%i/100"%%"10
set /a d=%%i/10"%%"10
set /a e=%%i"%%"10
set /a n=t!a!+t!b!+t!c!+t!d!+t!e!
if "!n!" == "%%i" echo %%i
)
pauseCOPY

请问有没有效率高的算法？

随风

你这个效率应该是很高了，所用的时间应该是for /l 必须的时间了吧。。

lhjoanna

@echo off&setlocal EnableDelayedExpansion
for /l %%k in (0,1,9) do ( set /a t%%k=%%k*%%k*%%k )
for /l %%i in (1,1,10000) do (
  set num=%%i
  set "n="
  :loop
    set /a a=!num!%%10
    set /a num/=10
    set /a n+=t!a!
  if !num! neq 0 goto loop
  if !n!==%%i echo %%i
)
pause
此段代码第二个for循环为何只能循环10次？？

kingerpk

@echo off
 
setlocal EnableDelayedExpansion
 
for /l %%a in (1,1,10000) do (
 
set /a a=%%a/10000
::万
set /a b=%%a/1000-!a!*10
::千
set /a c=%%a/100-!a!*100-!b!*10
::百
set /a e=%%a/10-!a!*1000-!b!*100-!c!*10
::十
set /a d=%%a%%10
::个
set /a k=!a!*!a!*!a!+!b!*!b!*!b!+!c!*!c!*!c!+!d!*!d!*!d!+!e!*!e!*!e!
 
if !k! == %%a echo %%a 
)
 
pauseCOPY

好长啊~~~~惭愧~~~
望大家指点！！

irresolute

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,10000) do (
set /a a=%%i/10000
set /a b=%%i-!a!*10000,b=b/1000
set /a c=%%i-!a!*10000-!b!*1000,c=c/100
set /a d=%%i-!a!*10000-!b!*1000-!c!*100,d=d/10
set /a e=%%i%%10
set /a aa=a*a*a+b*b*b+c*c*c+d*d*d+e*e*e
if %%i==!aa! echo %%i是水仙花数
)
pause>nulCOPY

irresolute

@echo off
setlocal enabledelayedexpansion
for /l %%i in (10000,-1,1) do (
set k=%%i
set a=!k:~0,1!
set b=!k:~1,1!
set c=!k:~2,1!
set d=!k:~3,1!
set e=!k:~4,1!
set /a aa=a*a*a+b*b*b+c*c*c+d*d*d+e*e*e
if %%i==!aa! echo %%i是水仙花数
)
pause>nulCOPY

TonyW

说实话, 不能完全理解... 看了一次楼上几位的代码后,根据自己的理解和回忆..还是写不出来!!

MYM123

楼上高手，受教了！厉害

pzspdl

原帖由 irresolute 于 2009-2-15 22:00 发表
@echo off
setlocal enabledelayedexpansion
for /l %%i in (10000,-1,1) do (
set k=%%i
set a=!k:~0,1!
set b=!k:~1,1!
set c=!k:~2,1!
set d=!k:~3,1!
set e=!k:~4,1!
set /a aa=a*a*a+b*b*b+c*c*c+d*d* ...

感觉这段写得非常漂亮，只是set a=!k:~0,1!
set b=!k:~1,1!
set c=!k:~2,1!
set d=!k:~3,1!
set e=!k:~4,1!这里我不太明白

myzwd

%~si和%~fi 我真没搞明白差别在那里。

sjzong

 @echo off&setlocal enabledelayedexpansion
for /l %%a in (0 1 9) do set/a t%%a=%%a*%%a*%%a
for /l %%i in (1 1 9) do (
if !t%%i!==%%i echo %%i 是水仙花数。
for /l %%j in (0 1 9) do (
  set/a num=!t%%i!+!t%%j!
  if !num!==%%i%%j echo %%i%%j 是水仙花数。
  for /l %%k in (0 1 9) do (
   set/a num=!t%%i!+!t%%j!+!t%%k!
   if !num!==%%i%%j%%k echo %%i%%j%%k 是水仙花数。
   for /l %%l in (0 1 9) do (
   set/a num=!t%%i!+!t%%j!+!t%%k!+!t%%l!
   if !num!==%%i%%j%%k%%l echo %%i%%j%%k%%l 是水仙花数。
))))
pause>nulCOPY

[ 本帖最后由 sjzong 于 2009-5-9 00:56 编辑 ]

Demon

水仙花数的定义错了

水仙花数是指一个 n 位数 ( n≥3 )，它的每个位上的数字的 n 次幂之和等于它本身。

例如：1^3 + 5^3 + 3^3 = 153，1634 = 1^4 + 6^4 + 3^4 + 4^4 = 1634

common

11# pzspdl


%a:~[m[,n]]%
方括号表示可选，%为变量标识符，a为变量名，不可少，冒号用于分隔变量名和说明部分，符号～可以
简单理解为“偏移”即可，m为偏移量（缺省为0），n为截取长度（缺省为全部）
%PATH:~10,5% 这个什么意思,看例子:

截取功能例子1：
@echo off
set a=bbs.verybat.cn
set var=%a:~1,2%
echo %var%
pause

我也是菜鸟，这个题我也写了半天没写出来，最后是参照别人实现了，没脸发上来了