[其他] 【已解决】如何让一个批处理既可以双击执行又可带参数运行？

ucvsv

@echo off 
MODE con: COLS=55  LINES=20


cls
echo======================================================
tasklist|find /i "winrar.exe" && echo        █ 提  示 █【rar已启动】||echo      █ 提  示 █【rar未启动】

echo======================================================
:main
echo.
echo             请按相应数字键选择所需功能
echo.
echo======================================================
echo=
echo=      1.结束rar
echo=
echo=      2.启动rar
echo=
echo=      3.重启rar
echo=
echo=      4.退出
echo=
echo======================================================

set choice=
set /p choice=    请输入要选择功能后回车:
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
if /i "%choice%"=="1" goto kill
if /i "%choice%"=="2" goto run
if /i "%choice%"=="3" goto restart
if /i "%choice%"=="4" goto exit

cls
goto main

:kill
taskkill /f /im winrar.exe && echo 结束rar成功 || echo 结束rar失败
goto main

:run
start "" "C:\Program Files\WinRAR\WinRAR.exe"
goto main

:restart
cls
taskkill /f /im winrar.exe 
goto run
 
:exit
exit
复制代码

代码贴出在上方
求助，一个批处理 求即可双击出现选择界面（如下图），



又可通过参数调用直接实现其中功能而不显示界面
比如 运行 a.bat kill
直接执行其中的结束进程命令而不显示选择界面
如图




比如 运行 a.bat run
直接执行其中的运行rar程序而不显示选择界面

CrLf

if /i "%~1"=="kill" goto kill
if /i "%~1"=="run" goto run
if /i "%~1"=="restart" goto restart
if /i "%~1"=="exit" goto exit
复制代码

pcl_test

@echo off 
MODE con: COLS=55  LINES=20
if "%~1" neq "" goto :%1
:main
cls
echo======================================================
tasklist|find /i "winrar.exe" >nul&& echo        █ 提  示 █【rar已启动】||echo      █ 提  示 █【rar未启动】

echo======================================================

echo.
echo             请按相应数字键选择所需功能
echo.
echo======================================================
echo=
echo=      1.结束rar
echo=
echo=      2.启动rar
echo=
echo=      3.重启rar
echo=
echo=      4.退出
echo=
echo======================================================

set choice=
set /p choice=请输入要选择功能后回车:
if "%choice%"=="1" goto kill
if "%choice%"=="2" goto run
if "%choice%"=="3" goto restart
if "%choice%"=="4" exit
goto main

:kill
taskkill /f /im winrar.exe && echo 结束rar成功 || echo 结束rar失败
if "%~1" neq "" exit
ping /n 3 0 >nul&goto main

:run
start "" "%ProgramFiles%\WinRAR\WinRAR.exe"
if "%~1" neq "" exit
goto main

:restart
cls
taskkill /f /im "winrar.exe"
goto run
复制代码

CrLf

回复 3# pcl_test


    eof 呢...

ucvsv

回复 2# CrLf


    十分感谢

ucvsv

回复 3# pcl_test


    十分感谢，解决了