[文件操作] [已解决] 批处理中单引号与双引号有什么区别

fulijung

下面是批处理建立与文件同名的文件夹并剪切至该文件夹下代码
@Echo Off
For /f "tokens=*" %%i in ('Dir /b /a-d *.txt') do (
Echo %%~ni
Md %%~ni
)
Pause

这里in ('Dir /b /a-d *.txt')中的单引号表示的是什么意思啊，它与双引号有什么区别

还有那个波浪线~又代表什么呢，谢谢哥哥姐姐们回答

pcl_test

回复 1# fulijung
单引号，是执行引号里的命令
双引号，是引用的内容，如字符串
波浪线，是扩充字符串，如你代码中的%%~ni 就是获取txt的文件名

@echo off
title 获取批处理文件的一些自身信息
mode con lines=40
color 03
echo *******************************************
echo #示例说明： 
echo 获取批处理文件的自身信息 
echo *******************************************
echo. 
echo 当前执行目录是：%cd% 
echo --------------该处理操作开始-------------- 
echo.
echo --1:[%%%%~s0]获取批处理文件自身的缩写全路径名: 
echo %~s0 
echo. 
echo --2:[%%%%0]获取批处理文件自身的完整路径(有引号可防止空格路径): 
echo %0 
echo. 
echo --3:[%%%%~0]获取批处理文件自身的完整路径，并去掉首尾的引号: 
echo %~0 
echo. 
echo --4:[%%%%~nx0]获取批处理文件自身的文件名及后缀名: 
echo %~nx0 
echo. 
echo --5:[%%%%~n0]获取批处理文件自身的文件名: 
echo %~n0 
echo. 
echo --6:[%%%%~x0]获取批处理文件自身的后缀名: 
echo %~x0 
echo. 
echo --7:[%%%%~dp0]获取批处理文件自身的完整路径，不含文件名: 
echo %~dp0 
echo. 
echo --8:[%%%%~d0]获取批处理文件自身的盘符: 
echo %~d0 
echo. 
echo --9:[%%%%~z0]获取批处理文件自身的大小(byte): 
echo %~z0 
echo. 
echo --10:[%%%%~t0]获取批处理文件自身的修改时间: 
echo %~t0 
echo.
pause
复制代码

Batcher

楼上讲的很清楚。楼主也可以参考这个：
http://bbs.bathome.net/thread-31727-1-1.html