[文本处理] 【已解决】批处理如何将文本全部替换为空行再删除最后3行？

elec

求助一个P处理，能够将文本的内容全部删除，但是行都在(应该是换行符？？)。再删除最后3行
        有没有办法做成将文本拖入bat中，就自动生成处理好的文本。

522235677

检测行数，然后-3,

Batcher

@echo off
if not exist "%~1" (
    echo File not exist
    pause
    goto :eof
)
for /f %%i in ('type "%~1" ^| find /c /v ""') do (
    set n=%%i
)
set /a n-=3
(for /l %%i in (1,1,%n%) do (
    echo,
))>"%~1".bathome
move /y "%~1".bathome "%~1"
复制代码

522235677

@echo off
for /f "tokens=1* delims=:" %%a in ('findstr /n .* %~s1') do (set n=%%a)
set /a n=%n%-3
for /l %%a in (2 1 %n%) do echo.>>"new_%~nx1"
pause
复制代码

elec

回复 4# 522235677


    我想知道类似于%~nx1    %~1   %~dpnx1等符号代表的意思。
    有没有系统的讲解？

522235677

%~I          - 删除任何引号(")，扩展 %I
     %~fI        - 将 %I 扩展到一个完全合格的路径名
     %~dI        - 仅将 %I 扩展到一个驱动器号
     %~pI        - 仅将 %I 扩展到一个路径
     %~nI        - 仅将 %I 扩展到一个文件名
     %~xI        - 仅将 %I 扩展到一个文件扩展名
     %~sI        - 扩展的路径只含有短名
     %~aI        - 将 %I 扩展到文件的文件属性
     %~tI        - 将 %I 扩展到文件的日期/时间
     %~zI        - 将 %I 扩展到文件的大小
     %~$PATH:I   - 查找列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个完全合格的名称。如果环境变量名
                   未被定义，或者没有找到文件，此组合键会扩展到
                   空字符串

可以组合修饰符来得到多重结果:

     %~dpI       - 仅将 %I 扩展到一个驱动器号和路径
     %~nxI       - 仅将 %I 扩展到一个文件名和扩展名
     %~fsI       - 仅将 %I 扩展到一个带有短名的完整路径名
     %~dp$PATH:I - 搜索列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个驱动器号和路径。
     %~ftzaI     - 将 %I 扩展到类似输出线路的 DIR

在以上例子中，%I 和 PATH 可用其他有效数值代替。%~ 语法
用一个有效的 FOR 变量名终止。选取类似 %I 的大写变量名
比较易读，而且避免与不分大小写的组合键混淆。

522235677

点击链接加入群【批处理之家①】：http://jq.qq.com/?_wv=1027&k=ML4fnU

elec

回复 3# Batcher


    您的代码好是好，但是会直接覆盖原文件。后果十分惨烈！！！！

    能不能改进一下，我想将处理好的数据输出到一个新的文件命名为 aa.db     再将原文件重命名为bb.db

Batcher

回复 8# elec


    把3楼最后一行删掉