[文本处理] 【已解决】批处理用文件名中的数组查找缺失的文件编号

@echo off
for /f "tokens=3 delims=-" %%i in ('dir /b /a-d *-*-*-*.*') do (
    for /f "tokens=* delims=BD0" %%j in ("%%i") do set n=%%j
)
setlocal enabledelayedexpansion
for /l %%i in (1,1,%n%) do (
    set m=000%%i
    set m=!m:~-4!
    if not exist "*-*-BD!m!-*.*" echo,BD!m!
)
pause
复制代码

@echo off &setlocal enabledelayedexpansion
for /f "tokens=3 delims=-" %%a in (' dir /b/a-d "*-BD????-*" ') do (set "%%a=1")
for /l %%n in (1,1,500) do (set "k=000%%n" &if not defined BD!k:~-4! echo,BD!k:~-4!)
endlocal&pause&exit/b
复制代码

@echo off
cd /d "%~dp0"
rem 定义开头，s=1；不定义则删除下一行
set s=1
setlocal enabledelayedexpansion
for /f "tokens=3 delims=-" %%i in ('dir /b /a-d *-*-*-*.* ^|find /v "%~nx0"') do (
	for /f "tokens=* delims=BD0" %%a in ("%%i") do (
		if !s! neq %%a (
			set /a e=%%a-1
			for /l %%l in (!s! 1 !e!) do (
				set str=0000000%%l
				echo BD!str:~-4!
			)
		)
		set /a s=%%a+1
	)
)
endlocal
pause
复制代码

@echo off
set x=9999
set y=0
setlocal enabledelayedexpansion
for /f "tokens=3 delims=-" %%i in ('dir /b /a-d *-*-*-*.*') do (
    for /f "tokens=* delims=BD0" %%j in ("%%i") do (
        if %%j lss !x! set x=%%j
        if %%j gtr !y! set y=%%j
    )
)
for /l %%i in (%x%,1,%y%) do (
    set m=000%%i
    set m=!m:~-4!
    if not exist "*-*-BD!m!-*.*" echo,BD!m!
)
pause
复制代码