[系统相关] 批处理如何设置电源计划中的关闭显示器的时间项？

冰淇淋小子

我想一个批处理把电源计划的关闭显示器设置为1分钟，一个批处理把电源计划的关闭显示器的设置为从不。这个批处理怎么写

ygqiang

我想一个批处理把电源计划的关闭显示器设置为1分钟，一个批处理把电源计划的关闭显示器的设置为从不。这个批 ...
冰淇淋小子 发表于 2016-3-7 07:51

    注册表-设置显示器

ygqiang

regedit /s 设置-20分钟后关闭显示器.reg
powercfg /setactive "家用/办公桌"
powercfg /x "家用/办公桌" /monitor-timeout-ac 20



regedit /s 设置-不关闭显示器.reg
powercfg /setactive "一直开着"
powercfg /x "一直开着" /monitor-timeout-ac 0

冰淇淋小子

必须用注册表？不用bat?

冰淇淋小子

我是windows10系统

happy886rr

自己写的，不嫌弃可以试用一下

@echo off 
setlocal enabledelayedexpansion 
color 0f

:main
set "ds1=  "
set "ds2=  "
set "ds3=  "
set "ds!cho!=√"
if "!cho!"=="3" (set "dsm=!min!分") else (set "dsm=")
:main0
cls
echo ┌───────────────┐
echo 丨###      电源计划管理      ###丨^[显示器关闭时间^]
echo ├───────────────┤
echo 丨    1-极省（1分钟后关闭）!ds1!   丨
echo 丨    2-持久（从不关闭）!ds2!      丨
echo 丨    3-自定义时间 !ds3!           丨!dsm!
echo 丨    0-电源配置                丨
echo └───────────────┘
set "cho="
set /p cho=请选择:
if "!cho!"=="1" (
	powercfg -x -monitor-timeout-ac 1
	goto main
)
if "!cho!"=="2" (
	powercfg -x -monitor-timeout-ac 0
	goto main
)
:define
if "!cho!"=="3" (
	set "min="
	set /p min=请输入自定义时间^(单位:分^):
	echo !min!|findstr /be "[0-9]*" >nul || echo 请输入纯数字 && pause>nul && goto define
	powercfg -x -monitor-timeout-ac !min!
	goto main
)
if "!cho!"=="0" (
	powercfg -list
	pause>nul
	goto main0
)
exit
复制代码

大致效果

冰淇淋小子

谢谢搞定了。不用注册表，就用命令搞定了

powercfg -x -monitor-timeout-ac 0

powercfg -change -monitor-timeout-ac 1