[文本处理] 批处理检测文件夹下面所有的txt文本行数，超过500行就清空文本

661100a

检测 d:\a 文件夹下面的所有子文件夹 如：d:\a\aaa d:\a\bbbb 等等的所有.txt文本的行数，如果单个文本超过500行就清空该文本内容。


请教大大。。

661100a

求助哦···············

DAIC

单个文件超过500行？还是所有文件行数总数超过500行？

661100a

单个..................

661100a

求助···············

apang

@echo off
for /f "delims=" %%a in ('dir /ad /b /s "D:\Test\"') do (
        pushd "%%a\"
        (for /f "tokens=1*delims=:" %%b in ('find /c /v "" *.txt') do (
                for /f "tokens=*delims=- " %%d in ("%%b") do (
                        if %%c gtr 500 cd.>"%%d"
                )
        )) 2>nul
        popd
)
pause
复制代码

661100a

回复 6# apang

牛B，3q

Batcher

@echo off
for /f "delims=" %%i in ('dir /a-d /b /s "D:\a\*.txt"') do (
    for /f %%j in ('type "%%i" ^| find /c /v ""') do (
        if %%j gtr 500 (
            cd.>%%i
        )
    )
)
复制代码

CrLf

用 findstr 可能更合适：

@echo off
cd /d d:\a
for /f "delims=:" %%a in ('findstr /n /s .* *.txt^|findstr "^[^:]*:501:"') do (
         break >"%%a"
)
复制代码

terse

C版 上面是否增加格判断呢  这样正则貌似有问题的

@echo off
for /f "tokens=1-3delims=:" %%a in ('findstr /n /s .* d:\a\*.txt^|findstr :501:') do (
        if %%c equ 501 cd.>%%a:%%b
    )
)
pause
复制代码