[文件操作] [已解决]批处理如何把文件名和目录名称更改为小写？

freesoft00

一个目录中的文件名称和目录名称，如果用批处理更改为小写

下面是一些示例的文件夹名称，文件名也类似如下：

X86_MICROSOFT-WINDOWS-D..IDERS-IBS.RESOURCES_31BF3856AD364E35_6.2.9200.16384_EN-US_03CFEC308BC6B1FA
X86_MICROSOFT.WINDOWS.C..-CONTROLS.RESOURCES_6595B64144CCF1DF_5.82.9200.16384_ZH-CN_34A1C02759BCE553
X86_MICROSOFT.WINDOWS.C..-CONTROLS.RESOURCES_6595B64144CCF1DF_6.0.9200.16384_ZH-CN_FECB149399CDF584
X86_MICROSOFT.WINDOWS.COMMON-CONTROLS_6595B64144CCF1DF_5.82.9200.16384_NONE_BF100CD445F4D954
X86_MICROSOFT.WINDOWS.COMMON-CONTROLS_6595B64144CCF1DF_6.0.9200.16384_NONE_893961408605E985
X86_MICROSOFT.WINDOWS.GDIPLUS.SYSTEMCOPY_31BF3856AD364E35_6.2.9200.16384_NONE_E385A265C77448BF
X86_MICROSOFT.WINDOWS.GDIPLUS_6595B64144CCF1DF_1.0.9200.16384_NONE_CAD2E541479289AC
X86_MICROSOFT.WINDOWS.GDIPLUS_6595B64144CCF1DF_1.1.9200.16384_NONE_BA245425E0986353
X86_MICROSOFT.WINDOWS.H..IVERCLASS.RESOURCES_31BF3856AD364E35_6.2.9200.16384_ZH-CN_2C5051D4D87F0104
X86_MICROSOFT.WINDOWS.H..IVERCLASS.RESOURCES_31BF3856AD364E35_6.2.9200.16384_ZH-CN_0852455A5009DCAC
X86_MICROSOFT.WINDOWS.H..IVERCLASS.RESOURCES_31BF3856AD364E35_6.2.9200.16384_ZH-CN_A3CD74F14BB63ABA
X86_MICROSOFT-WINDOWS-D..GEMENT-WINPROVIDERS_31BF3856AD364E35_6.2.9200.16384_NONE_B3F8C5787652E48C
复制代码

pcl_test

@echo off
::运行后刷新一下
for /f "delims=" %%a in ('dir /b /l') do ren "%%a" "%%a"
for /d /r %%b in (*) do (
    pushd "%%b"
    for /f "delims=" %%c in ('dir /b /l') do ren "%%c" "%%c"
    popd
)
pause
复制代码

freesoft00

回复 3# pcl_test


    老兄的可以了，运行后顺利完成

freesoft00

回复 2# tigerpower


    运行后一闪而过，没有效果
谢谢上面的两位了，谢谢！

WHY

我习惯这样干：

@echo off
for /f "delims=" %%i in ('dir /b /s') do (
    set "file=%%~nxi"
    setlocal enabledelayedexpansion
    for %%j in (q w e r t y u i o p a s d f g h j k l z x c v b n m) do (
        set "file=!file:%%j=%%j!"
    )
    for %%j in ("!file!") do endlocal & ren "%%i" "%%~j"
)
pause
复制代码