[其他] 批处理如何提取文件夹中图片的名称及拍摄时间？

@echo off
rem 下载并添加到环境变量 （https://exiftool.org/）
chcp 65001 >nul
cd /d "%~dp0"
exiftool -Filename -DateTimeOriginal -T "*.jpg" >>out.txt
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set /a size=2048
for %%i in (*.jpg) do (
    copy /y "%%i" $.temp >nul
    fsutil file seteof $.temp %size% >nul
    certutil -encodehex -f $.temp $.temp >nul
    set /a n=tag=len=end=0&set "offset="
    (for /f "tokens=1*" %%a in ($.temp) do (
        set "str=%%b"
        for /f "delims=。" %%s in ("!str:   =。!") do for %%h in (%%s) do (
            if !end! lss 19 (
                set /a n+=1,tag+=1
                if /i "%%h"=="4d" if "!pre!"=="4d" set /a n=2
                if /i "%%h"=="03" if "!pre!"=="90" set /a tag=1009003
                if !tag! gtr 1009009 if !tag! leq 1009013 set "offset=!offset!%%h"&set /a len+=1
                if !len! equ 4 if !n! gtr 0x!offset! echo,%%h&set /a end+=1
                set "pre=%%h"
                )
            )
        )) > $.time
    certutil -decodehex -f $.time $.time >nul
    for /f "tokens=* delims=" %%t in ($.time) do echo,%%t--------%%i
    )
del /q $.temp $.time
pause
复制代码