[文本处理] [已解决] 批处理如何判断两块raid卡目前状态

ybbpgkfdn

刚小弟看回复发现有大神，没看懂小弟的需求！那小弟就写的简单一点。
有两行英文其后面的Optimal是会变化的值。Optimal （代表正常）Uptimal（代表不正常）
我的需求是写一个批处理双击后会输出：[RAID卡一切正常] 或 [RAID10卡不正常]，着样的文字提示。
RAID1_State               : Optimal  
RAID10_State               : Optimal   

我目前写到着里出来了很多问题：例如tokens=1,2 它取值是最后一行的两列！！！等等
@echo off  & setlocal enabledelayedexpansion
d:
::type raid.txt | find "State" >A.txt
for /f "tokens=1,2 delims=: " %%i in (A.txt) do set num1=%%i&& set num2=%%j
if "%num2%"=="Optimal" (echo "健康的RAID10") else echo "不健康的RAID10"
echo "%num1%"
echo "%num2%"
pause

不知道大家用过shell没有如果用shell大概写法是着样的
#/bin/bash
RAID=`grep "Optimal|wc -l"`
RAID1=`cat a.txt|awk -F ": " 'NR==1{print $2}'`
RAID10=`cat a.txt|awk -F ": " 'NR==2{print $2}'`
if [ $RAID -eq 2 ]
  then
    echo "RAID卡一切正常"
  else
     if [ "$RAID1" == "Optimal" ]
        then  
           echo "RAID10卡不正常"
        else
           echo "RAID1卡不正常"
     fi
fi

wskwfkbdn

不知所云                                 ~

GNU

@echo off
type "D:\raid.txt" | find "State" >A.txt
for /f "tokens=1,2 delims=: " %%i in (A.txt) do (
    if "%%j"=="Optimal" (
        echo "健康的%%i --- %%j"
    ) else (
        echo "不健康的%%i --- %%j"
    )
)
pause
复制代码

GNU

@echo off
setlocal enabledelayedexpansion
type "D:\raid.txt" | find "State" >A.txt
for /f "tokens=1,2 delims=: " %%i in (A.txt) do (
    if "%%j"=="Optimal" (
        echo "健康的%%i --- %%j"
    ) else (
        echo "不健康的%%i --- %%j"
    )
    set "num1=%%i"
    set "num2=%%j"
    echo !num1! !num2!
)
pause
复制代码

pcl_test

举个栗子

@echo off&setlocal enabledelayedexpansion
set optimal=正常
set uptimal=不正常
for /f "tokens=1-3 delims=_: " %%i in ('more +13 "%~f0"') do (
    if /i "%%k"=="Optimal" set /a n+=1
    set "#%%i=%%k"
)
if "%n%" equ "2" (
    echo;RAID卡一切正常
) else (
    for /f "tokens=1,2 delims=#=" %%i in ('set #') do echo;%%i!%%j!
)
pause&exit
RAID1_State               : Optimal  
RAID10_State               : Optimal 
复制代码

ybbpgkfdn

回复 3# GNU
非常感谢
我不太明白for do（）的含义，为什么我不加括号只匹配最后一行的Optimal

ybbpgkfdn

回复 5# pcl_test
非常感谢
太复杂了完全看不懂…………有没有好的书求推荐

Bella

回复 7# ybbpgkfdn


    http://www.bathome.net/thread-5814-1-1.html
居家旅行, 杀人灭口必备手册

ybbpgkfdn

回复 8# Bella

非常谢谢。