[出题]批处理限制输入只能为字母且个数在3-10之间

随风

在别的论坛看到这个题目，大家没事练练手吧，看都有些什么方法实现。
要求：对用户的输入进行判断，字符数不能少于3个,大于10个，且必须是字母（不分大小写）

tireless

@echo off
:repeat
set /p input=请输入: 
if "%input:~2,1%" equ "" goto repeat
if "%input:~10,1%" neq "" goto repeat
for /f "delims=abcdefghijklmnopqrstuvwxyz" %%a in ("%input%") do (
  if "%%a" neq "" goto repeat
)
pauseCOPY

随风

未对大小写作判断。。

zhouyongjun

@echo off
:repeat
set/p input=请输入: 
if "%input:~2,1%" equ "" goto repeat
if "%input:~10,1%" neq "" goto repeat
echo.%input%|findstr/i "^[a-z]*$">nul2>nul||goto repeat
pauseCOPY

[ 本帖最后由 zhouyongjun 于 2009-3-27 23:08 编辑 ]

随风

>nul2>nul  两句中间应该要个空格吧。

Batcher

@echo off
rem 限制输入3位至10位字母
set LenMin=3
set LenMax=10
set AllLetter=a b c d e f g h i j k l m n o p q r s t u v w x y z
 
:GetInput
set input=
set /p "input=请输入3至10位字母："
if "%input%" neq "" (
  if "%input:~2,1%" equ "" (
    echo 不足%LenMin%位
    goto :GetInput
  ) else if "%input:~10,1%" neq "" (
    echo 多于%LenMax%位
    goto :GetInput
  )
) else (
  echo 输入不能为空
  goto :GetInput
)
setlocal enabledelayedexpansion
for %%a in (%AllLetter%) do (
  set input=!input:%%a=!
  if "!input!" equ "" (
    goto :RightInput
  )
)
if "!input!" neq "" (
  echo 只能输入纯字母[a-zA-Z]
  endlocal
  goto :GetInput
)
 
:RightInput
echo 恭喜输入正确
pauseCOPY

[ 本帖最后由 Batcher 于 2009-3-29 14:20 编辑 ]

tireless

@echo off&setlocal enabledelayedexpansion
:repeat
set /p input=请输入: 
echo !input!>%temp%\#tmp#
findstr /xi "[a-z][a-z][a-z] [a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z]" %temp%\#tmp# >nul || goto repeat
pauseCOPY

或者：

@echo off
:repeat
set /p input=请输入: 
(call set/p="%%input%%"<nul&echo.)>%temp%\#tmp#
findstr /xi "[a-z][a-z][a-z] [a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z]" %temp%\#tmp# >nul || goto repeat
pauseCOPY

[ 本帖最后由 tireless 于 2009-3-27 23:47 编辑 ]

随风

I 服了 you !
思路倒是不错，只是代码。。。。。

Batcher

输入off
代码出现误判
^_^

随风

batcher 真是细心  echo.%input% 就可以解决了

zhouyongjun

哈哈，batcher思维果然严谨

tireless

7楼代码已修改。

代码难看不代表效率低啊

[ 本帖最后由 tireless 于 2009-3-27 23:34 编辑 ]

Batcher

7楼是不是再改改？否则遇到off一样会误判^_^

随风

处理 off 的办法以在10楼解决，不行么？
代码除了要讲究效率以外，还要在可能的情况下讲究简洁和美观。

Batcher

可以啊，我只是建议tireless兄更新一下7楼的代码 :）