[文本处理] 【已解决】横着两个数字塔的效果BAT批处理怎么写？

battab

@echo off
for /l %%a in (0,1,1) do (
	for /l %%i in (0,1,9) do (
	for /l %%j in (0,1,%%i) do set /p=%%j<nul
	echo=
	)
)
pause
复制代码

我这个BAT可以竖下来输出2个数字塔，如果我想达到附件里效果要怎么写呢？

weichenxiehou

回复 1# battab

@echo off&setlocal enabledelayedexpansion
set "space=          "
for /l %%i in (0,1,9) do (
	set/a n=10-%%i,m=%%i-1
	for %%z in (!n!) do set t=!space:~,%%z!
	for /l %%j in (0,1,!m!) do set /p=%%j<nul
	set/p=%%i!t!<nul
	for /l %%j in (0,1,%%i) do set /p=%%j<nul
	echo,
)
pause
复制代码

apang

@echo off & setlocal enabledelayedexpansion
for /l %%i in (0 1 9) do set "sp=!sp! "
for /l %%i in (0 1 9) do (
    set "s="
    for /l %%j in (0 1 %%i) do set "s=!s!%%j"
    set "str=!s!!sp!"
    echo,!str:~,11!!s!
)
pause
复制代码

CrLf

继续发另类解：

@echo off
%1 cmd /v /c @%0 :|more /t11&pause&exit

for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /l %%a in (0 1 9) do set str=!str!%%a&echo !str!!tab!!str!
复制代码

simon4055

这个好 mark一下 留着用.
学习了..

terse

这样简化

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0 1 9) do set "sp=!sp! "
for /l %%i in (0 1 9) do (
    set "str=!str!%%i"
    echo !str!!sp:~%%i!!str!
)
pause
复制代码

mq0036

我也给个自己写的，把第二个for的参数改下，横向的可以打印1，2，3，4，5，6........个数字塔

@echo off
for /l %%i in (0,1,9) do (
for /l %%j in (0,1,1) do (
for /l %%k in (0,1,10) do (
if %%k leq %%i (set /p =%%k<nul) else (set /p = <nul)
)
)
echo.
)
echo.
复制代码

DAIC

回复 7# mq0036


不要把所有的代码都顶格写

@echo off
for /l %%i in (0,1,9) do (
    for /l %%j in (0,1,1) do (
        for /l %%k in (0,1,10) do (
            if %%k leq %%i (
                set /p =%%k<nul
            ) else (
                set /p = <nul
            )
        )
    )
    echo.
)
echo.
复制代码

battab

回复 4# CrLf


这个确实很另类，看得一头雾水，谁能解说下，谢谢先！

mq0036

回复 8# DAIC

呵呵，用别人的电脑，随手拿记事本写的，手头也没有现成的工具可用。