[系统相关] win11 打印机批处理安装教程

@echo off
MODE con: COLS=100 LINES=28
title 打印机自动安装程序

set TheBit=%PROCESSOR_ARCHITECTURE:~-2%
if /i not "%os%"=="Windows_NT" (set TheOS=非Windows系统&set TheBit=) else (
    ver | find "10.0" > nul && set system_info=Win10.%TheBit%
    ver | find "10.0.22000" > nul && set system_info=Win11.%TheBit%
)

:: 定义打印机信息
set print_port=LPT1:
set print_drive_dir=C:\ceshi\Gprinter.inf
set print_drive_name=Gprinter GP-M323

:: 打印机列表
set "printers=便捷式打印50X40 便捷式打印40X30 便捷式打印40X24"

echo.
echo.          打印机自动安装程序
echo.
echo.    =========================================================================
echo.
echo.    操作系统 ：  %system_info%
echo.
echo.    打印机端口：  %print_port%
echo.
echo.    驱动路径 ：  %print_drive_dir%
echo.
echo.    驱动名称 ：  %print_drive_name%
echo.
echo.    =========================================================================
echo.
echo.    准备安装以下打印机：
echo.    %printers%
echo.
echo.    如果出现提示，请允许运行
echo.
echo.    如果程序运行异常或未能安装打印机，请联系管理员！
echo.
echo.
echo.


:check
:: 检查驱动目录是否存在
if not exist %print_drive_dir% goto no_drive

:install_printers
:: 循环安装每个打印机
for %%p in (%printers%) do (
    echo.
    echo.    正在安装打印机 %%p，请稍等...
    rundll32 printui.dll,PrintUIEntry /if /b "%%p" /f "%print_drive_dir%" /r "%print_port%" /m "%print_drive_name%" /z
    if errorlevel 0 (
        echo.
        echo.    打印机 %%p 安装成功！
    ) else (
        echo.
        echo.    打印机 %%p 安装失败！
    )
)

:end
echo.
echo.  5秒后自动退出...
echo.
ping -n 5 127.0.0.1 >nul
exit

:no_drive
echo.
echo.  驱动文件不存在或操作系统不支持，程序即将退出...
echo.
goto end
复制代码