[文本处理] [已解决]批处理如何找出两个文本内容不相同的部分。

每天几分

文本A、B是交集关系，它们各自都没有重复文字，要求在文本B中找出跟文本A不相交的文字并导出到新文本。
额，表述可能有点混乱，即如下图，找出B中的黑色内容即可。

pcl_test

回复 1# 每天几分
A、B都是一字占一行吗？

每天几分

回复 2# pcl_test


2种情况能否都考虑？都需要用到的，因为要做到A、B各自没有重复文字，一行多字或者一字一行都能实现。

pcl_test

一字一行

@echo off
for /f "delims=" %%a in ('type "a.txt"') do set %%a=def
(for /f "delims=" %%b in ('type "b.txt"') do if not defined %%b echo,%%b)>"c.txt"
pause
复制代码

gawk

findstr /v /x /g:a.txt b.txt > c.txt
复制代码

pcl_test

一行多字

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type "a.txt"') do (
set "str=%%a"
set "str=!str: =!"
set "$=!str!#"
set len=&for %%z in (4096 2048 1024 512 256 128 64 32 16) do if !$:~%%z^,1!. neq . set/a len+=%%z&set $=!$:~%%z!
set $=!$!fedcba9876543210 & set/a len+=0x!$:~16,1! &set/a len-=1
for /l %%i in (0 1 !len!) do set _"!str:~%%i,1!"=Def
)

(for /f "delims=" %%a in ('type "b.txt"') do (
set "str=%%a"
set "str=!str: =!"
set "$=!str!#"
set len=&for %%z in (4096 2048 1024 512 256 128 64 32 16) do if !$:~%%z^,1!. neq . set/a len+=%%z&set $=!$:~%%z!
set $=!$!fedcba9876543210 & set/a len+=0x!$:~16,1! &set/a len-=1
for /l %%i in (0 1 !len!) do (
if not defined _"!str:~%%i,1!" set/p=!str:~%%i,1!<nul
)
echo,
))>"c.txt"
pause
复制代码