____________________________版主提醒____________________________
为了避免影响技术讨论、提高看帖的舒适性，请大家不要在此帖下跟
无实质内容的口水帖,特别是纯顶、纯支持、纯感谢、路过之类的帖子，
管理人员将不定期清理此类回帖，请大家多参与讨论少灌水，与人方便，
终将给自己带来方便，谢谢合作。
________________________________________________________________
你手头是否有几本chm格式的电子书？你是否有过满世界搜索反编译chm软件的痛苦经历？你是否抱怨过这些软件有这样或那样的限制？然而，你是否意识到，就在你的系统里，微软已经为你准备好了小巧而强悍的反编译程序？
没错，微软已经为各位准备好了这样的软件，它就是各位双击chm文件时系统默认调用的hh.exe！我没有开玩笑，hh.exe这个毫不起眼的家伙，除了是个默默无闻的chm文件阅览器之外，还是个现成的chm文件反编译器！只是这个反编译器的调用参数一直未见微软公布，网上偶尔见到只言片语，也未引起大家的足够重视，因此它一直是大隐隐于市。
不过，hh.exe要成为我们手里的反编译利器，光靠一条简陋的命令是不够的，它还需要各位的反复测试、耐心打磨。现奉上本人草就的代码，只做了一些主要的功能，尚未做界面的美化，请各位测试。- ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
- :: chm文件反编译器 V1.3
- :: code by namejm 2007.12.27～2010.4.9 bbs.bathome.net CMD@XP
- ::
- :: 功能：
- :: 单个/批量反编译chm文件，并保持资源的原始结构。
- :: 使用方式有两种：
- :: ① 把单个或多个文件直接拖放到本程序。
- :: ② 直接双击运行。此时处理的是当前目录下所有以.chm为后缀的文件
- :: 执行过程及处理效果：
- :: 因为 hh -decompile 语句不能使用引号，所以，先把原始资源释放到
- :: 短文件名格式的文件夹中，释放完毕后再改名；
- :: 两种执行方式都有简单的容错处理；反编译后的资源放在单独的文件夹
- :: 中，此文件夹位于当前目录，并以chm文件名命名。
- :: 无法识别不以.chm为后缀名的chm文件，但是可以识别以.chm为后缀名
- ::的其他文件（貌似有点拗口^_^）
- ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
- @echo off
- set TT=chm文件反编译器 1.3
- echo.&echo.&echo 正在反编译CHM文件，请稍候...
- cd /d "%~dp0"
- :: 以拖动文件到批处理文件上的方式运行批处理时，%cd% 的值将会强制转换为
- :: %homepath%，因此，上一条语句非常关键！
- set "destination=chm文件反编译结果"
- for /f "delims=" %%i in ("%destination%") do set "destination_short=%%~sfi"
- md "%destination%" 2>nul
- del /a /f "%destination%\伪chm文件列表.txt" 2>nul
- if "%~1"=="" goto All
-
- :Some
- set str=%*
- set "str=%str:"=%"
- set "str= %str%"
- call set "str=%%str: %~d1=" "%~d1%%"
- for %%i in ("%str%") do (
- if not %%i=="" (
- title %TT%-正在处理"%%~nxi"
- if /i not "%%~xi"==".chm" (
- echo.&echo "%%~nxi"不是chm文件
- echo.&echo 请按任意键继续...
- pause>nul
- cls
- echo.&echo.&echo 正在反编译CHM文件，请稍候...
- ) else (
- rd /q /s "%%~ni" 2>nul
- hh -decompile %destination_short%\%%~sni %%~sfi
- if not exist "%destination%\%%~sni" (
- echo "%%~nxi">>"%destination%\伪chm文件列表.txt"
- ) else (
- ren "%destination%\%%~sni" "%%~ni" 2>nul
- )
- )
- )
- )
- exit
-
- :All
- for /f "delims=" %%i in ('dir /a-d /b *.chm 2^>nul') do (
- title %TT%-正在处理"%%~nxi"
- rd /q /s "%destination%\%%~ni" 2>nul
- hh -decompile %destination_short%\%%~sni %%~sfi
- if not exist "%destination%\%%~sni" (
- echo "%%~nxi">>"%destination%\伪chm文件列表.txt"
- ) else (
- ren "%destination%\%%~sni" "%%~ni" 2>nul
- )
- )
更新历史：- 2010.4.9
- 把反编译后的资源统一存放在指定的目录下，不再与cmd文件位于同一
- 目录下；
- 修改了几处错误：
- 1、当把文件拖曳到cmd窗口时，能兼容绝大多数特殊情况，比如等号、
- 分号、&；唯有两种情况无法处理：当路径中带&而没有任何空格时；当路径
- 中存在^符号时；但是，双击运行时不受任何特殊字符的影响；
- 2、当拖曳过来的文件与cmd文件不在同一目录下时也能正确处理；
- 此为1.3版；
- 2008.3.13
- 生成的文件夹与CHM文件名保持一致，无须对特殊字符再做任何替换；
- 感谢 随风 的提醒；此为1.2版；
- 2008.1.27
- 增添了反编译多个指定CHM文件的功能；修正了不兼容文件名中带^的
- 错误；修改了部分提示信息；此为1.1版；
- 2008.1.8
- 不再把文件名中的&强制改为＆，但是，文件名中的空格仍然没法不去掉
- 2007.12.27
- 初始版本1.0发布
| 
发表于 2007-12-27 22:41
| 